From 19f4f86bfed21c5326ed2acebe1163f3a83e832b Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Mon, 6 May 2024 04:25:50 +0200
Subject: Adding upstream version 241.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 shell-completion/zsh/_systemd-analyze | 82 +++++++++++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 shell-completion/zsh/_systemd-analyze

(limited to 'shell-completion/zsh/_systemd-analyze')

diff --git a/shell-completion/zsh/_systemd-analyze b/shell-completion/zsh/_systemd-analyze
new file mode 100644
index 0000000..64d418e
--- /dev/null
+++ b/shell-completion/zsh/_systemd-analyze
@@ -0,0 +1,82 @@
+#compdef systemd-analyze
+# SPDX-License-Identifier: LGPL-2.1+
+
+(( $+functions[_systemd-analyze_log-level] )) ||
+_systemd-analyze_log-level() {
+    local -a _levels
+    _levels=(debug info notice warning err crit alert emerg)
+    _describe -t level 'logging level' _levels || compadd "$@"
+}
+
+(( $+functions[_systemd-analyze_log-target] )) ||
+_systemd-analyze_log-target() {
+    local -a _targets
+    _targets=(console journal kmsg journal-or-kmsg null)
+    _describe -t target 'logging target' _targets || compadd "$@"
+}
+
+(( $+functions[_systemd-analyze_verify] )) ||
+_systemd-analyze_verify() {
+    _sd_unit_files
+}
+
+(( $+functions[_systemd-analyze_service-watchdogs] )) ||
+_systemd-analyze_service-watchdogs() {
+    local -a _states
+    _states=(on off)
+    _describe -t state 'state' _states || compadd "$@"
+}
+
+(( $+functions[_systemd-analyze_commands] )) ||
+_systemd-analyze_commands(){
+    local -a _systemd_analyze_cmds
+    # Descriptions taken from systemd-analyze --help.
+    _systemd_analyze_cmds=(
+        'time:Print time spent in the kernel before reaching userspace'
+        'blame:Print list of running units ordered by time to init'
+        'critical-chain:Print a tree of the time critical chain of units'
+        'plot:Output SVG graphic showing service initialization'
+        'dot:Dump dependency graph (in dot(1) format)'
+        'dump:Dump server status'
+        'unit-paths:List unit load paths'
+        'log-level:Get/set systemd log threshold'
+        'log-target:Get/set systemd log target'
+        'service-watchdogs:Get/set service watchdog status'
+        'syscall-filter:List syscalls in seccomp filter'
+        'verify:Check unit files for correctness'
+        'calendar:Validate repetitive calendar time events'
+    )
+
+    if (( CURRENT == 1 )); then
+        _describe "options" _systemd_analyze_cmds
+    else
+        local curcontext="$curcontext"
+        cmd="${${_systemd_analyze_cmds[(r)$words[1]:*]%%:*}}"
+        if (( $#cmd )); then
+            if (( $+functions[_systemd-analyze_$cmd] )) && (( CURRENT == 2 )); then
+                _systemd-analyze_$cmd
+            else
+                _message "no more options"
+            fi
+        else
+            _message "unknown systemd-analyze command: $words[1]"
+        fi
+    fi
+}
+
+_arguments \
+    {-h,--help}'[Show help text]' \
+    '--version[Show package version]' \
+    '--system[Operate on system systemd instance]' \
+    '--user[Operate on user systemd instance]' \
+    '--global[Show global user instance config]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--man=[Do (not) check for existence of man pages]:boolean:(1 0)' \
+    '--order[When generating graph for dot, show only order]' \
+    '--require[When generating graph for dot, show only requirement]' \
+    '--fuzz=[When printing the tree of the critical chain, print also services, which finished TIMESPAN earlier, than the latest in the branch]:TIMESPAN' \
+    '--from-pattern=[When generating a dependency graph, filter only origins]:GLOB' \
+    '--to-pattern=[When generating a dependency graph, filter only destinations]:GLOB' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machine:_sd_machines' \
+    '*::systemd-analyze commands:_systemd-analyze_commands'
-- 
cgit v1.2.3