Adding upstream version 2:9.0.1378.upstream/2%9.0.1378upstream

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/src/testdir/test_expand_dllpath.vim b/src/testdir/test_expand_dllpath.vim
new file mode 100644
index 0000000..8e48972
--- /dev/null
+++ b/src/testdir/test_expand_dllpath.vim
@@ -0,0 +1,36 @@
+" Test for expanding dllpath options
+
+func s:test_expand_dllpath(optname)
+  let $TEST_EXPAND_DLLPATH = '/dllpath/lib' . substitute(a:optname, '\zedll$', '.', '')
+  execute 'let dllpath_save = &' . a:optname
+  try
+    execute 'set ' . a:optname . '=$TEST_EXPAND_DLLPATH'
+    execute 'call assert_equal("' . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')'
+
+    execute 'set ' . a:optname . '=~' . $TEST_EXPAND_DLLPATH
+    let home = substitute($HOME, '\\', '/', 'g')
+    execute 'call assert_equal("' . home . $TEST_EXPAND_DLLPATH . '", &' . a:optname . ')'
+  finally
+    execute 'let &' . a:optname . ' = dllpath_save'
+    let $TEST_EXPAND_DLLPATH = ''
+  endtry
+endfunc
+
+func s:generate_test_if_exists(optname)
+  if exists('+' . a:optname)
+    execute join([
+          \ 'func Test_expand_' . a:optname . '()',
+          \ '  call s:test_expand_dllpath("' . a:optname . '")',
+          \ 'endfunc'
+          \ ], "\n")
+  endif
+endfunc
+
+call s:generate_test_if_exists('luadll')
+call s:generate_test_if_exists('perldll')
+call s:generate_test_if_exists('pythondll')
+call s:generate_test_if_exists('pythonthreedll')
+call s:generate_test_if_exists('rubydll')
+call s:generate_test_if_exists('tcldll')
+
+" vim: shiftwidth=2 sts=2 expandtab