1 files changed, 70 insertions, 0 deletions
diff --git a/plugins/flatpak/meson.build b/plugins/flatpak/meson.build
new file mode 100644
index 0000000..0afc5a9
--- /dev/null
+++ b/plugins/flatpak/meson.build
@@ -0,0 +1,70 @@
+cargs = ['-DG_LOG_DOMAIN="GsPluginFlatpak"']
+deps = [
+  plugin_libs,
+  flatpak,
+  libxmlb,
+  ostree,
+]
+
+if get_option('mogwai')
+  deps += mogwai_schedule_client
+endif
+
+shared_module(
+  'gs_plugin_flatpak',
+  sources : [
+    'gs-appstream.c',
+    'gs-flatpak-app.c',
+    'gs-flatpak.c',
+    'gs-flatpak-transaction.c',
+    'gs-flatpak-utils.c',
+    'gs-plugin-flatpak.c'
+  ],
+  include_directories : [
+    include_directories('../..'),
+    include_directories('../../lib'),
+  ],
+  install : true,
+  install_dir: plugin_dir,
+  c_args : cargs,
+  dependencies : deps,
+  link_with : [
+    libgnomesoftware
+  ]
+)
+metainfo = 'org.gnome.Software.Plugin.Flatpak.metainfo.xml'
+
+i18n.merge_file(
+  input: metainfo + '.in',
+  output: metainfo,
+  type: 'xml',
+  po_dir: join_paths(meson.source_root(), 'po'),
+  install: true,
+  install_dir: join_paths(get_option('datadir'), 'metainfo')
+)
+
+if get_option('tests')
+  subdir('tests')
+
+  cargs += ['-DLOCALPLUGINDIR="' + meson.current_build_dir() + '"']
+  cargs += ['-DLOCALPLUGINDIR_CORE="' + meson.current_build_dir() + '/../core"']
+  cargs += ['-DTESTDATADIR="' + join_paths(meson.current_build_dir(), 'tests') + '"']
+  e = executable(
+    'gs-self-test-flatpak',
+    compiled_schemas,
+    sources : [
+      'gs-flatpak-app.c',
+      'gs-self-test.c'
+    ],
+    include_directories : [
+      include_directories('../..'),
+      include_directories('../../lib'),
+    ],
+    dependencies : deps,
+    link_with : [
+      libgnomesoftware
+    ],
+    c_args : cargs,
+  )
+  test('gs-self-test-flatpak', e, suite: ['plugins', 'flatpak'], env: test_env, timeout : 120)
+endif