Adding upstream version 5.3.1.upstream/5.3.1upstream

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>

1 files changed, 69 insertions, 0 deletions

diff --git a/distro/arch/PKGBUILD b/distro/arch/PKGBUILD
new file mode 100644
index 0000000..7b3cfe4
--- /dev/null
+++ b/distro/arch/PKGBUILD
@@ -0,0 +1,69 @@
+# Maintainer:	Tomas Krizek <tomas.krizek@nic.cz>
+# Contributor:	Ondřej Surý <ondrej@sury.org>
+# SPDX-License-Identifier: GPL-3.0-or-later
+
+pkgname=knot-resolver
+pkgver=__VERSION__
+pkgrel=1
+pkgdesc='Caching DNSSEC-validating DNS resolver'
+arch=('x86_64' 'armv7h')
+url='https://www.knot-resolver.cz/'
+license=('GPL3')
+depends=(
+    'dnssec-anchors'
+    'gnutls'
+    'knot'
+    'libedit'
+    'libuv'
+    'lmdb'
+    'luajit'
+    'systemd'
+    'libcap-ng'
+    'libnghttp2'
+)
+makedepends=(
+    'cmocka'
+    'meson'
+    'systemd-libs'
+)
+optdepends=(
+    'lua51-basexx: experimental_dot_auth module'
+    'lua51-cqueues: http and dns64 module, policy.rpz() function'
+    'lua51-http: http and prefill modules, trust_anchors bootstrap'
+    'lua51-psl: policy.slice_randomize_psl() function'
+)
+backup=('etc/knot-resolver/kresd.conf')
+options=(debug strip)
+source=("knot-resolver_${pkgver}.orig.tar.xz")
+sha256sums=('SKIP')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    meson build \
+        --buildtype=release \
+        --prefix=/usr \
+        --sbindir=bin \
+        -D keyfile_default=/etc/trusted-key.key \
+        -D systemd_files=enabled \
+        -D client=enabled \
+        -D install_kresd_conf=enabled \
+        -D unit_tests=enabled
+    ninja -C build
+}
+
+check() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    meson test -C build
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    DESTDIR=${pkgdir} ninja -C build install
+
+    # add kresd.target to multi-user.target.wants to support enabling kresd services
+    install -d -m 0755 "${pkgdir}/usr/lib/systemd/system/multi-user.target.wants"
+    ln -s ../kresd.target "${pkgdir}/usr/lib/systemd/system/multi-user.target.wants/kresd.target"
+
+    # remove modules with missing dependencies
+    rm "${pkgdir}/usr/lib/knot-resolver/kres_modules/etcd.lua"
+}