From 8baab3c8d7a6f22888bd581cd5c6098fd2e4b5a8 Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Mon, 6 May 2024 04:44:24 +0200
Subject: Adding upstream version 2:8.1.0875.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 runtime/ftplugin/debcontrol.vim | 70 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 runtime/ftplugin/debcontrol.vim

(limited to 'runtime/ftplugin/debcontrol.vim')

diff --git a/runtime/ftplugin/debcontrol.vim b/runtime/ftplugin/debcontrol.vim
new file mode 100644
index 0000000..3a6e39a
--- /dev/null
+++ b/runtime/ftplugin/debcontrol.vim
@@ -0,0 +1,70 @@
+" Vim filetype plugin file (GUI menu and folding)
+" Language:     Debian control files
+" Maintainer:   Debian Vim Maintainers
+" Former Maintainer:    Pierre Habouzit <madcoder@debian.org>
+" Last Change:  2018-01-28
+" URL:          https://salsa.debian.org/vim-team/vim-debian/blob/master/ftplugin/debcontrol.vim
+
+" Do these settings once per buffer
+if exists('b:did_ftplugin')
+  finish
+endif
+let b:did_ftplugin=1
+
+" {{{1 Local settings (do on every load)
+if exists('g:debcontrol_fold_enable')
+  setlocal foldmethod=expr
+  setlocal foldexpr=DebControlFold(v:lnum)
+  setlocal foldtext=DebControlFoldText()
+endif
+setlocal textwidth=0
+
+" Clean unloading
+let b:undo_ftplugin = 'setlocal tw< foldmethod< foldexpr< foldtext<'
+
+" }}}1
+
+" {{{1 folding
+
+function! s:getField(f, lnum)
+  let line = getline(a:lnum)
+  let fwdsteps = 0
+  while line !~ '^'.a:f.':'
+    let fwdsteps += 1
+    let line = getline(a:lnum + fwdsteps)
+    if line ==# ''
+      return 'unknown'
+    endif
+  endwhile
+  return substitute(line, '^'.a:f.': *', '', '')
+endfunction
+
+function! DebControlFoldText()
+  if v:folddashes ==# '-'  " debcontrol entry fold
+    let type = substitute(getline(v:foldstart), ':.*', '', '')
+    if type ==# 'Source'
+      let ftext = substitute(foldtext(), ' *Source: *', ' ', '')
+      return ftext . ' -- ' . s:getField('Maintainer', v:foldstart) . ' '
+    endif
+    let arch  = s:getField('Architecture', v:foldstart)
+    let ftext = substitute(foldtext(), ' *Package: *', ' [' . arch . '] ', '')
+    return ftext . ': ' . s:getField('Description', v:foldstart) . ' '
+  endif
+  return foldtext()
+endfunction
+
+function! DebControlFold(l)
+
+  " This is for not merging blank lines around folds to them
+  if getline(a:l) =~# '^Source:'
+    return '>1'
+  endif
+
+  if getline(a:l) =~# '^Package:'
+    return '>1'
+  endif
+
+  return '='
+endfunction
+
+" }}}1
-- 
cgit v1.2.3