1 files changed, 54 insertions, 0 deletions
diff --git a/plugins/spell/meson.build b/plugins/spell/meson.build
new file mode 100644
index 0000000..8ce7634
--- /dev/null
+++ b/plugins/spell/meson.build
@@ -0,0 +1,54 @@
+libspell_sources = files(
+  'gedit-spell-app-activatable.c',
+  'gedit-spell-plugin.c',
+)
+
+libspell_deps = [
+  libgedit_dep,
+  gspell_dep,
+]
+
+subdir('resources')
+
+libspell_sha = shared_module(
+  'spell',
+  sources: libspell_sources,
+  include_directories: root_include_dir,
+  dependencies: libspell_deps,
+  install: true,
+  install_dir: join_paths(
+    pkglibdir,
+    'plugins',
+  ),
+  name_suffix: module_suffix,
+)
+
+spell_gschema_file = files('org.gnome.gedit.plugins.spell.gschema.xml')
+install_data(
+  spell_gschema_file,
+  install_dir: join_paths(get_option('prefix'), get_option('datadir'), 'glib-2.0/schemas')
+)
+
+if xmllint.found()
+  test(
+    'validate-spell-gschema',
+    xmllint,
+    args: [
+      '--noout',
+      '--dtdvalid', gschema_dtd,
+      spell_gschema_file,
+    ]
+  )
+endif
+
+custom_target(
+  'spell.plugin',
+  input: 'spell.plugin.desktop.in',
+  output: 'spell.plugin',
+  command: msgfmt_plugin_cmd,
+  install: true,
+  install_dir: join_paths(
+    pkglibdir,
+    'plugins',
+  )
+)