From 029f72b1a93430b24b88eb3a72c6114d9f149737 Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Wed, 10 Apr 2024 22:09:20 +0200
Subject: Adding upstream version 2:9.1.0016.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 runtime/ftplugin/gdscript.vim | 59 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 runtime/ftplugin/gdscript.vim

(limited to 'runtime/ftplugin/gdscript.vim')

diff --git a/runtime/ftplugin/gdscript.vim b/runtime/ftplugin/gdscript.vim
new file mode 100644
index 0000000..93519d8
--- /dev/null
+++ b/runtime/ftplugin/gdscript.vim
@@ -0,0 +1,59 @@
+vim9script
+
+# Vim filetype plugin file
+# Language: gdscript (Godot game engine scripting language)
+# Maintainer: Maxim Kim <habamax@gmail.com>
+# Website: https://github.com/habamax/vim-gdscript
+
+if exists("b:did_ftplugin") | finish | endif
+
+b:did_ftplugin = 1
+b:undo_ftplugin = 'setlocal cinkeys<'
+      \ .. '| setlocal indentkeys<'
+      \ .. '| setlocal commentstring<'
+      \ .. '| setlocal suffixesadd<'
+      \ .. '| setlocal foldexpr<'
+      \ .. '| setlocal foldignore<'
+
+setlocal cinkeys-=0#
+setlocal indentkeys-=0#
+setlocal suffixesadd=.gd
+setlocal commentstring=#\ %s
+setlocal foldignore=
+setlocal foldexpr=GDScriptFoldLevel()
+
+
+def GDScriptFoldLevel(): string
+    var line = getline(v:lnum)
+    if line =~? '^\s*$'
+        return "-1"
+    endif
+
+    var sw = shiftwidth()
+    var indent = indent(v:lnum) / sw
+    var indent_next = indent(nextnonblank(v:lnum + 1)) / sw
+
+    if indent_next > indent && line =~ ':\s*$'
+        return $">{indent_next}"
+    else
+        return $"{indent}"
+    endif
+enddef
+
+
+if !exists("g:no_plugin_maps")
+    # Next/Previous section
+    def NextSection(back: bool, cnt: number)
+        for n in range(cnt)
+            search('^\s*func\s', back ? 'bW' : 'W')
+        endfor
+    enddef
+
+    nnoremap <silent><buffer> ]] <scriptcmd>NextSection(false, v:count1)<CR>
+    nnoremap <silent><buffer> [[ <scriptcmd>NextSection(true, v:count1)<CR>
+    xmap <buffer><expr> ]] $'<C-\><C-N>{v:count1}]]m>gv'
+    xmap <buffer><expr> [[ $'<C-\><C-N>{v:count1}[[m>gv'
+    b:undo_ftplugin ..=
+          \    " | silent exe 'unmap <buffer> [['"
+          \ .. " | silent exe 'unmap <buffer> ]]'"
+endif
-- 
cgit v1.2.3