/* This Source Code Form is subject to the terms of the Mozilla Public
 * License, v. 2.0. If a copy of the MPL was not distributed with this file,
 * You can obtain one at http://mozilla.org/MPL/2.0/. */

include protocol PBackgroundFileRequest;
include protocol PBackgroundMutableFile;
include protocol PChildToParentStream; // FIXME: bug 792908
include protocol PFileDescriptorSet; // FIXME: bug 792908
include protocol PParentToChildStream; // FIXME: bug 792908
include protocol PRemoteLazyInputStream; // FIXME: bug 792908

include IPCBlob;

namespace mozilla {
namespace dom {

struct FileRequestGetMetadataParams
{
  bool size;
  bool lastModified;
};

struct FileRequestReadParams
{
  uint64_t offset;
  uint64_t size;
};

struct FileRequestStringData
{
  nsCString string;
};

struct FileRequestBlobData
{
  IPCBlob blob;
};

union FileRequestData
{
  FileRequestStringData;
  FileRequestBlobData;
};

struct FileRequestWriteParams
{
  uint64_t offset;
  FileRequestData data;
  uint64_t dataLength;
};

struct FileRequestTruncateParams
{
  uint64_t offset;
};

struct FileRequestFlushParams
{
};

union FileRequestParams
{
  FileRequestGetMetadataParams;
  FileRequestReadParams;
  FileRequestWriteParams;
  FileRequestTruncateParams;
  FileRequestFlushParams;
};

protocol PBackgroundFileHandle
{
  manager PBackgroundMutableFile;

  manages PBackgroundFileRequest;

parent:
  async DeleteMe();

  async Finish();
  async Abort();

  async PBackgroundFileRequest(FileRequestParams params);

child:
  async __delete__();

  async Complete(bool aborted);
};

} // namespace dom
} // namespace mozilla