# binaries/spelling -- lintian check script -*- perl -*-

# Copyright (C) 1998 Christian Schwarz and Richard Braakman
# Copyright (C) 2012 Kees Cook
# Copyright (C) 2017-2020 Chris Lamb <lamby@debian.org>
# Copyright (C) 2021 Felix Lechner
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

package Lintian::Check::Binaries::Spelling;

use v5.20;
use warnings;
use utf8;

use Lintian::Spelling qw(check_spelling);

use Moo;
use namespace::clean;

with 'Lintian::Check';

has BINARY_SPELLING_EXCEPTIONS => (
    is => 'rw',
    lazy => 1,
    default => sub {
        my ($self) = @_;

        return $self->data->load('binaries/spelling-exceptions',qr/\s+/);
    }
);

sub spelling_tag_emitter {
    my ($self, $tag_name, $item, @orig_args) = @_;

    return sub {

        my $pointer = $item->pointer($.);

        return $self->pointed_hint($tag_name, $pointer, @orig_args, @_);
    };
}

sub visit_installed_files {
    my ($self, $item) = @_;

    return
      unless $item->is_file;

    return
      unless $item->file_type =~ /^ [^,]* \b ELF \b /x;

    my @acceptable = (
        @{ $self->group->spelling_exceptions },
        $self->BINARY_SPELLING_EXCEPTIONS->all
    );

    my $tag_emitter
      = $self->spelling_tag_emitter('spelling-error-in-binary', $item);

    check_spelling($self->data, $item->strings, \@acceptable, $tag_emitter, 0);

    return;
}

1;

# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et