1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
#! @SHELL@
# -*- shell-script -*-
# ifnames - print the identifiers used in C preprocessor conditionals
# Copyright 2010 Thomas E. Dickey
# Copyright 1994, 1995, 1999, 2000 Free Software Foundation, Inc.
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2, or (at your option)
# any later version.
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.
# Reads from stdin if no files are given.
# Writes to stdout.
# Written by David MacKenzie <djm@gnu.ai.mit.edu>
# and Paul Eggert <eggert@twinsun.com>.
me=`echo "$0" | sed -e 's,.*/,,'`
usage="\
Usage: $0 [OPTION] ... [FILE] ...
Scan all of the C source FILES (or the standard input, if none are
given) and write to the standard output a sorted list of all the
identifiers that appear in those files in \`#if', \`#elif', \`#ifdef', or
\`#ifndef' directives. Print each identifier on a line, followed by a
space-separated list of the files in which that identifier occurs.
-h, --help print this help, then exit
-V, --version print version number, then exit
Report bugs to <@PACKAGE_BUGREPORT@>."
version="\
ifnames (@PACKAGE_NAME@) @VERSION@
Written by David J. MacKenzie and Paul Eggert.
Copyright 1994, 1995, 1999, 2000 Free Software Foundation, Inc.
This is free software; see the source for copying conditions. There is NO
warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE."
help="\
Try \`$me --help' for more information."
while test $# -gt 0; do
case "$1" in
--help | -h )
echo "$usage"; exit 0 ;;
--version | -V )
echo "$version"; exit 0 ;;
--) # Stop option processing.
shift; break ;;
-*)
exec >&2
echo "$me: invalid option $1"
echo "$help"
exit 1 ;;
*) break ;;
esac
done
# Variables.
: ${AWK=@AWK@}
$AWK '
# Record that sym was found in FILENAME.
function file_sym(sym, i, fs)
{
if (sym ~ /^[A-Za-z_]/)
{
if (!found[sym,FILENAME])
{
found[sym,FILENAME] = 1
# Insert FILENAME into files[sym], keeping the list sorted.
i = 1
fs = files[sym]
while (match(substr(fs, i), /^ [^ ]*/) \
&& substr(fs, i + 1, RLENGTH - 1) < FILENAME)
{
i += RLENGTH
}
files[sym] = substr(fs, 1, i - 1) " " FILENAME substr(fs, i)
}
}
}
{
while (sub(/\\$/, "", $0) > 0)
{
if ((getline tmp) > 0)
$0 = $0 tmp
else
break
}
}
/^[\t ]*#/ {
if (sub(/^[\t ]*#[\t ]*ifn?def[\t ]+/, "", $0))
{
sub(/[^A-Za-z_0-9].*/, "", $0)
file_sym($0)
}
if (sub(/^[\t ]*#[\t ]*(el)?if[\t ]+/, "", $0))
{
# Remove comments. Not perfect, but close enough.
gsub(/\/\*[^\/]*(\*\/)?/, "", $0)
for (i = split($0, field, /[^A-Za-z_0-9]+/); 1 <= i; i--)
{
if (field[i] != "defined")
{
file_sym(field[i])
}
}
}
}
END {
for (sym in files)
{
print sym files[sym]
}
}
' ${1+"$@"} | sort
|
