3 files changed, 68 insertions, 0 deletions
diff --git a/test cases/common/140 custom target multiple outputs/generator.py b/test cases/common/140 custom target multiple outputs/generator.py
new file mode 100755
index 0000000..39dbd11
--- /dev/null
+++ b/test cases/common/140 custom target multiple outputs/generator.py
@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+
+import sys, os
+
+if len(sys.argv) != 3:
+    print(sys.argv[0], '<namespace>', '<output dir>')
+
+name = sys.argv[1]
+odir = sys.argv[2]
+
+with open(os.path.join(odir, name + '.h'), 'w') as f:
+    f.write('int func();\n')
+with open(os.path.join(odir, name + '.sh'), 'w') as f:
+    f.write('#!/bin/bash')
diff --git a/test cases/common/140 custom target multiple outputs/meson.build b/test cases/common/140 custom target multiple outputs/meson.build
new file mode 100644
index 0000000..abc5728
--- /dev/null
+++ b/test cases/common/140 custom target multiple outputs/meson.build
@@ -0,0 +1,44 @@
+project('multiple outputs install')
+
+gen = find_program('generator.py')
+
+custom_target('different-install-dirs',
+  output : ['diff.h', 'diff.sh'],
+  command : [gen, 'diff', '@OUTDIR@'],
+  install : true,
+  install_dir : [join_paths(get_option('prefix'), get_option('includedir')),
+                 join_paths(get_option('prefix'), get_option('bindir'))])
+
+custom_target('same-install-dir',
+  output : ['same.h', 'same.sh'],
+  command : [gen, 'same', '@OUTDIR@'],
+  install : true,
+  install_dir : '/opt')
+
+custom_target('only-install-first',
+  output : ['first.h', 'first.sh'],
+  command : [gen, 'first', '@OUTDIR@'],
+  install : true,
+  install_dir : [join_paths(get_option('prefix'), get_option('includedir')), false])
+
+targets = custom_target('only-install-second',
+  output : ['second.h', 'second.sh'],
+  command : [gen, 'second', '@OUTDIR@'],
+  install : true,
+  install_dir : [false, join_paths(get_option('prefix'), get_option('bindir'))])
+
+paths = []
+foreach i : targets.to_list()
+  paths += i.full_path()
+endforeach
+
+# The Xcode backend has a different output naming scheme.
+if meson.backend() == 'xcode'
+  assert(paths == [meson.project_build_root() / get_option('buildtype') / 'second.h',
+                   meson.project_build_root() / get_option('buildtype') / 'second.sh'])
+
+# Skip on Windows because paths are not identical, '/' VS '\'.
+elif host_machine.system() != 'windows'
+  assert(paths == [meson.current_build_dir() / 'second.h',
+                   meson.current_build_dir() / 'second.sh'])
+endif
diff --git a/test cases/common/140 custom target multiple outputs/test.json b/test cases/common/140 custom target multiple outputs/test.json
new file mode 100644
index 0000000..e59cb9f
--- /dev/null
+++ b/test cases/common/140 custom target multiple outputs/test.json
@@ -0,0 +1,10 @@
+{
+  "installed": [
+    {"type": "file", "file": "usr/include/diff.h"},
+    {"type": "file", "file": "usr/include/first.h"},
+    {"type": "file", "file": "usr/bin/diff.sh"},
+    {"type": "file", "file": "usr/bin/second.sh"},
+    {"type": "file", "file": "opt/same.h"},
+    {"type": "file", "file": "opt/same.sh"}
+  ]
+}