From e6918187568dbd01842d8d1d2c808ce16a894239 Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Sun, 21 Apr 2024 13:54:28 +0200
Subject: Adding upstream version 18.2.2.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 src/spdk/dpdk/devtools/check-forbidden-tokens.awk | 69 +++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100755 src/spdk/dpdk/devtools/check-forbidden-tokens.awk

(limited to 'src/spdk/dpdk/devtools/check-forbidden-tokens.awk')

diff --git a/src/spdk/dpdk/devtools/check-forbidden-tokens.awk b/src/spdk/dpdk/devtools/check-forbidden-tokens.awk
new file mode 100755
index 000000000..8c89de3d4
--- /dev/null
+++ b/src/spdk/dpdk/devtools/check-forbidden-tokens.awk
@@ -0,0 +1,69 @@
+# SPDX-License-Identifier: BSD-3-Clause
+# Copyright 2018 Arnon Warshavsky <arnon@qwilt.com>
+
+# This awk script receives a list of expressions to monitor
+# and a list of folders to search these expressions in
+# - No search is done inside comments
+# - Both additions and removals of the expressions are checked
+#   A positive balance of additions fails the check
+
+BEGIN {
+	split(FOLDERS,deny_folders," ");
+	split(EXPRESSIONS,deny_expr," ");
+	in_file=0;
+	in_comment=0;
+	count=0;
+	comment_start="/*"
+	comment_end="*/"
+}
+# search for add/remove instances in current file
+# state machine assumes the comments structure is enforced by
+# checkpatches.pl
+(in_file) {
+	# comment start
+	if (index($0,comment_start) > 0) {
+		in_comment = 1
+	}
+	# non comment code
+	if (in_comment == 0) {
+		for (i in deny_expr) {
+			forbidden_added = "^\\+.*" deny_expr[i];
+			forbidden_removed="^-.*" deny_expr[i];
+			current = expressions[deny_expr[i]]
+			if ($0 ~ forbidden_added) {
+				count = count + 1;
+				expressions[deny_expr[i]] = current + 1
+			}
+			if ($0 ~ forbidden_removed) {
+				count = count - 1;
+				expressions[deny_expr[i]] = current - 1
+			}
+		}
+	}
+	# comment end
+	if (index($0,comment_end) > 0) {
+		in_comment = 0
+	}
+}
+# switch to next file , check if the balance of add/remove
+# of previous filehad new additions
+($0 ~ "^\\+\\+\\+ b/") {
+	in_file = 0;
+	if (count > 0) {
+		exit;
+	}
+	for (i in deny_folders) {
+		re = "^\\+\\+\\+ b/" deny_folders[i];
+		if ($0 ~ deny_folders[i]) {
+			in_file = 1
+			last_file = $0
+		}
+	}
+}
+END {
+	if (count > 0) {
+		print "Warning in " substr(last_file,6) ":"
+		print MESSAGE
+		exit RET_ON_FAIL
+	}
+}
-- 
cgit v1.2.3