1 files changed, 71 insertions, 0 deletions
diff --git a/coccinelle/fopen-unlocked.cocci b/coccinelle/fopen-unlocked.cocci
new file mode 100644
index 0000000..7870f8c
--- /dev/null
+++ b/coccinelle/fopen-unlocked.cocci
@@ -0,0 +1,71 @@
+@@
+expression f, path, options;
+@@
+- f = fopen(path, options);
+- if (!f)
+-       return -errno;
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);
++ r = fopen_unlocked(path, options, &f);
++ if (r < 0)
++       return r;
+@@
+expression f, path, options;
+@@
+- f = fopen(path, options);
+- if (!f) {
+-       if (errno == ENOENT)
+-            return -ESRCH;
+-       return -errno;
+- }
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);
++ r = fopen_unlocked(path, options, &f);
++ if (r == -ENOENT)
++     return -ESRCH;
++ if (r < 0)
++       return r;
+@@
+expression f, path, options;
+@@
+- f = fopen(path, options);
+- if (!f)
+-       return errno == ENOENT ? -ESRCH : -errno;
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);
++ r = fopen_unlocked(path, options, &f);
++ if (r == -ENOENT)
++     return -ESRCH;
++ if (r < 0)
++       return r;
+@@
+expression f, path, p;
+@@
+  r = fopen_temporary(path, &f, &p);
+  if (r < 0)
+    return ...;
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);
+@@
+expression f, g, path, p;
+@@
+  r = fopen_temporary_label(path, g, &f, &p);
+  if (r < 0)
+    return ...;
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);
+@@
+expression f, fd, options;
+@@
+- f = fdopen(fd, options);
++ r = fdopen_unlocked(fd, options, &f);
++ if (r < 0) {
+- if (!f) {
+        ...
+-       return -errno;
++       return r;
+  }
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);
+@@
+expression f, buf, sz;
+@@
+- f = open_memstream(&buf, &sz);
++ f = open_memstream_unlocked(&buf, &sz);
+  if (!f)
+        return ...;
+- (void) __fsetlocking(f, FSETLOCKING_BYCALLER);