From 698f8c2f01ea549d77d7dc3338a12e04c11057b9 Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Wed, 17 Apr 2024 14:02:58 +0200
Subject: Adding upstream version 1.64.0+dfsg1.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 src/etc/installer/msi/squash-components.xsl | 34 +++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 src/etc/installer/msi/squash-components.xsl

(limited to 'src/etc/installer/msi/squash-components.xsl')

diff --git a/src/etc/installer/msi/squash-components.xsl b/src/etc/installer/msi/squash-components.xsl
new file mode 100644
index 000000000..17b4e0388
--- /dev/null
+++ b/src/etc/installer/msi/squash-components.xsl
@@ -0,0 +1,34 @@
+<?xml version="1.0" ?>
+<xsl:stylesheet version="1.0"
+        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+        xmlns:wix="http://schemas.microsoft.com/wix/2006/wi">
+    <!-- Copy all attributes and elements to the output. -->
+    <xsl:template match="@*|*">
+        <xsl:copy>
+            <xsl:apply-templates select="@*|*"/>
+        </xsl:copy>
+    </xsl:template>
+    <xsl:output method="xml" indent="yes" />
+
+    <!-- Move all files in directory into first component in that directory. -->
+    <xsl:template match="wix:Component[1]">
+        <xsl:copy>
+            <xsl:apply-templates select="@*|*"/>
+            <xsl:for-each select="../wix:Component[preceding-sibling::*]/wix:File">
+                <xsl:copy>
+                    <!-- Component can only have one KeyPath -->
+                    <xsl:apply-templates select="@*[not(name()='KeyPath')]|*"/>
+                </xsl:copy>
+            </xsl:for-each>
+        </xsl:copy>
+    </xsl:template>
+
+    <!-- Now the rest of components are empty, find them. -->
+    <xsl:key name="empty-cmp-ids" match="wix:Component[preceding-sibling::*]" use="@Id" />
+
+    <!-- And remove. -->
+    <xsl:template match="wix:Component[preceding-sibling::*]" />
+
+    <!-- Also remove componentsrefs referencing empty components. -->
+    <xsl:template match="wix:ComponentRef[key('empty-cmp-ids', @Id)]" />
+</xsl:stylesheet>
-- 
cgit v1.2.3