Adding upstream version 7.0.14-dfsg.upstream/7.0.14-dfsg

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
author: Daniel Baumann <daniel.baumann@progress-linux.org> 2024-04-11 08:17:27 +0000
committer: Daniel Baumann <daniel.baumann@progress-linux.org> 2024-04-11 08:17:27 +0000
commit: f215e02bf85f68d3a6106c2a1f4f7f063f819064 (patch)
tree: 6bb5b92c046312c4e95ac2620b10ddf482d3fa8b /src/VBox/Installer/win/Scripts
parent: Initial commit. (diff)
download: virtualbox-f215e02bf85f68d3a6106c2a1f4f7f063f819064.tar.xz
virtualbox-f215e02bf85f68d3a6106c2a1f4f7f063f819064.zip
11 files changed, 2480 insertions, 0 deletions
diff --git a/src/VBox/Installer/win/Scripts/Combined-1-Prepare.cmd b/src/VBox/Installer/win/Scripts/Combined-1-Prepare.cmd
new file mode 100644
index 00000000..9aac4967
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/Combined-1-Prepare.cmd
@@ -0,0 +1,314 @@
+@echo off
+rem $Id: Combined-1-Prepare.cmd $
+rem rem @file
+rem Windows NT batch script for preparing both amd64 and x86 for signing submission.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Globals and checks for required enviornment variables.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+if ".%KBUILD_BIN_PATH%" == "." (echo KBUILD_BIN_PATH is not set & goto end_failed)
+set _MY_SCRIPT_DIR=%~dp0
+set _MY_SAVED_CD=%CD%
+set _MY_VER_REV=@VBOX_VERSION_STRING@r@VBOX_SVN_REV@
+set _MY_PACK_EXTPACK=1
+set _MY_PACK_ADDITIONS=0
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_UNTAR_DIR=%_MY_SCRIPT_DIR%\..\..\..
+for %%i in (%_MY_OPT_UNTAR_DIR%) do set _MY_OPT_UNTAR_DIR=%%~fi
+set _MY_OPT_EXTPACK=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%.vbox-extpack
+set _MY_OPT_EXTPACK_ENTERPRISE=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%-ENTERPRISE.vbox-extpack
+set _MY_OPT_BUILD_TYPE=@KBUILD_TYPE@
+set _MY_OPT_OUTDIR=%_MY_OPT_UNTAR_DIR%\output
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-g"                   goto opt_g
+if ".%1" == ".--additions"          goto opt_g
+if ".%1" == ".-e"                   goto opt_e
+if ".%1" == ".--extpack"            goto opt_e
+if ".%1" == ".--no-extpack"         goto opt_ne
+if ".%1" == ".-o"                   goto opt_o
+if ".%1" == ".--outdir"             goto opt_o
+if ".%1" == ".-s"                   goto opt_s
+if ".%1" == ".--extpack-enterprise" goto opt_s
+if ".%1" == ".-t"                   goto opt_t
+if ".%1" == ".--build-type"         goto opt_t
+if ".%1" == ".-u"                   goto opt_u
+if ".%1" == ".--vboxall-untar-dir"  goto opt_u
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_g
+set _MY_PACK_ADDITIONS=1
+shift
+goto argument_loop
+
+:opt_e
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK=%~f2
+goto argument_loop_next_with_value
+
+:opt_ne
+set _MY_PACK_EXTPACK=0
+shift
+goto argument_loop
+
+:opt_h
+echo Toplevel combined package: Prepare both x86 and amd64 for submission.
+echo .
+echo Usage: Combined-1-Prepare.cmd [-o output-dir] [-e/--extpack puel.vbox-extpack]
+echo            [-s/--extpack-enterprise puel-enterprise.vbox-extpack]
+echo            [--no-extpack] [-g/--additions]
+echo            [-u/--vboxall-dir unpacked-vboxall-dir] [-t build-type]
+echo .
+echo Default -e/--extpack value:            %_MY_OPT_EXTPACK%
+echo Default -s/--extpack-enterprise value: %_MY_OPT_EXTPACK_ENTERPRISE%
+echo Default -u/--vboxall-untar-dir value:  %_MY_OPT_UNTAR_DIR%
+echo Default -o/--outdir value:             %_MY_OPT_OUTDIR%
+echo Default -t/--build-type value:         %_MY_OPT_BUILD_TYPE%
+echo .
+goto end_failed
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTDIR=%~f2
+goto argument_loop_next_with_value
+
+:opt_s
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK_ENTERPRISE=%~f2
+goto argument_loop_next_with_value
+
+:opt_t
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BUILD_TYPE=%~2
+goto argument_loop_next_with_value
+
+:opt_u
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_UNTAR_DIR=%~f2
+goto argument_loop_next_with_value
+
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+
+:error_vboxall_untar_dir_not_found
+echo syntax error: The VBoxAll untar directory was not found: "%_MY_OPT_UNTAR_DIR%"
+goto end_failed
+
+:error_amd64_bindir_not_found
+echo syntax error: The AMD64 bin directory was not found: "%_MY_BINDIR_AMD64%"
+goto end_failed
+
+:error_x86_bindir_not_found
+echo syntax error: The X86 bin directory was not found: "%_MY_BINDIR_X86%"
+goto end_failed
+
+:error_amd64_repack_dir_not_found
+echo syntax error: The AMD64 repack directory was not found: "%_MY_REPACK_DIR_AMD64%"
+goto end_failed
+
+:error_x86_repack_dir_not_found
+echo syntax error: The X86 repack directory was not found: "%_MY_REPACK_DIR_X86%"
+goto end_failed
+
+:error_extpack_not_found
+echo syntax error: Specified extension pack not found: "%_MY_OPT_EXTPACK%"
+goto end_failed
+
+:error_enterprise_extpack_not_found
+echo syntax error: Specified enterprise extension pack not found: "%_MY_OPT_EXTPACK_ENTERPRISE%"
+goto end_failed
+
+:error_extpack_and_additions_together
+echo usage error: You can't prepare extPack and GuestAdditions in one call
+goto end_failed
+
+:no_more_arguments
+rem
+rem Validate and adjust specified options.
+rem
+
+if not exist "%_MY_OPT_UNTAR_DIR%"      goto error_vboxall_untar_dir_not_found
+
+set _MY_BINDIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\bin
+set _MY_BINDIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\bin
+if not exist "%_MY_BINDIR_AMD64%"       goto error_amd64_bindir_not_found
+if not exist "%_MY_BINDIR_X86%"         goto error_x86_bindir_not_found
+
+if ".%_MY_PACK_EXTPACK%" == ".%_MY_PACK_ADDITIONS%" goto error_extpack_and_additions_together
+
+set _MY_REPACK_DIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\repack
+set _MY_REPACK_DIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\repack
+if ".%_MY_PACK_ADDITIONS%" == ".0" goto skip_additions_packing_options
+set _MY_REPACK_DIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\repackadd
+set _MY_REPACK_DIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\repackadd
+:skip_additions_packing_options
+if not exist "%_MY_REPACK_DIR_AMD64%"   goto error_amd64_repack_dir_not_found
+if not exist "%_MY_REPACK_DIR_X86%"     goto error_x86_repack_dir_not_found
+
+rem Make sure the output dir exists.
+if not exist "%_MY_OPT_OUTDIR%"     (mkdir "%_MY_OPT_OUTDIR%" || goto end_failed)
+
+rem
+rem ExtPack section
+rem
+if ".%_MY_PACK_EXTPACK%" == ".0" goto skip_extpack_packing
+
+if not exist "%_MY_OPT_EXTPACK%"        goto error_extpack_not_found
+if not ".%_MY_OPT_EXTPACK_ENTERPRISE%" == "." if not exist "%_MY_OPT_EXTPACK_ENTERPRISE%" goto error_enterprise_extpack_not_found
+
+rem
+rem Install the extpack in the bin directories.
+rem Note! Not really necessary, but whatever.
+rem
+echo on
+copy /y "%_MY_OPT_EXTPACK%" "%_MY_BINDIR_AMD64%\Oracle_VM_VirtualBox_Extension_Pack.vbox-extpack" || goto end_failed
+copy /y "%_MY_OPT_EXTPACK%"   "%_MY_BINDIR_X86%\Oracle_VM_VirtualBox_Extension_Pack.vbox-extpack" || goto end_failed
+@echo off
+
+rem
+rem Do the packing of ExtPack
+rem
+echo **************************************************************************
+echo Packing AMD64 drivers
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_AMD64%" || goto end_failed
+call "%_MY_REPACK_DIR_AMD64%\PackDriversForSubmission.cmd" -b "%_MY_BINDIR_AMD64%" -a amd64 -e "%_MY_OPT_EXTPACK%" ^
+    -o "%_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-amd64.cab" || goto end_failed
+echo .
+echo **************************************************************************
+echo Packing X86 drivers
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+call "%_MY_REPACK_DIR_X86%\PackDriversForSubmission.cmd" -b "%_MY_BINDIR_X86%" -a x86 -e "%_MY_OPT_EXTPACK%" ^
+    -o "%_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-x86.cab" || goto end_failed
+echo .
+cd /d "%_MY_SAVED_CD%"
+:skip_extpack_packing
+
+rem
+rem GuestAdditions section
+rem
+if ".%_MY_PACK_ADDITIONS%" == ".0" goto skip_additions_packing
+
+rem
+rem Do the packing of GuestAdditions
+rem
+echo **************************************************************************
+echo Packing AMD64 additions
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_AMD64%" || goto end_failed
+call "%_MY_REPACK_DIR_AMD64%\PackDriversForSubmission.cmd" -b "%_MY_BINDIR_AMD64%" -a amd64 -x -n --no-main --ga ^
+    -o "%_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-amd64.cab" || goto end_failed
+echo .
+echo **************************************************************************
+echo Packing X86 drivers
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+call "%_MY_REPACK_DIR_X86%\PackDriversForSubmission.cmd" -b "%_MY_BINDIR_X86%" -a x86 -x -n --no-main --ga ^
+    -o "%_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-x86.cab" || goto end_failed
+echo .
+cd /d "%_MY_SAVED_CD%"
+:skip_additions_packing
+
+rem
+rem Generate script for taking the next step.
+rem
+set _MY_NEXT_SCRIPT_SHORT_NAME=Combined-3-Repack.cmd
+set _MY_NEXT_SCRIPT=%_MY_OPT_OUTDIR%\%_MY_NEXT_SCRIPT_SHORT_NAME%
+if ".%_MY_PACK_ADDITIONS%" == ".0" goto generate_legacy_script
+set _MY_NEXT_SCRIPT_SHORT_NAME=Combined-3-RepackAdditions.cmd
+set _MY_NEXT_SCRIPT=%_MY_OPT_OUTDIR%\%_MY_NEXT_SCRIPT_SHORT_NAME%
+echo cd /d "%cd%" > "%_MY_NEXT_SCRIPT%"
+echo call "%_MY_SCRIPT_DIR%%_MY_NEXT_SCRIPT_SHORT_NAME%" ^
+    --vboxall-untar-dir "%_MY_OPT_UNTAR_DIR%" ^
+    --outdir "%_MY_OPT_OUTDIR%" ^
+    --build-type "%_MY_OPT_BUILD_TYPE%" %%* >> "%_MY_NEXT_SCRIPT%"
+goto show_next_steps
+:generate_legacy_script
+echo cd /d "%cd%" > "%_MY_NEXT_SCRIPT%"
+echo call "%_MY_SCRIPT_DIR%%_MY_NEXT_SCRIPT_SHORT_NAME%" --extpack "%_MY_OPT_EXTPACK%" ^
+    --extpack-enterprise "%_MY_OPT_EXTPACK_ENTERPRISE%" ^
+    --vboxall-untar-dir "%_MY_OPT_UNTAR_DIR%" ^
+    --outdir "%_MY_OPT_OUTDIR%" ^
+    %_MY_OPT_SCRIPT_SKIPEXTPACK_PARAM% %_MY_OPT_SCRIPT_ADDITIONS_PARAM% ^
+    --build-type "%_MY_OPT_BUILD_TYPE%" %%* >> "%_MY_NEXT_SCRIPT%"
+
+:show_next_steps
+rem
+rem Instructions on what to do next.
+rem
+echo **************************************************************************
+echo * First step is done.
+echo *
+echo * Created:
+echo *     %_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-amd64.cab
+echo *     %_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-x86.cab
+echo *
+echo * Next steps:
+echo *   1. Submit the files to Microsoft for attestation signing.
+echo *   2. Download the signed result.
+echo *   3. "%_MY_NEXT_SCRIPT%" --signed-x86 {zip} --signed-amd64 {zip} %_MY_OPT_SCRIPT_SKIPEXTPACK_PARAM% %_MY_OPT_SCRIPT_ADDITIONAL_PARAMS%
+goto end
+:end_failed
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+@echo * Failed!
+@exit /b 1
+
+:end
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+
diff --git a/src/VBox/Installer/win/Scripts/Combined-3-Repack.cmd b/src/VBox/Installer/win/Scripts/Combined-3-Repack.cmd
new file mode 100644
index 00000000..2886cdbf
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/Combined-3-Repack.cmd
@@ -0,0 +1,349 @@
+@echo off
+rem $Id: Combined-3-Repack.cmd $
+rem rem @file
+rem Windows NT batch script for repacking signed amd64 and x86 drivers.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Globals and checks for required enviornment variables.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+if ".%KBUILD_BIN_PATH%" == "." (echo KBUILD_BIN_PATH is not set & goto end_failed)
+set _MY_SCRIPT_DIR=%~dp0
+set _MY_SAVED_CD=%CD%
+set _MY_VER_REV=@VBOX_VERSION_STRING@r@VBOX_SVN_REV@
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_UNTAR_DIR=%_MY_SCRIPT_DIR%\..\..\..\
+for %%i in (%_MY_OPT_UNTAR_DIR%) do set _MY_OPT_UNTAR_DIR=%%~fi
+set _MY_OPT_EXTPACK=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%.vbox-extpack
+set _MY_OPT_EXTPACK_ENTERPRISE=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%-ENTERPRISE.vbox-extpack
+set _MY_OPT_BUILD_TYPE=@KBUILD_TYPE@
+set _MY_OPT_OUTDIR=%_MY_OPT_UNTAR_DIR%\output
+set _MY_OPT_SIGNED_AMD64=
+set _MY_OPT_SIGNED_X86=
+set _MY_OPT_NOEXTPACK=
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-e"                   goto opt_e
+if ".%1" == ".--extpack"            goto opt_e
+if ".%1" == ".-n"                   goto opt_n
+if ".%1" == ".--no-extpack"         goto opt_n
+if ".%1" == ".-o"                   goto opt_o
+if ".%1" == ".--outdir"             goto opt_o
+if ".%1" == ".-s"                   goto opt_s
+if ".%1" == ".--extpack-enterprise" goto opt_s
+if ".%1" == ".--signed-amd64"       goto opt_signed_amd64
+if ".%1" == ".--signed-x86"         goto opt_signed_x86
+if ".%1" == ".-t"                   goto opt_t
+if ".%1" == ".--build-type"         goto opt_t
+if ".%1" == ".-u"                   goto opt_u
+if ".%1" == ".--vboxall-untar-dir"  goto opt_u
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_e
+if ".%~2" == "."             goto syntax_error_missing_value
+set _MY_OPT_EXTPACK=%~f2
+goto argument_loop_next_with_value
+
+:opt_h
+echo Toplevel combined package: Repack the installer and extpacks.
+echo .
+echo Usage: Combined-3-Repack.cmd [-o output-dir] [-e/--extpack puel.vbox-extpack]
+echo            [-s/--extpack-enterprise puel-enterprise.vbox-extpack]
+echo            [-u/--vboxall-dir unpacked-vboxall-dir] [-t build-type]
+echo            [--signed-amd64 signed-amd64.zip]
+echo            [--signed-x86 signed-x86.zip]
+echo
+echo .
+echo Default -e/--extpack value:            %_MY_OPT_EXTPACK%
+echo Default -s/--extpack-enterprise value: %_MY_OPT_EXTPACK_ENTERPRISE%
+echo Default -u/--vboxall-untar-dir value:  %_MY_OPT_UNTAR_DIR%
+echo Default -o/--outdir value:             %_MY_OPT_OUTDIR%
+echo Default -t/--build-type value:         %_MY_OPT_BUILD_TYPE%
+echo .
+goto end_failed
+
+:opt_n
+set _MY_OPT_NOEXTPACK=1
+shift
+goto argument_loop
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTDIR=%~f2
+goto argument_loop_next_with_value
+
+:opt_s
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK_ENTERPRISE=%~f2
+goto argument_loop_next_with_value
+
+:opt_signed_amd64
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_SIGNED_AMD64=%~f2
+goto argument_loop_next_with_value
+
+:opt_signed_x86
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_SIGNED_X86=%~f2
+goto argument_loop_next_with_value
+
+:opt_t
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BUILD_TYPE=%~2
+goto argument_loop_next_with_value
+
+:opt_u
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_UNTAR_DIR=%~f2
+goto argument_loop_next_with_value
+
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+
+:error_vboxall_untar_dir_not_found
+echo syntax error: The VBoxAll untar directory was not found: "%_MY_OPT_UNTAR_DIR%"
+goto end_failed
+
+:error_amd64_bindir_not_found
+echo syntax error: The AMD64 bin directory was not found: "%_MY_BINDIR_AMD64%"
+goto end_failed
+
+:error_x86_bindir_not_found
+echo syntax error: The X86 bin directory was not found: "%_MY_BINDIR_X86%"
+goto end_failed
+
+:error_amd64_repack_dir_not_found
+echo syntax error: The AMD64 repack directory was not found: "%_MY_REPACK_DIR_AMD64%"
+goto end_failed
+
+:error_x86_repack_dir_not_found
+echo syntax error: The X86 repack directory was not found: "%_MY_REPACK_DIR_X86%"
+goto end_failed
+
+:error_extpack_not_found
+echo syntax error: Specified extension pack not found: "%_MY_OPT_EXTPACK%"
+goto end_failed
+
+:error_enterprise_extpack_not_found
+echo syntax error: Specified enterprise extension pack not found: "%_MY_OPT_EXTPACK_ENTERPRISE%"
+goto end_failed
+
+:error_signed_amd64_not_found
+echo syntax error: Zip with signed AMD64 drivers not found: "%_MY_OPT_SIGNED_AMD64%"
+goto end_failed
+
+:error_signed_x86_not_found
+echo syntax error: Zip with signed X86 drivers not found: "%_MY_OPT_SIGNED_X86%"
+goto end_failed
+
+
+:no_more_arguments
+rem
+rem Validate and adjust specified options.
+rem
+
+if not exist "%_MY_OPT_UNTAR_DIR%"      goto error_vboxall_untar_dir_not_found
+
+set _MY_BINDIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\bin
+set _MY_BINDIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\bin
+if not exist "%_MY_BINDIR_AMD64%"       goto error_amd64_bindir_not_found
+if not exist "%_MY_BINDIR_X86%"         goto error_x86_bindir_not_found
+
+set _MY_REPACK_DIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\repack
+set _MY_REPACK_DIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\repack
+if not exist "%_MY_REPACK_DIR_AMD64%"   goto error_amd64_repack_dir_not_found
+if not exist "%_MY_REPACK_DIR_X86%"     goto error_x86_repack_dir_not_found
+
+if ".%_MY_OPT_NOEXTPACK%" == ".1"       goto no_enterprise_check
+if not exist "%_MY_OPT_EXTPACK%"        goto error_extpack_not_found
+if not ".%_MY_OPT_EXTPACK_ENTERPRISE%" == "." if not exist "%_MY_OPT_EXTPACK_ENTERPRISE%" goto error_enterprise_extpack_not_found
+:no_enterprise_check
+
+if not exist "%_MY_OPT_SIGNED_AMD64%"   goto error_signed_amd64_not_found
+if not exist "%_MY_OPT_SIGNED_X86%"     goto error_signed_x86_not_found
+
+rem Make sure the output dir exists.
+if not exist "%_MY_OPT_OUTDIR%"     (mkdir "%_MY_OPT_OUTDIR%" || goto end_failed)
+
+rem
+rem Unpacking the two driver zips.
+rem
+echo **************************************************************************
+echo * AMD64: Unpacking signed drivers...
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_AMD64%" || goto end_failed
+call "%_MY_REPACK_DIR_AMD64%\UnpackBlessedDrivers.cmd" -n -b "%_MY_BINDIR_AMD64%" -i "%_MY_OPT_SIGNED_AMD64%" || goto end_failed
+echo .
+
+echo **************************************************************************
+echo * X86: Unpacking signed drivers...
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+call "%_MY_REPACK_DIR_X86%\UnpackBlessedDrivers.cmd" -n -b "%_MY_BINDIR_X86%" -i "%_MY_OPT_SIGNED_X86%" || goto end_failed
+echo .
+
+
+rem
+rem Do the AMD64 work.
+rem
+echo **************************************************************************
+echo * AMD64: Repackaging installers
+echo **************************************************************************
+echo * AMD64: Compiling WIX...
+cd /d "%_MY_REPACK_DIR_AMD64%" || goto end_failed
+for %%i in (1-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * AMD64: Linking WIX...
+for %%i in (2-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * AMD64: Applying language patches to MSI...
+for %%i in (3-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+
+rem
+rem Do the X86 work.
+rem
+echo **************************************************************************
+echo * X86: Repackaging installers
+echo **************************************************************************
+echo * X86: Compiling WIX...
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+for %%i in (1-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * X86: Linking WIX...
+for %%i in (2-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * X86: Applying language patches to MSI...
+for %%i in (3-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * X86: Creating multi arch installer...
+for %%i in (4-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+set _MY_OUT_FILES=
+cd /d "%_MY_REPACK_DIR_AMD64%" || goto end_failed
+for %%i in (VBoxMerge*msm) do (
+    copy /y "%%i" "%_MY_OPT_OUTDIR%" || goto end_failed
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+for %%i in (VBoxMerge*msm) do (
+    copy /y "%%i" "%_MY_OPT_OUTDIR%" || goto end_failed
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+for %%i in (VirtualBox-*MultiArch*exe) do (
+    copy /y "%%i" "%_MY_OPT_OUTDIR%" || goto end_failed
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+
+if ".%_MY_OPT_NOEXTPACK%" == ".1" goto no_enterprise_repacking
+
+rem
+rem Repack the extension packs.
+rem
+echo **************************************************************************
+echo * Repacking extension packs.
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+
+echo * Regular PUEL...
+set _MY_TMP_OUT=%_MY_OPT_EXTPACK%
+for %%i in (%_MY_TMP_OUT%) do (
+    set _MY_TMP_OUT=%_MY_OPT_OUTDIR%\%%~nxi
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+call "%_MY_REPACK_DIR_X86%\RepackExtPack.cmd" --bindir-amd64 "%_MY_BINDIR_AMD64%" --bindir-x86 "%_MY_BINDIR_X86%" ^
+    --input "%_MY_OPT_EXTPACK%" --output "%_MY_TMP_OUT%" || goto end_failed
+
+if ".%_MY_OPT_EXTPACK_ENTERPRISE%" == "." goto no_enterprise_repacking
+echo * Enterprise PUEL...
+set _MY_TMP_OUT=%_MY_OPT_EXTPACK_ENTERPRISE%
+for %%i in (%_MY_TMP_OUT%) do (
+    set _MY_TMP_OUT=%_MY_OPT_OUTDIR%\%%~nxi
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+call "%_MY_REPACK_DIR_X86%\RepackExtPack.cmd" --bindir-amd64 "%_MY_BINDIR_AMD64%" --bindir-x86 "%_MY_BINDIR_X86%" ^
+    --input "%_MY_OPT_EXTPACK_ENTERPRISE%" --output "%_MY_TMP_OUT%" || goto end_failed
+:no_enterprise_repacking
+@cd /d "%_MY_SAVED_CD%"
+
+rem
+rem That's that.
+rem
+echo **************************************************************************
+echo * The third and final step is done.
+echo *
+echo * Successfully created:
+for %%i in (%_MY_OUT_FILES%) do echo *    "%_MY_OPT_OUTDIR%\%%i"
+goto end
+
+
+:end_failed
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+@echo * Failed!
+@exit /b 1
+
+:end
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+
+
diff --git a/src/VBox/Installer/win/Scripts/Combined-3-RepackAdditions.cmd b/src/VBox/Installer/win/Scripts/Combined-3-RepackAdditions.cmd
new file mode 100644
index 00000000..a4238563
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/Combined-3-RepackAdditions.cmd
@@ -0,0 +1,370 @@
+@echo off
+rem $Id: Combined-3-RepackAdditions.cmd $
+rem rem @file
+rem Windows NT batch script for repacking signed amd64 and x86 drivers.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Globals and checks for required enviornment variables.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+if ".%KBUILD_BIN_PATH%" == "." (echo KBUILD_BIN_PATH is not set & goto end_failed)
+set _MY_SCRIPT_DIR=%~dp0
+set _MY_SAVED_CD=%CD%
+set _MY_VER_REV=@VBOX_VERSION_STRING@r@VBOX_SVN_REV@
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_UNTAR_DIR=%_MY_SCRIPT_DIR%\..\..\..\
+for %%i in (%_MY_OPT_UNTAR_DIR%) do set _MY_OPT_UNTAR_DIR=%%~fi
+set _MY_OPT_BUILD_TYPE=@KBUILD_TYPE@
+set _MY_OPT_OUTDIR=%_MY_OPT_UNTAR_DIR%\output
+set _MY_OPT_SRC_DIR=%_MY_SCRIPT_DIR%\resources\
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-o"                   goto opt_o
+if ".%1" == ".--outdir"             goto opt_o
+if ".%1" == ".-s"                   goto opt_s
+if ".%1" == ".--source"             goto opt_s
+if ".%1" == ".--signed-amd64"       goto opt_signed_amd64
+if ".%1" == ".--signed-x86"         goto opt_signed_x86
+if ".%1" == ".-t"                   goto opt_t
+if ".%1" == ".--build-type"         goto opt_t
+if ".%1" == ".-u"                   goto opt_u
+if ".%1" == ".--vboxall-untar-dir"  goto opt_u
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_h
+echo Toplevel combined package: Repack the guest additions.
+echo .
+echo Usage: Combined-3-RepackAdditions.cmd [-o output-dir]
+echo            [-u/--vboxall-dir unpacked-vboxall-dir] [-t build-type]
+echo            [--signed-amd64 signed-amd64.zip]
+echo            [--signed-x86 signed-x86.zip]
+echo
+echo .
+echo Default -u/--vboxall-untar-dir value:  %_MY_OPT_UNTAR_DIR%
+echo Default -o/--outdir value:             %_MY_OPT_OUTDIR%
+echo Default -t/--build-type value:         %_MY_OPT_BUILD_TYPE%
+echo .
+goto end_failed
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTDIR=%~f2
+goto argument_loop_next_with_value
+
+:opt_s
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_SRC_DIR=%~f2
+goto argument_loop_next_with_value
+
+:opt_signed_amd64
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_SIGNED_AMD64=%~f2
+goto argument_loop_next_with_value
+
+:opt_signed_x86
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_SIGNED_X86=%~f2
+goto argument_loop_next_with_value
+
+:opt_t
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BUILD_TYPE=%~2
+goto argument_loop_next_with_value
+
+:opt_u
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_UNTAR_DIR=%~f2
+goto argument_loop_next_with_value
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+:error_vboxall_untar_dir_not_found
+echo syntax error: The VBoxAll untar directory was not found: "%_MY_OPT_UNTAR_DIR%"
+goto end_failed
+
+:error_amd64_bindir_not_found
+echo syntax error: The AMD64 bin directory was not found: "%_MY_BINDIR_AMD64%"
+goto end_failed
+
+:error_x86_bindir_not_found
+echo syntax error: The X86 bin directory was not found: "%_MY_BINDIR_X86%"
+goto end_failed
+
+:error_amd64_repack_dir_not_found
+echo syntax error: The AMD64 repack directory was not found: "%_MY_REPACK_DIR_AMD64%"
+goto end_failed
+
+:error_x86_repack_dir_not_found
+echo syntax error: The X86 repack directory was not found: "%_MY_REPACK_DIR_X86%"
+goto end_failed
+
+:error_extpack_not_found
+echo syntax error: Specified extension pack not found: "%_MY_OPT_EXTPACK%"
+goto end_failed
+
+:error_enterprise_extpack_not_found
+echo syntax error: Specified enterprise extension pack not found: "%_MY_OPT_EXTPACK_ENTERPRISE%"
+goto end_failed
+
+:error_signed_amd64_not_found
+echo syntax error: Zip with signed AMD64 drivers not found: "%_MY_OPT_SIGNED_AMD64%"
+goto end_failed
+
+:error_signed_x86_not_found
+echo syntax error: Zip with signed X86 drivers not found: "%_MY_OPT_SIGNED_X86%"
+goto end_failed
+
+:error_src_dir_not_found
+echo syntax error: src directory not found: "%_MY_OPT_SRC_DIR%"
+goto end_failed
+
+
+:no_more_arguments
+rem
+rem Validate and adjust specified options.
+rem
+
+if not exist "%_MY_OPT_UNTAR_DIR%"      goto error_vboxall_untar_dir_not_found
+
+set _MY_BINDIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\bin\additions
+set _MY_BINDIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\bin\additions
+if not exist "%_MY_BINDIR_AMD64%"       goto error_amd64_bindir_not_found
+if not exist "%_MY_BINDIR_X86%"         goto error_x86_bindir_not_found
+
+set _MY_REPACK_DIR_AMD64=%_MY_OPT_UNTAR_DIR%\win.amd64\%_MY_OPT_BUILD_TYPE%\repackadd
+set _MY_REPACK_DIR_X86=%_MY_OPT_UNTAR_DIR%\win.x86\%_MY_OPT_BUILD_TYPE%\repackadd
+if not exist "%_MY_REPACK_DIR_AMD64%"   goto error_amd64_repack_dir_not_found
+if not exist "%_MY_REPACK_DIR_X86%"     goto error_x86_repack_dir_not_found
+
+if not ".%_MY_OPT_SIGNED_AMD64%" == "." goto skip_set_default_amd64_signed
+set _MY_OPT_SIGNED_AMD64="%_MY_OPT_OUTDIR%/VBoxDrivers-@VBOX_VERSION_STRING@r@VBOX_SVN_REV@-amd64.cab.Signed.zip"
+:skip_set_default_amd64_signed
+
+if not ".%_MY_OPT_SIGNED_X86%" == "." goto skip_set_default_x86_signed
+set _MY_OPT_SIGNED_X86="%_MY_OPT_OUTDIR%/VBoxDrivers-@VBOX_VERSION_STRING@r@VBOX_SVN_REV@-x86.cab.Signed.zip"
+:skip_set_default_x86_signed
+
+if not exist "%_MY_OPT_SIGNED_AMD64%"   goto error_signed_amd64_not_found
+if not exist "%_MY_OPT_SIGNED_X86%"     goto error_signed_x86_not_found
+
+rem Make sure the output dir exists.
+if not exist "%_MY_OPT_OUTDIR%"     (mkdir "%_MY_OPT_OUTDIR%" || goto end_failed)
+
+if not exist "%_MY_OPT_SRC_DIR%"              goto error_src_dir_not_found
+
+rem
+rem Unpacking the two driver zips.
+rem
+echo **************************************************************************
+echo * AMD64: Unpacking signed drivers...
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_AMD64%" || goto end_failed
+call "%_MY_REPACK_DIR_AMD64%\UnpackBlessedDrivers.cmd" -n -b "%_MY_BINDIR_AMD64%" -i "%_MY_OPT_SIGNED_AMD64%" --guest-additions || goto end_failed
+echo .
+
+echo **************************************************************************
+echo * X86: Unpacking signed drivers...
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR_X86%" || goto end_failed
+call "%_MY_REPACK_DIR_X86%\UnpackBlessedDrivers.cmd" -n -b "%_MY_BINDIR_X86%" -i "%_MY_OPT_SIGNED_X86%" --guest-additions || goto end_failed
+echo .
+
+
+rem
+rem Building amd64 installer
+rem
+echo **************************************************************************
+echo * Building amd64 installer
+echo **************************************************************************
+
+del %_MY_OPT_UNTAR_DIR%\win.amd64\release\bin\additions\VBoxWindowsAdditions-amd64.exe
+cp %_MY_REPACK_DIR_AMD64%\..\obj\uninst.exe %_MY_REPACK_DIR_AMD64%
+
+rem TBD: that has to be converted to invoke auto-generated .cmd
+
+%KBUILD_BIN_PATH%\kmk_redirect.exe -C %_MY_OPT_SRC_DIR% ^
+        -E "PATH_OUT=%_MY_REPACK_DIR_AMD64%\.." ^
+        -E "PATH_TARGET=%_MY_REPACK_DIR_AMD64%" ^
+        -E "PATH_TARGET_X86=%_MY_REPACK_DIR_X86%\resources" ^
+        -E "VBOX_PATH_ADDITIONS_WIN_X86=%_MY_REPACK_DIR_AMD64%\..\bin\additions" ^
+        -E "VBOX_PATH_DIFX=%KBUILD_DEVTOOLS%\win.amd64\DIFx\v2.1-r3" ^
+        -E "VBOX_VENDOR=Oracle Corporation" -E "VBOX_VENDOR_SHORT=Oracle" -E "VBOX_PRODUCT=Oracle VM VirtualBox" ^
+        -E "VBOX_C_YEAR=@VBOX_C_YEAR@" -E "VBOX_VERSION_STRING=@VBOX_VERSION_STRING@" -E "VBOX_VERSION_STRING_RAW=@VBOX_VERSION_STRING_RAW@" ^
+        -E "VBOX_VERSION_MAJOR=@VBOX_VERSION_MAJOR@" -E "VBOX_VERSION_MINOR=@VBOX_VERSION_MINOR@" -E "VBOX_VERSION_BUILD=@VBOX_VERSION_BUILD@" -E "VBOX_SVN_REV=@VBOX_SVN_REV@" ^
+        -E "VBOX_WINDOWS_ADDITIONS_ICON_FILE=%_MY_OPT_SRC_DIR%\VirtualBoxGA-vista.ico" ^
+        -E "VBOX_NSIS_ICON_FILE=%_MY_OPT_SRC_DIR%\VirtualBoxGA-nsis.ico" ^
+        -E "VBOX_WITH_GUEST_INSTALL_HELPER=1" -E "VBOX_WITH_GUEST_INSTALLER_UNICODE=1" -E "VBOX_WITH_LICENSE_INSTALL_RTF=1" ^
+        -E "VBOX_WITH_WDDM=1" -E "VBOX_WITH_MESA3D=1" -E "VBOX_BRAND_WIN_ADD_INST_DLGBMP=%_MY_OPT_SRC_DIR%\welcome.bmp" ^
+        -E "VBOX_BRAND_LICENSE_RTF=%_MY_OPT_SRC_DIR%\License-gpl-3.0.rtf"  -E "KBUILD_TYPE=%_MY_OPT_BUILD_TYPE%" -E "KBUILD_TARGET_ARCH=amd64" ^
+        --  %KBUILD_DEVTOOLS%/win.x86/nsis/v3.04-log/makensis.exe /NOCD /V2 ^
+                "/DVBOX_SIGN_ADDITIONS=1" ^
+                "/DEXTERNAL_UNINSTALLER=1" ^
+                "%_MY_OPT_SRC_DIR%\VBoxGuestAdditions.nsi"
+
+rem
+rem Building amd64 installer
+rem
+echo **************************************************************************
+echo * Building x86 installer
+echo **************************************************************************
+
+del %_MY_OPT_UNTAR_DIR%\win.x86\release\bin\additions\VBoxWindowsAdditions-x86.exe
+cp %_MY_REPACK_DIR_X86%\..\obj\uninst.exe %_MY_REPACK_DIR_X86%\
+
+rem TBD: that has to be converted to invoke auto-generated .cmd
+
+%KBUILD_BIN_PATH%\kmk_redirect.exe -C %_MY_OPT_SRC_DIR% ^
+        -E "PATH_OUT=%_MY_REPACK_DIR_X86%\.." ^
+        -E "PATH_TARGET=%_MY_REPACK_DIR_X86%" ^
+        -E "PATH_TARGET_X86=%_MY_REPACK_DIR_X86%\resources" ^
+        -E "VBOX_PATH_ADDITIONS_WIN_X86=%_MY_REPACK_DIR_X86%\..\bin\additions" ^
+        -E "VBOX_PATH_DIFX=%KBUILD_DEVTOOLS%\win.x86\DIFx\v2.1-r3" ^
+        -E "VBOX_VENDOR=Oracle Corporation" -E "VBOX_VENDOR_SHORT=Oracle" -E "VBOX_PRODUCT=Oracle VM VirtualBox" ^
+        -E "VBOX_C_YEAR=@VBOX_C_YEAR@" -E "VBOX_VERSION_STRING=@VBOX_VERSION_STRING@" -E "VBOX_VERSION_STRING_RAW=@VBOX_VERSION_STRING_RAW@" ^
+        -E "VBOX_VERSION_MAJOR=@VBOX_VERSION_MAJOR@" -E "VBOX_VERSION_MINOR=@VBOX_VERSION_MINOR@" -E "VBOX_VERSION_BUILD=@VBOX_VERSION_BUILD@" -E "VBOX_SVN_REV=@VBOX_SVN_REV@" ^
+        -E "VBOX_WINDOWS_ADDITIONS_ICON_FILE=%_MY_OPT_SRC_DIR%\VirtualBoxGA-vista.ico" ^
+        -E "VBOX_NSIS_ICON_FILE=%_MY_OPT_SRC_DIR%\VirtualBoxGA-nsis.ico" ^
+        -E "VBOX_WITH_GUEST_INSTALL_HELPER=1" -E "VBOX_WITH_GUEST_INSTALLER_UNICODE=1" -E "VBOX_WITH_LICENSE_INSTALL_RTF=1" ^
+        -E "VBOX_WITH_WDDM=1" -E "VBOX_WITH_MESA3D=1" -E "VBOX_BRAND_WIN_ADD_INST_DLGBMP=%_MY_OPT_SRC_DIR%\welcome.bmp" ^
+        -E "VBOX_BRAND_LICENSE_RTF=%_MY_OPT_SRC_DIR%\License-gpl-3.0.rtf"  -E "KBUILD_TYPE=%_MY_OPT_BUILD_TYPE%" -E "KBUILD_TARGET_ARCH=x86" ^
+        --  %KBUILD_DEVTOOLS%/win.x86/nsis/v3.04-log/makensis.exe /NOCD /V2 ^
+                "/DVBOX_SIGN_ADDITIONS=1" ^
+                "/DEXTERNAL_UNINSTALLER=1" ^
+                "%_MY_OPT_SRC_DIR%\VBoxGuestAdditions.nsi"
+
+rem
+rem Making .iso
+rem
+echo **************************************************************************
+echo * Making VBoxGuestAdditions.iso
+echo **************************************************************************
+
+del %_MY_OPT_OUTDIR%/VBoxGuestAdditions.iso
+
+rem TBD: that has to be converted to invoke auto-generated .cmd
+
+%_MY_SCRIPT_DIR%/../bin/bldRTIsoMaker.exe ^
+        --output %_MY_OPT_OUTDIR%/VBoxGuestAdditions.iso ^
+        --iso-level 3 ^
+        --rock-ridge ^
+        --joliet ^
+        --rational-attribs ^
+        --random-order-verification 2048 ^
+        /cert/vbox-sha1.cer=%_MY_SCRIPT_DIR%/../bin/additions/vbox-sha1.cer ^
+        /cert/vbox-sha256.cer=%_MY_SCRIPT_DIR%/../bin/additions/vbox-sha256.cer ^
+        /windows11-bypass.reg=%_MY_SCRIPT_DIR%/../bin/additions/windows11-bypass.reg ^
+        /VBoxWindowsAdditions-x86.exe=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxWindowsAdditions-x86.exe ^
+        /VBoxWindowsAdditions.exe=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxWindowsAdditions.exe ^
+        /AUTORUN.INF=%_MY_OPT_SRC_DIR%/AUTORUN.INF ^
+        /cert/VBoxCertUtil.exe=%_MY_SCRIPT_DIR%/../bin/additions/VBoxCertUtil.exe ^
+        /NT3x/Readme.txt=%_MY_OPT_SRC_DIR%/NT3xReadme.txt ^
+        /NT3x/VBoxGuest.sys=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxGuest.sys ^
+        /NT3x/VBoxGuest.cat=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxGuest.cat ^
+        /NT3x/VBoxGuest.inf=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxGuest.inf ^
+        /NT3x/VBoxMouseNT.sys=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxMouseNT.sys ^
+        /NT3x/VBoxMouse.inf=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxMouse.inf ^
+        /NT3x/VBoxMouse.cat=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxMouse.cat ^
+        /NT3x/VBoxMouse.sys=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxMouse.sys ^
+        /NT3x/VBoxControl.exe=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxControl.exe ^
+        /NT3x/VBoxService.exe=%_MY_OPT_UNTAR_DIR%/win.x86/release/bin/additions/VBoxService.exe ^
+        /VBoxWindowsAdditions-amd64.exe=%_MY_OPT_UNTAR_DIR%/win.amd64/release/bin/additions/VBoxWindowsAdditions-amd64.exe ^
+        /VBoxSolarisAdditions.pkg=%_MY_OPT_UNTAR_DIR%/solaris.x86/release/bin/additions/VBoxSolarisAdditions.pkg ^
+        /OS2/VBoxGuest.sys=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/VBoxGuest.sys ^
+        /OS2/VBoxSF.ifs=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/VBoxSF.ifs ^
+        /OS2/VBoxService.exe=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/VBoxService.exe ^
+        /OS2/VBoxControl.exe=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/VBoxControl.exe ^
+        /OS2/VBoxReplaceDll.exe=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/VBoxReplaceDll.exe ^
+        /OS2/libc06.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc06.dll ^
+        /OS2/libc061.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc061.dll ^
+        /OS2/libc062.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc062.dll ^
+        /OS2/libc063.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc063.dll ^
+        /OS2/libc064.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc064.dll ^
+        /OS2/libc065.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc065.dll ^
+        /OS2/libc066.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/libc066.dll ^
+        /OS2/readme.txt=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/readme.txt ^
+        /OS2/gengradd.dll=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/gengradd.dll ^
+        /OS2/vboxmouse.sys=%_MY_OPT_UNTAR_DIR%/os2.x86/release/bin/additions/vboxmouse.sys ^
+        /VBoxLinuxAdditions.run=%_MY_OPT_UNTAR_DIR%/linux.x86/release/bin/additions/VBoxLinuxAdditions.run ^
+        /runasroot.sh=%_MY_OPT_UNTAR_DIR%/linux.x86/release/bin/additions/runasroot.sh ^
+        /autorun.sh=%_MY_OPT_UNTAR_DIR%/linux.x86/release/bin/additions/autorun.sh ^
+        /VBoxDarwinAdditions.pkg=%_MY_OPT_UNTAR_DIR%/darwin.amd64/release/dist/additions/VBoxGuestAdditions.pkg ^
+        /VBoxDarwinAdditionsUninstall.tool=%_MY_OPT_UNTAR_DIR%/darwin.amd64/release/dist/additions/VBoxDarwinAdditionsUninstall.tool ^
+        --chmod a+x:/VBoxLinuxAdditions.run  --chmod a+x:/runasroot.sh  --chmod a+x:/autorun.sh  --chmod a+x:/VBoxDarwinAdditionsUninstall.tool ^
+        --volume-id="VBOXADDITIONS_@VBOX_VERSION_STRING@_@VBOX_SVN_REV@" ^
+        --name-setup=joliet ^
+        --volume-id="VBox_GAs_@VBOX_VERSION_STRING@"
+
+if not exist %_MY_OPT_OUTDIR%/VBoxGuestAdditions.iso goto end_failed
+call set _MY_OUT_FILES=%%VBoxGuestAdditions.iso
+
+rem
+rem That's that.
+rem
+echo **************************************************************************
+echo * The third and final step is done.
+echo *
+echo * Successfully created:
+for %%i in (%_MY_OUT_FILES%) do echo *    "%_MY_OPT_OUTDIR%\%%i"
+goto end
+
+
+:end_failed
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+@echo * Failed!
+@exit /b 1
+
+:end
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
diff --git a/src/VBox/Installer/win/Scripts/Makefile.kup b/src/VBox/Installer/win/Scripts/Makefile.kup
new file mode 100644
index 00000000..e69de29b
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/Makefile.kup
diff --git a/src/VBox/Installer/win/Scripts/PackDriversForSubmission.cmd b/src/VBox/Installer/win/Scripts/PackDriversForSubmission.cmd
new file mode 100644
index 00000000..7a349dc1
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/PackDriversForSubmission.cmd
@@ -0,0 +1,347 @@
+@echo off
+rem $Id: PackDriversForSubmission.cmd $
+rem rem @file
+rem Windows NT batch script for preparing for signing submission.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_BINDIR=..\bin
+set _MY_OPT_PDBDIR=
+set _MY_OPT_GADIR=
+set _MY_OPT_WITH_MAIN=1
+set _MY_OPT_WITH_PDB=1
+set _MY_OPT_EXTPACK=
+set _MY_OPT_NO_EXTRACT=0
+set _MY_OPT_WITH_EXTPACK=1
+set _MY_OPT_WITH_GA=0
+set _MY_OPT_OUTPUT=
+set _MY_OPT_DDF_FILE=
+set _MY_OPT_ARCH=amd64
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-a"           goto opt_a
+if ".%1" == ".--arch"       goto opt_a
+if ".%1" == ".-b"           goto opt_b
+if ".%1" == ".--bindir"     goto opt_b
+if ".%1" == ".-d"           goto opt_d
+if ".%1" == ".--ddf"        goto opt_d
+if ".%1" == ".-e"           goto opt_e
+if ".%1" == ".--extpack"    goto opt_e
+if ".%1" == ".--no-main"    goto opt_m
+if ".%1" == ".-n"           goto opt_n
+if ".%1" == ".--no-pdb"     goto opt_n
+if ".%1" == ".-o"           goto opt_o
+if ".%1" == ".--output"     goto opt_o
+if ".%1" == ".-p"           goto opt_p
+if ".%1" == ".--pdb"        goto opt_p
+if ".%1" == ".-t"           goto opt_p
+if ".%1" == ".--no-extract" goto opt_t
+if ".%1" == ".-x"           goto opt_x
+if ".%1" == ".--no-extpack" goto opt_x
+if ".%1" == ".-g"           goto opt_g
+if ".%1" == ".--ga"         goto opt_g
+if ".%1" == ".--additions"  goto opt_g
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_a
+if ".%~2" == "."            goto syntax_error_missing_value
+if not "%2" == "x86" if not "%2" == "amd64" goto syntax_error_unknown_arch
+set _MY_OPT_ARCH=%~2
+goto argument_loop_next_with_value
+
+:opt_b
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BINDIR=%~2
+goto argument_loop_next_with_value
+
+:opt_d
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_DDF_FILE=%~2
+goto argument_loop_next_with_value
+
+:opt_e
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK=%~2
+goto argument_loop_next_with_value
+
+:opt_h
+echo This script creates a .cab file containing all drivers needing blessing from
+echo Microsoft to run on recent Windows 10 installations.
+echo .
+echo Usage: PackDriversForSubmission.cmd [-b bindir] [-p pdbdir] [--no-main] [-n/--no-pdb] [-e expack]
+echo           [-x/--no-extpack] [-g/--ga/--additions] [-o output.cab] [-p output.ddf] [-a x86/amd64]
+echo .
+echo Warning! This script should normally be invoked from the repack directory w/o any parameters.
+goto end_failed
+
+:opt_m
+set _MY_OPT_WITH_MAIN=0
+shift
+goto argument_loop
+
+:opt_n
+set _MY_OPT_WITH_PDB=0
+shift
+goto argument_loop
+
+:opt_p
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_PDBDIR=%~2
+goto argument_loop_next_with_value
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTPUT=%~2
+goto argument_loop_next_with_value
+
+:opt_t
+set _MY_OPT_NO_EXTRACT=1
+shift
+goto argument_loop
+
+:opt_x
+set _MY_OPT_WITH_EXTPACK=0
+shift
+goto argument_loop
+
+:opt_g
+set _MY_OPT_WITH_GA=1
+shift
+goto argument_loop
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+:syntax_error_unknown_arch
+echo syntax error: Unknown architecture: %2
+goto end_failed
+
+:error_bindir_does_not_exist
+echo syntax error: Specified BIN directory does not exist: "%_MY_OPT_BINDIR%"
+goto end_failed
+
+:error_pdbdir_does_not_exist
+echo syntax error: Specified PDB directory does not exist: "%_MY_OPT_PDBDIR%"
+goto end_failed
+
+:error_extpack_does_not_exist
+echo syntax error: Specified extension pack does not exist: "%_MY_OPT_EXTPACK%"
+goto end_failed
+
+:error_additions_does_not_exist
+echo syntax error: Specified guest additions does not exist: "%_MY_OPT_GADIR%"
+goto end_failed
+
+
+:error_output_exists
+echo error: The output file already exist: "%_MY_OPT_OUTPUT%"
+goto end_failed
+
+:error_ddf_exists
+echo error: The DDF file already exist: "%_MY_OPT_DDF_FILE%"
+goto end_failed
+
+:no_more_arguments
+rem validate specified options
+if not exist "%_MY_OPT_BINDIR%"     goto error_bindir_does_not_exist
+
+if "%_MY_OPT_WITH_PDB%" == "0"      goto no_pdbdir_validation
+if ".%_MY_OPT_PDBDIR%" == "."       set _MY_OPT_PDBDIR=%_MY_OPT_BINDIR%\..\stage\debug\bin
+if not exist "%_MY_OPT_PDBDIR%"     goto error_pdbdir_does_not_exist
+:no_pdbdir_validation
+
+if "%_MY_OPT_WITH_EXTPACK%" == "0"  goto no_extpack_validation
+if "%_MY_OPT_NO_EXTRACT%" == "1"    goto no_extpack_validation
+if ".%_MY_OPT_EXTPACK%" == "."      set _MY_OPT_EXTPACK=%_MY_OPT_BINDIR%\Oracle_VM_VirtualBox_Extension_Pack.vbox-extpack
+if not exist "%_MY_OPT_EXTPACK%"    goto error_extpack_does_not_exist
+:no_extpack_validation
+
+if "%_MY_OPT_WITH_GA%" == "0"       goto no_additions_validation
+if ".%_MY_OPT_GADIR%" == "."        set _MY_OPT_GADIR=%_MY_OPT_BINDIR%\additions
+if not exist "%_MY_OPT_GADIR%"      goto error_additions_does_not_exist
+:no_additions_validation
+
+if ".%_MY_OPT_OUTPUT%" == "."       set _MY_OPT_OUTPUT=VBoxDrivers-@VBOX_VERSION_STRING@r@VBOX_SVN_REV@-%_MY_OPT_ARCH%.cab
+if exist "%_MY_OPT_OUTPUT%"         goto error_output_exists
+
+if ".%_MY_OPT_DDF_FILE%" == "."     set _MY_OPT_DDF_FILE=%_MY_OPT_OUTPUT%.ddf
+if exist "%_MY_OPT_DDF_FILE%"       goto error_ddf_exists
+
+
+rem
+rem Unpack the extension pack.
+rem We unpack it into the bin directory in the usual location.
+rem
+rem Note! Modify the path a little to ensure windows utilities are used before
+rem       cygwin ones, and that we can use stuff from bin\tools if we like.
+rem
+set PATH=%SystemRoot%\System32;%PATH%;%_MY_OPT_BINDIR%
+if "%_MY_OPT_WITH_EXTPACK%" == "0" goto no_extpack_unpack
+set _MY_EXTPACK_DIR=%_MY_OPT_BINDIR%\ExtensionPacks\Oracle_VM_VirtualBox_Extension_Pack
+if not exist "%_MY_OPT_BINDIR%\ExtensionPacks"  ( mkdir "%_MY_OPT_BINDIR%\ExtensionPacks" || goto end_failed )
+if not exist "%_MY_EXTPACK_DIR%"                ( mkdir "%_MY_EXTPACK_DIR%" || goto end_failed )
+if "%_MY_OPT_NO_EXTRACT%" == "1" goto no_extpack_unpack
+"%_MY_OPT_BINDIR%\tools\RTTar.exe" -xzf "%_MY_OPT_EXTPACK%"  -C "%_MY_EXTPACK_DIR%" || goto end_failed
+:no_extpack_unpack
+
+rem
+rem Create the DDF file for makecab.
+rem
+echo .OPTION EXPLICIT>                                                                  "%_MY_OPT_DDF_FILE%" || goto end_failed
+echo .Set CabinetFileCountThreshold=0 >>                                                "%_MY_OPT_DDF_FILE%"
+echo .Set FolderFileCountThreshold=0 >>                                                 "%_MY_OPT_DDF_FILE%"
+echo .Set FolderSizeThreshold=0 >>                                                      "%_MY_OPT_DDF_FILE%"
+echo .Set MaxCabinetSize=0 >>                                                           "%_MY_OPT_DDF_FILE%"
+echo .Set MaxDiskFileCount=0 >>                                                         "%_MY_OPT_DDF_FILE%"
+echo .Set MaxDiskSize=0 >>                                                              "%_MY_OPT_DDF_FILE%"
+echo .Set Cabinet=on>>                                                                  "%_MY_OPT_DDF_FILE%"
+echo .Set CompressionType=MSZIP>>                                                       "%_MY_OPT_DDF_FILE%"
+echo .Set Compress=on>>                                                                 "%_MY_OPT_DDF_FILE%"
+echo .Set DiskDirectoryTemplate= >>                                                     "%_MY_OPT_DDF_FILE%"
+echo .Set CabinetNameTemplate=%_MY_OPT_OUTPUT%>>                                        "%_MY_OPT_DDF_FILE%"
+echo .Set InfFileName=%_MY_OPT_OUTPUT%.inf>>                                            "%_MY_OPT_DDF_FILE%"
+echo .Set RptFileName=%_MY_OPT_OUTPUT%.rpt>>                                            "%_MY_OPT_DDF_FILE%"
+
+if %_MY_OPT_WITH_MAIN% == 0 goto skip_main_package
+echo .Set DestinationDir=VBoxSup>>                                                      "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxSup.inf VBoxSup.inf>>                                         "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxSup.sys VBoxSup.sys>>                                         "%_MY_OPT_DDF_FILE%"
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxSup.pdb VBoxSup.pdb>>          "%_MY_OPT_DDF_FILE%"
+
+echo .Set DestinationDir=VBoxNetAdp6>>                                                  "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxNetAdp6.inf VBoxNetAdp6.inf>>                                 "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxNetAdp6.sys VBoxNetAdp6.sys>>                                 "%_MY_OPT_DDF_FILE%"
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxNetAdp6.pdb VBoxNetAdp6.pdb>>  "%_MY_OPT_DDF_FILE%"
+
+echo .Set DestinationDir=VBoxNetLwf>>                                                   "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxNetLwf.inf VBoxNetLwf.inf>>                                   "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxNetLwf.sys VBoxNetLwf.sys>>                                   "%_MY_OPT_DDF_FILE%"
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxNetLwf.pdb VBoxNetLwf.pdb>>    "%_MY_OPT_DDF_FILE%"
+
+echo .Set DestinationDir=VBoxUSB>>                                                      "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxUSB.inf VBoxUSB.inf>>                                         "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxUSB.sys VBoxUSB.sys>>                                         "%_MY_OPT_DDF_FILE%"
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxUSB.pdb VBoxUSB.pdb>>          "%_MY_OPT_DDF_FILE%"
+
+echo .Set DestinationDir=VBoxUSBMon>>                                                   "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxUSBMon.inf VBoxUSBMon.inf>>                                   "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxUSBMon.sys VBoxUSBMon.sys>>                                   "%_MY_OPT_DDF_FILE%"
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxUSBMon.pdb VBoxUSBMon.pdb>>    "%_MY_OPT_DDF_FILE%"
+
+echo .Set DestinationDir=VMMR0>>                                                        "%_MY_OPT_DDF_FILE%"
+echo .\VMMR0.inf VMMR0.inf>>                                                            "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VMMR0.r0 VMMR0.r0>>                                               "%_MY_OPT_DDF_FILE%"
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VMMR0.pdb VMMR0.pdb>>              "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_BINDIR%\VBoxDDR0.r0 VBoxDDR0.r0>>                                         "%_MY_OPT_DDF_FILE%"
+:skip_main_package
+
+if "%_MY_OPT_WITH_PDB%" == "1" echo %_MY_OPT_PDBDIR%\VBoxDDR0.pdb VBoxDDR0.pdb>>        "%_MY_OPT_DDF_FILE%"
+
+if "%_MY_OPT_WITH_EXTPACK%" == "0" goto no_extpack_ddf
+echo .Set DestinationDir=VBoxExtPackPuel>>                                              "%_MY_OPT_DDF_FILE%"
+echo .\VBoxExtPackPuel.inf VBoxExtPackPuel.inf>>                                        "%_MY_OPT_DDF_FILE%"
+rem echo %_MY_EXTPACK_DIR%\win.%_MY_OPT_ARCH%\VBoxEhciR0.r0 VBoxEhciR0.r0>>                 "%_MY_OPT_DDF_FILE%"
+echo %_MY_EXTPACK_DIR%\win.%_MY_OPT_ARCH%\VBoxNvmeR0.r0 VBoxNvmeR0.r0>>                 "%_MY_OPT_DDF_FILE%"
+rem echo %_MY_EXTPACK_DIR%\win.%_MY_OPT_ARCH%\VBoxPciRawR0.r0 VBoxPciRawR0.r0>>             "%_MY_OPT_DDF_FILE%"
+:no_extpack_ddf
+
+if "%_MY_OPT_WITH_GA%" == "0"   goto no_additions_ddf
+echo .Set DestinationDir=VBoxGuestAdditions>>                                           "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxGuest.inf>>                                                    "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxGuest.sys>>                                                    "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxTray.exe>>                                                     "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxControl.exe>>                                                  "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxMouse.inf>>                                                    "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxMouse.sys>>                                                    "%_MY_OPT_DDF_FILE%"
+rem VBoxVideo files are excluded from attestation signing.
+rem echo %_MY_OPT_GADIR%\VBoxVideo.inf>>                                                    "%_MY_OPT_DDF_FILE%"
+rem echo %_MY_OPT_GADIR%\VBoxVideo.sys>>                                                    "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxWddm.inf>>                                                     "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxWddm.sys>>                                                     "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxDX.dll>>                                                       "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxDisp.dll>>                                                     "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxDispD3D.dll>>                                                  "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxNine.dll>>                                                     "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxSVGA.dll>>                                                     "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxGL.dll>>                                                       "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxMRXNP.dll>>                                                    "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxSF.sys>>                                                       "%_MY_OPT_DDF_FILE%"
+if ".%_MY_OPT_ARCH%" == ".x86" goto skip_amd64_files
+echo %_MY_OPT_GADIR%\VBoxDX-x86.dll>>                                                   "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxDispD3D-x86.dll>>                                              "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxNine-x86.dll>>                                                 "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxSVGA-x86.dll>>                                                 "%_MY_OPT_DDF_FILE%"
+echo %_MY_OPT_GADIR%\VBoxGL-x86.dll>>                                                   "%_MY_OPT_DDF_FILE%"
+:skip_amd64_files
+
+:no_additions_ddf
+
+rem
+rem Create the cabient file.
+rem Note! MakeCab is shipped on W10, so we ASSUME it's in the PATH.
+rem
+MakeCab.exe /v2 /F "%_MY_OPT_DDF_FILE%" || goto end_failed
+
+rem
+rem EV sign the cabient file.
+rem
+if not exist "sign-ev.cmd" goto end
+echo info: Now signing the created CAB file. Can take a few minutes...
+call sign-ev.cmd "%_MY_OPT_OUTPUT%" || goto end_failed
+
+goto end
+
+:end_failed
+@endlocal
+@endlocal
+@exit /b 1
+
+:end
+@endlocal
+@endlocal
diff --git a/src/VBox/Installer/win/Scripts/RepackExtPack.cmd b/src/VBox/Installer/win/Scripts/RepackExtPack.cmd
new file mode 100644
index 00000000..e75348a7
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/RepackExtPack.cmd
@@ -0,0 +1,240 @@
+@echo off
+rem $Id: RepackExtPack.cmd $
+rem rem @file
+rem Windows NT batch script for repacking an extension pack with blessed .r0 files.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Check for environment variables we need.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+rem if ".%KBUILD_BIN_PATH%" == "." (echo KBUILD_BIN_PATH is not set & goto end_failed)
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_BINDIR_X86=..\..\..\win.x86\@KBUILD_TYPE@\bin
+set _MY_OPT_BINDIR_AMD64=..\..\..\win.amd64\@KBUILD_TYPE@\bin
+set _MY_OPT_INPUT=
+set _MY_OPT_OUTPUT=
+set _MY_OPT_STAGE_DIR=.\repack-extpack-%RANDOM%
+for %%i in (%_MY_OPT_STAGE_DIR%) do set _MY_OPT_STAGE_DIR=%%~fi
+set _MY_OPT_SIGN_CAT=1
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-a"           goto opt_a
+if ".%1" == ".--bindir-amd64" goto opt_a
+if ".%1" == ".-b"           goto opt_b
+if ".%1" == ".--bindir-x86" goto opt_b
+if ".%1" == ".-i"           goto opt_i
+if ".%1" == ".--input"      goto opt_i
+if ".%1" == ".-o"           goto opt_o
+if ".%1" == ".--output"     goto opt_o
+if ".%1" == ".-s"           goto opt_s
+if ".%1" == ".--stage-dir"  goto opt_s
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_a
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BINDIR_AMD64=%~f2
+goto argument_loop_next_with_value
+
+:opt_b
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BINDIR_X86=%~f2
+goto argument_loop_next_with_value
+
+:opt_h
+echo This script repacks an extension pack replacing windows .r0 files with
+echo blessed copies from the bin directory.  The ASSUMPTION here is that prior
+echo to invoking this script, the UnpackBlessedDrivers.cmd script was executed
+echo both for win.amd64 and win.x86.
+echo .
+echo Usage: RepackExtPack.cmd [-b bindir-x86] [-a bindir-amd64] [-s staging-dir]
+echo            -i input.vbox-extpack -o output.vbox-extpack
+echo .
+echo Warning! This script should normally be invoked from the win.x86 repack directory.
+goto end_failed
+
+:opt_i
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_INPUT=%~f2
+goto argument_loop_next_with_value
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTPUT=%~f2
+goto argument_loop_next_with_value
+
+:opt_s
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_STAGE_DIR=%~f2
+goto argument_loop_next_with_value
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+:error_bindir_amd64_does_not_exist
+echo syntax error: Specified AMD64 BIN directory does not exist: "%_MY_OPT_BINDIR_AMD64%"
+goto end_failed
+
+:error_bindir_x86_does_not_exist
+echo syntax error: Specified x86 BIN directory does not exist: "%_MY_OPT_BINDIR_X86%"
+goto end_failed
+
+:error_input_not_found
+echo error: Input file does not exist: "%_MY_OPT_INPUT%"
+goto end_failed
+
+:error_stage_dir_exists
+echo error: Temporary staging directory exists: "%_MY_OPT_STAGE_DIR%"
+goto end_failed
+
+:no_more_arguments
+rem
+rem Validate and adjust specified options.
+rem
+if not exist "%_MY_OPT_BINDIR_X86%"   goto error_bindir_x86_does_not_exist
+if not exist "%_MY_OPT_BINDIR_AMD64%" goto error_bindir_amd64_does_not_exist
+
+if ".%_MY_OPT_INPUT%" == "."        set _MY_OPT_INPUT=%_MY_OPT_BINDIR_X86%\Oracle_VM_VirtualBox_Extension_Pack.vbox-extpack
+if not exist "%_MY_OPT_INPUT%"      goto error_input_not_found
+
+if ".%_MY_OPT_OUTPUT%" == "."       for %%i in ("%_MY_OPT_INPUT%") do set _MY_OPT_OUTPUT=.\%%~nxi
+
+rem Make _MY_OPT_STAGE_DIR absolute.
+if exist "%_MY_OPT_STAGE_DIR%"      goto error_stage_dir_exists
+
+rem
+rem Modify PATH to facilitate using our zip, gzip and manifest tools
+rem
+rem TODO: Use RTTar for creation too.
+rem TODO: Not sure how well the bsdtar output actually work with 5.1...
+rem TODO: Check whether we need stupid cygwin to get the right execute bits (x) on unix.
+rem
+set PATH=%PATH%;%_MY_OPT_BINDIR_AMD64%
+set _MY_TOOL_TAR_EXPAND="%_MY_OPT_BINDIR_AMD64%\tools\RTTar.exe" -x
+set _MY_TOOL_TAR_CREATE="%KBUILD_DEVTOOLS%\win.x86\gnuwin32\r1\bin\bsdtar.exe" -c --format ustar
+set _MY_TOOL_GZIP=%_MY_OPT_BINDIR_AMD64%\tools\RTGzip.exe
+set _MY_TOOL_MANIFEST=%_MY_OPT_BINDIR_AMD64%\tools\RTManifest.exe
+
+rem
+rem Unpack the extension pack.
+rem
+echo * Unpacking "%_MY_OPT_INPUT" to "%_MY_OPT_STAGE_DIR%"...
+mkdir "%_MY_OPT_STAGE_DIR%" || goto end_failed
+%_MY_TOOL_TAR_EXPAND% -vzf "%_MY_OPT_INPUT%" -C "%_MY_OPT_STAGE_DIR%" || goto end_failed_cleanup
+
+rem
+rem Copy over the blessed .r0 files.
+rem
+echo * Copying over blessed .r0 binaries...
+if not exist "%_MY_OPT_STAGE_DIR%\win.x86" goto no_win_x86
+for %%i in ("%_MY_OPT_STAGE_DIR%\win.x86\*.r0") do (
+    echo -=- %%i
+    copy /y "%_MY_OPT_BINDIR_X86%\%%~nxi" "%_MY_OPT_STAGE_DIR%\win.x86" || goto end_failed_cleanup
+)
+:no_win_x86
+
+for %%i in ("%_MY_OPT_STAGE_DIR%\win.amd64\*.r0") do (
+    echo -=- %%i
+    copy /y "%_MY_OPT_BINDIR_AMD64%\%%~nxi" "%_MY_OPT_STAGE_DIR%\win.amd64" || goto end_failed_cleanup
+)
+
+rem
+rem Recreate the manifest.
+rem
+echo * Collecting files for manifest...
+set _MY_MANIFEST_FILES=
+for /D %%d in ("%_MY_OPT_STAGE_DIR%\*") do (
+    for %%f in ("%%d\*") do call set _MY_MANIFEST_FILES=%%_MY_MANIFEST_FILES%% %%~nxd/%%~nxf
+)
+for %%f in ("%_MY_OPT_STAGE_DIR%\*") do (
+    if not "%%~nxf" == "ExtPack.manifest" if not "%%~nxf" == "ExtPack.signature" call set _MY_MANIFEST_FILES=%%_MY_MANIFEST_FILES%% %%~nxf
+)
+rem echo _MY_MANIFEST_FILES=%_MY_MANIFEST_FILES%
+
+echo * Creating manifest...
+echo on
+"%_MY_TOOL_MANIFEST%" --manifest "%_MY_OPT_STAGE_DIR%\ExtPack.manifest" --chdir "%_MY_OPT_STAGE_DIR%" %_MY_MANIFEST_FILES% || goto end_failed_cleanup
+@echo off
+
+rem
+rem Repackage the damn thing.
+rem
+@echo * Packing extension pack...
+
+echo on
+%_MY_TOOL_TAR_CREATE% -vf "%_MY_OPT_OUTPUT%.tmp" -C "%_MY_OPT_STAGE_DIR%" . || goto end_failed_cleanup
+"%_MY_TOOL_GZIP%" -9 -n "%_MY_OPT_OUTPUT%.tmp"       || goto end_failed_cleanup
+move /Y "%_MY_OPT_OUTPUT%.tmp.gz" "%_MY_OPT_OUTPUT%" || goto end_failed_cleanup
+echo off
+
+rem
+rem Cleanup and we're good.
+rem
+echo * Cleaning up...
+rmdir /s /q "%_MY_OPT_STAGE_DIR%"
+
+echo * Successfully created: "%_MY_OPT_OUTPUT%
+goto end
+
+:end_failed_cleanup
+@rmdir /s /q "%_MY_OPT_STAGE_DIR%"
+@if exist "%_MY_OPT_OUTPUT%.tmp"    del "%_MY_OPT_OUTPUT%.tmp"
+@if exist "%_MY_OPT_OUTPUT%.tmp.gz" del "%_MY_OPT_OUTPUT%.tmp.gz"
+
+:end_failed
+@endlocal
+@endlocal
+@echo * Failed!
+@exit /b 1
+
+:end
+@endlocal
+@endlocal
+
diff --git a/src/VBox/Installer/win/Scripts/Single-1-Prepare.cmd b/src/VBox/Installer/win/Scripts/Single-1-Prepare.cmd
new file mode 100644
index 00000000..bd5b6567
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/Single-1-Prepare.cmd
@@ -0,0 +1,248 @@
+@echo off
+rem $Id: Single-1-Prepare.cmd $
+rem rem @file
+rem Windows NT batch script for preparing single build (either amd64 and x86) for signing submission.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Globals and checks for required enviornment variables.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+if ".%KBUILD_BIN_PATH%" == "." (echo KBUILD_BIN_PATH is not set & goto end_failed)
+set _MY_SCRIPT_DIR=%~dp0
+set _MY_SAVED_CD=%CD%
+set _MY_VER_REV=@VBOX_VERSION_STRING@r@VBOX_SVN_REV@
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_UNTAR_DIR=%_MY_SCRIPT_DIR%\..\
+for %%i in (%_MY_OPT_UNTAR_DIR%) do set _MY_OPT_UNTAR_DIR=%%~fi
+set _MY_OPT_EXTPACK=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%.vbox-extpack
+set _MY_OPT_EXTPACK_ENTERPRISE=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%-ENTERPRISE.vbox-extpack
+set _MY_OPT_BUILD_TYPE=@KBUILD_TYPE@
+set _MY_OPT_OUTDIR=%_MY_OPT_UNTAR_DIR%\output
+set _MY_OPT_ARCH=@KBUILD_TARGET_ARCH@
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-a"                   goto opt_a
+if ".%1" == ".--arch"               goto opt_a
+if ".%1" == ".-e"                   goto opt_e
+if ".%1" == ".--extpack"            goto opt_e
+if ".%1" == ".-o"                   goto opt_o
+if ".%1" == ".--outdir"             goto opt_o
+if ".%1" == ".-s"                   goto opt_s
+if ".%1" == ".--extpack-enterprise" goto opt_s
+if ".%1" == ".-t"                   goto opt_t
+if ".%1" == ".--build-type"         goto opt_t
+if ".%1" == ".-u"                   goto opt_u
+if ".%1" == ".--vboxall-untar-dir"  goto opt_u
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_a
+if ".%~2" == "."            goto syntax_error_missing_value
+if not "%2" == "x86" if not "%2" == "amd64" goto syntax_error_unknown_arch
+set _MY_OPT_ARCH=%~2
+goto argument_loop_next_with_value
+
+:opt_e
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK=%~f2
+goto argument_loop_next_with_value
+
+:opt_h
+echo Toplevel single package: Prepare either x86 and amd64 for submission.
+echo .
+echo Usage: Single-1-Prepare.cmd [-o output-dir] [-e/--extpack puel.vbox-extpack]
+echo            [-s/--extpack-enterprise puel-enterprise.vbox-extpack]
+echo            [-u/--vboxall-dir unpacked-vboxall-dir] [-t build-type]
+echo            [-a x86/amd64]
+echo .
+echo Default -a/--arch value:               %_MY_OPT_ARCH%
+echo Default -e/--extpack value:            %_MY_OPT_EXTPACK%
+echo Default -s/--extpack-enterprise value: %_MY_OPT_EXTPACK_ENTERPRISE%
+echo Default -u/--vboxall-untar-dir value:  %_MY_OPT_UNTAR_DIR%
+echo Default -o/--outdir value:             %_MY_OPT_OUTDIR%
+echo Default -t/--build-type value:         %_MY_OPT_BUILD_TYPE%
+echo .
+goto end_failed
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTDIR=%~f2
+goto argument_loop_next_with_value
+
+:opt_s
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK_ENTERPRISE=%~f2
+goto argument_loop_next_with_value
+
+:opt_t
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BUILD_TYPE=%~2
+goto argument_loop_next_with_value
+
+:opt_u
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_UNTAR_DIR=%~f2
+goto argument_loop_next_with_value
+
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+:syntax_error_unknown_arch
+echo syntax error: Unknown architecture: %2
+goto end_failed
+
+
+:error_vboxall_untar_dir_not_found
+echo syntax error: The VBoxAll untar directory was not found: "%_MY_OPT_UNTAR_DIR%"
+goto end_failed
+
+:error_bindir_not_found
+echo syntax error: The bin directory was not found: "%_MY_BINDIR%"
+goto end_failed
+
+:error_repack_dir_not_found
+echo syntax error: The repack directory was not found: "%_MY_REPACK_DIR%"
+goto end_failed
+
+:error_extpack_not_found
+echo syntax error: Specified extension pack not found: "%_MY_OPT_EXTPACK%"
+goto end_failed
+
+:error_enterprise_extpack_not_found
+echo syntax error: Specified enterprise extension pack not found: "%_MY_OPT_EXTPACK_ENTERPRISE%"
+goto end_failed
+
+
+
+:no_more_arguments
+rem
+rem Validate and adjust specified options.
+rem
+
+if not exist "%_MY_OPT_UNTAR_DIR%"      goto error_vboxall_untar_dir_not_found
+
+set _MY_BINDIR=%_MY_OPT_UNTAR_DIR%\bin
+if not exist "%_MY_BINDIR%"             goto error_bindir_not_found
+
+set _MY_REPACK_DIR=%_MY_OPT_UNTAR_DIR%\repack
+if not exist "%_MY_REPACK_DIR%"         goto error_repack_dir_not_found
+
+if not exist "%_MY_OPT_EXTPACK%"        goto error_extpack_not_found
+if not ".%_MY_OPT_EXTPACK_ENTERPRISE%" == "." if not exist "%_MY_OPT_EXTPACK_ENTERPRISE%" goto error_enterprise_extpack_not_found
+
+
+rem Make sure the output dir exists.
+if not exist "%_MY_OPT_OUTDIR%"     (mkdir "%_MY_OPT_OUTDIR%" || goto end_failed)
+
+rem
+rem Install the extpack in the bin directories.
+rem Note! Not really necessary, but whatever.
+rem
+echo on
+copy /y "%_MY_OPT_EXTPACK%" "%_MY_BINDIR%\Oracle_VM_VirtualBox_Extension_Pack.vbox-extpack" || goto end_failed
+@echo off
+
+rem
+rem Do the packing.
+rem
+echo **************************************************************************
+echo Packing drivers
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR%" || goto end_failed
+call "%_MY_REPACK_DIR%\PackDriversForSubmission.cmd" -b "%_MY_BINDIR%" -a %_MY_OPT_ARCH% -e "%_MY_OPT_EXTPACK%" ^
+    -o "%_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-%_MY_OPT_ARCH%.cab" || goto end_failed
+echo .
+cd /d "%_MY_SAVED_CD%"
+
+rem
+rem Generate script for taking the next step.
+rem
+set _MY_NEXT_SCRIPT=%_MY_OPT_OUTDIR%\Single-3-Repack.cmd
+rem If out dir is the same as repack dir this would erase original repack script
+if not exist "%_MY_NEXT_SCRIPT%" goto generate_next_script
+set _MY_NEXT_SCRIPT=%_MY_OPT_OUTDIR%\Single-3-Repack-Gen.cmd
+:generate_next_script
+echo cd /d "%cd%" > "%_MY_NEXT_SCRIPT%"
+echo call "%_MY_SCRIPT_DIR%\Single-3-Repack.cmd" --extpack "%_MY_OPT_EXTPACK%" ^
+    --extpack-enterprise "%_MY_OPT_EXTPACK_ENTERPRISE%" ^
+    --vboxall-untar-dir "%_MY_OPT_UNTAR_DIR%" ^
+    --outdir "%_MY_OPT_OUTDIR%" ^
+    --build-type "%_MY_OPT_BUILD_TYPE%" %%* >> "%_MY_NEXT_SCRIPT%"
+
+rem
+rem Instructions on what to do next.
+rem
+echo **************************************************************************
+echo * First step is done.
+echo *
+echo * Created:
+echo *     %_MY_OPT_OUTDIR%\VBoxDrivers-%_MY_VER_REV%-%_MY_OPT_ARCH%.cab
+echo *
+echo * Next steps:
+echo *   1. Submit the files to Microsoft for attestation signing.
+echo *   2. Download the signed result.
+echo *   3. "%_MY_NEXT_SCRIPT%" --signed {zip}
+
+goto end
+
+
+:end_failed
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+@echo * Failed!
+@exit /b 1
+
+:end
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+
diff --git a/src/VBox/Installer/win/Scripts/Single-3-Repack.cmd b/src/VBox/Installer/win/Scripts/Single-3-Repack.cmd
new file mode 100644
index 00000000..166b40b3
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/Single-3-Repack.cmd
@@ -0,0 +1,291 @@
+@echo off
+rem $Id: Single-3-Repack.cmd $
+rem rem @file
+rem Windows NT batch script for repacking signed amd64 or x86 drivers.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Globals and checks for required enviornment variables.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+if ".%KBUILD_BIN_PATH%" == "." (echo KBUILD_BIN_PATH is not set & goto end_failed)
+set _MY_SCRIPT_DIR=%~dp0
+set _MY_SAVED_CD=%CD%
+set _MY_VER_REV=@VBOX_VERSION_STRING@r@VBOX_SVN_REV@
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_UNTAR_DIR=%_MY_SCRIPT_DIR%\..\
+for %%i in (%_MY_OPT_UNTAR_DIR%) do set _MY_OPT_UNTAR_DIR=%%~fi
+set _MY_OPT_EXTPACK=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%.vbox-extpack
+set _MY_OPT_EXTPACK_ENTERPRISE=%_MY_OPT_UNTAR_DIR%\Oracle_VM_VirtualBox_Extension_Pack-%_MY_VER_REV%-ENTERPRISE.vbox-extpack
+set _MY_OPT_BUILD_TYPE=@KBUILD_TYPE@
+set _MY_OPT_OUTDIR=%_MY_OPT_UNTAR_DIR%\output
+set _MY_OPT_SIGNED=
+set _MY_OPT_NOEXTPACK=
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-e"                   goto opt_e
+if ".%1" == ".--extpack"            goto opt_e
+if ".%1" == ".-n"                   goto opt_n
+if ".%1" == ".--no-extpack"         goto opt_n
+if ".%1" == ".-o"                   goto opt_o
+if ".%1" == ".--outdir"             goto opt_o
+if ".%1" == ".-s"                   goto opt_s
+if ".%1" == ".--extpack-enterprise" goto opt_s
+if ".%1" == ".--signed"             goto opt_signed
+if ".%1" == ".-t"                   goto opt_t
+if ".%1" == ".--build-type"         goto opt_t
+if ".%1" == ".-u"                   goto opt_u
+if ".%1" == ".--vboxall-untar-dir"  goto opt_u
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_e
+if ".%~2" == "."             goto syntax_error_missing_value
+set _MY_OPT_EXTPACK=%~f2
+goto argument_loop_next_with_value
+
+:opt_h
+echo Toplevel combined package: Repack the installer and extpacks.
+echo .
+echo Usage: Combined-3-Repack.cmd [-o output-dir] [-e/--extpack puel.vbox-extpack]
+echo            [-s/--extpack-enterprise puel-enterprise.vbox-extpack]
+echo            [-u/--vboxall-dir unpacked-vboxall-dir] [-t build-type]
+echo            [--signed signed.zip]
+echo
+echo .
+echo Default -e/--extpack value:            %_MY_OPT_EXTPACK%
+echo Default -s/--extpack-enterprise value: %_MY_OPT_EXTPACK_ENTERPRISE%
+echo Default -u/--vboxall-untar-dir value:  %_MY_OPT_UNTAR_DIR%
+echo Default -o/--outdir value:             %_MY_OPT_OUTDIR%
+echo Default -t/--build-type value:         %_MY_OPT_BUILD_TYPE%
+echo .
+goto end_failed
+
+:opt_n
+set _MY_OPT_NOEXTPACK=1
+shift
+goto argument_loop
+
+:opt_o
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_OUTDIR=%~f2
+goto argument_loop_next_with_value
+
+:opt_s
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_EXTPACK_ENTERPRISE=%~f2
+goto argument_loop_next_with_value
+
+:opt_signed
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_SIGNED=%~f2
+goto argument_loop_next_with_value
+
+:opt_t
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BUILD_TYPE=%~2
+goto argument_loop_next_with_value
+
+:opt_u
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_UNTAR_DIR=%~f2
+goto argument_loop_next_with_value
+
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+
+:error_vboxall_untar_dir_not_found
+echo syntax error: The VBoxAll untar directory was not found: "%_MY_OPT_UNTAR_DIR%"
+goto end_failed
+
+:error_bindir_not_found
+echo syntax error: The bin directory was not found: "%_MY_BINDIR%"
+goto end_failed
+
+:error_repack_dir_not_found
+echo syntax error: The repack directory was not found: "%_MY_REPACK_DIR%"
+goto end_failed
+
+:error_extpack_not_found
+echo syntax error: Specified extension pack not found: "%_MY_OPT_EXTPACK%"
+goto end_failed
+
+:error_enterprise_extpack_not_found
+echo syntax error: Specified enterprise extension pack not found: "%_MY_OPT_EXTPACK_ENTERPRISE%"
+goto end_failed
+
+:error_signed_not_found
+echo syntax error: Zip with signed drivers not found: "%_MY_OPT_SIGNED%"
+goto end_failed
+
+
+:no_more_arguments
+rem
+rem Validate and adjust specified options.
+rem
+
+if not exist "%_MY_OPT_UNTAR_DIR%"      goto error_vboxall_untar_dir_not_found
+
+set _MY_BINDIR=%_MY_OPT_UNTAR_DIR%\bin
+if not exist "%_MY_BINDIR%"             goto error_bindir_not_found
+
+set _MY_REPACK_DIR=%_MY_OPT_UNTAR_DIR%\repack
+if not exist "%_MY_REPACK_DIR%"         goto error_repack_dir_not_found
+
+if ".%_MY_OPT_NOEXTPACK%" == ".1"       goto no_enterprise_check
+if not exist "%_MY_OPT_EXTPACK%"        goto error_extpack_not_found
+if not ".%_MY_OPT_EXTPACK_ENTERPRISE%" == "." if not exist "%_MY_OPT_EXTPACK_ENTERPRISE%" goto error_enterprise_extpack_not_found
+:no_enterprise_check
+
+if not exist "%_MY_OPT_SIGNED%"         goto error_signed_not_found
+
+rem Make sure the output dir exists.
+if not exist "%_MY_OPT_OUTDIR%"     (mkdir "%_MY_OPT_OUTDIR%" || goto end_failed)
+
+rem
+rem Unpacking the driver zip.
+rem
+echo **************************************************************************
+echo * Unpacking signed drivers...
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR%" || goto end_failed
+call "%_MY_REPACK_DIR%\UnpackBlessedDrivers.cmd" -n -b "%_MY_BINDIR%" -i "%_MY_OPT_SIGNED%" || goto end_failed
+echo .
+
+
+rem
+rem Do the work.
+rem
+echo **************************************************************************
+echo * Repackaging installers
+echo **************************************************************************
+echo * Compiling WIX...
+cd /d "%_MY_REPACK_DIR%" || goto end_failed
+for %%i in (1-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * Linking WIX...
+for %%i in (2-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * Applying language patches to MSI...
+for %%i in (3-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+echo * Creating multi arch installer...
+for %%i in (4-*.cmd) do (call %%i || goto end_failed)
+echo .
+
+
+set _MY_OUT_FILES=
+cd /d "%_MY_REPACK_DIR%" || goto end_failed
+for %%i in (VBoxMerge*msm) do (
+    copy /y "%%i" "%_MY_OPT_OUTDIR%" || goto end_failed
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+for %%i in (VirtualBox-*MultiArch*exe) do (
+    copy /y "%%i" "%_MY_OPT_OUTDIR%" || goto end_failed
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+
+
+if ".%_MY_OPT_NOEXTPACK%" == ".1" goto no_enterprise_repacking
+rem
+rem Repack the extension packs.
+rem
+echo **************************************************************************
+echo * Repacking extension packs.
+echo **************************************************************************
+cd /d "%_MY_REPACK_DIR%" || goto end_failed
+
+echo * Regular PUEL...
+set _MY_TMP_OUT=%_MY_OPT_EXTPACK%
+for %%i in (%_MY_TMP_OUT%) do (
+    set _MY_TMP_OUT=%_MY_OPT_OUTDIR%\%%~nxi
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+call "%_MY_REPACK_DIR%\RepackExtPack.cmd" --bindir-amd64 "%_MY_BINDIR%" --bindir-x86 "%_MY_BINDIR%" ^
+    --input "%_MY_OPT_EXTPACK%" --output "%_MY_TMP_OUT%" || goto end_failed
+
+if ".%_MY_OPT_EXTPACK_ENTERPRISE%" == "." goto no_enterprise_repacking
+echo * Enterprise PUEL...
+set _MY_TMP_OUT=%_MY_OPT_EXTPACK_ENTERPRISE%
+for %%i in (%_MY_TMP_OUT%) do (
+    set _MY_TMP_OUT=%_MY_OPT_OUTDIR%\%%~nxi
+    call set _MY_OUT_FILES=%%_MY_OUT_FILES%% %%~nxi
+)
+call "%_MY_REPACK_DIR%\RepackExtPack.cmd" --bindir-amd64 "%_MY_BINDIR%" --bindir-x86 "%_MY_BINDIR%" ^
+    --input "%_MY_OPT_EXTPACK_ENTERPRISE%" --output "%_MY_TMP_OUT%" || goto end_failed
+:no_enterprise_repacking
+@cd /d "%_MY_SAVED_CD%"
+
+rem
+rem That's that.
+rem
+echo **************************************************************************
+echo * The third and final step is done.
+echo *
+echo * Successfully created:
+for %%i in (%_MY_OUT_FILES%) do echo *    "%_MY_OPT_OUTDIR%\%%i"
+goto end
+
+
+:end_failed
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
+@echo * Failed!
+@exit /b 1
+
+:end
+@cd /d "%_MY_SAVED_CD%"
+@endlocal
+@endlocal
diff --git a/src/VBox/Installer/win/Scripts/UnpackBlessedDrivers.cmd b/src/VBox/Installer/win/Scripts/UnpackBlessedDrivers.cmd
new file mode 100644
index 00000000..c41a5d50
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/UnpackBlessedDrivers.cmd
@@ -0,0 +1,185 @@
+@echo off
+rem $Id: UnpackBlessedDrivers.cmd $
+rem rem @file
+rem Windows NT batch script for unpacking drivers after being signed.
+rem
+
+rem
+rem Copyright (C) 2018-2023 Oracle and/or its affiliates.
+rem
+rem This file is part of VirtualBox base platform packages, as
+rem available from https://www.virtualbox.org.
+rem
+rem This program is free software; you can redistribute it and/or
+rem modify it under the terms of the GNU General Public License
+rem as published by the Free Software Foundation, in version 3 of the
+rem License.
+rem
+rem This program is distributed in the hope that it will be useful, but
+rem WITHOUT ANY WARRANTY; without even the implied warranty of
+rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+rem General Public License for more details.
+rem
+rem You should have received a copy of the GNU General Public License
+rem along with this program; if not, see <https://www.gnu.org/licenses>.
+rem
+rem SPDX-License-Identifier: GPL-3.0-only
+rem
+
+
+setlocal ENABLEEXTENSIONS
+setlocal
+
+rem
+rem Globals and Check for environment variables we need.
+rem
+if ".%KBUILD_DEVTOOLS%" == "." (echo KBUILD_DEVTOOLS is not set & goto end_failed)
+set _MY_DRIVER_BASE_NAMES=VBoxSup VBoxNetAdp6 VBoxNetLwf VBoxUSB VBoxUSBMon
+set _MY_GUEST_ADDITIONS_DRIVER_BASE_NAMES=VBoxVideo VBoxWddm VBoxGuest VBoxMouse
+set _MY_UNZIP=%KBUILD_DEVTOOLS%\win.x86\bin\unzip.exe
+if not exist "%_MY_UNZIP%" (echo "%_MY_UNZIP%" does not exist & goto end_failed)
+
+rem
+rem Parse arguments.
+rem
+set _MY_OPT_BINDIR=..\bin
+set _MY_OPT_INPUT=
+set _MY_OPT_SIGN_CAT=1
+set _MY_OPT_SIGN_VERIFY=1
+
+:argument_loop
+if ".%1" == "."             goto no_more_arguments
+
+if ".%1" == ".-h"           goto opt_h
+if ".%1" == ".-?"           goto opt_h
+if ".%1" == "./h"           goto opt_h
+if ".%1" == "./H"           goto opt_h
+if ".%1" == "./?"           goto opt_h
+if ".%1" == ".-help"        goto opt_h
+if ".%1" == ".--help"       goto opt_h
+
+if ".%1" == ".-b"           goto opt_b
+if ".%1" == ".--bindir"     goto opt_b
+if ".%1" == ".-i"           goto opt_i
+if ".%1" == ".--input"      goto opt_i
+if ".%1" == ".-n"           goto opt_n
+if ".%1" == ".--no-sign-cat" goto opt_n
+if ".%1" == ".-v"           goto opt_v
+if ".%1" == ".--no-sign-verify" goto opt_v
+if ".%1" == ".--guest-additions" goto opt_ga
+
+echo syntax error: Unknown option: %1
+echo               Try --help to list valid options.
+goto end_failed
+
+:argument_loop_next_with_value
+shift
+shift
+goto argument_loop
+
+:opt_b
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_BINDIR=%~2
+goto argument_loop_next_with_value
+
+:opt_h
+echo This script unpacks the zip-file containing the blessed driver files from
+echo Microsoft, replacing original files in the bin directory.  The catalog files
+echo will be signed again and the Microsoft signature merged with ours.
+echo .
+echo Usage: UnpackBlessedDrivers.cmd [-b bindir] [-n/--no-sign-cat] [-v/--no-sign-verify] -i input.zip
+echo .
+echo Warning! This script should normally be invoked from the repack directory
+goto end_failed
+
+:opt_i
+if ".%~2" == "."            goto syntax_error_missing_value
+set _MY_OPT_INPUT=%~2
+goto argument_loop_next_with_value
+
+:opt_n
+set _MY_OPT_SIGN_CAT=0
+shift
+goto argument_loop
+
+:opt_v
+set _MY_OPT_SIGN_VERIFY=0
+shift
+goto argument_loop
+
+:opt_ga
+set _MY_DRIVER_BASE_NAMES=%_MY_GUEST_ADDITIONS_DRIVER_BASE_NAMES%
+shift
+goto argument_loop
+
+:syntax_error_missing_value
+echo syntax error: missing or empty option value after %1
+goto end_failed
+
+:error_bindir_does_not_exist
+echo syntax error: Specified BIN directory does not exist: "%_MY_OPT_BINDIR%"
+goto end_failed
+
+:error_input_not_found
+echo error: Input file does not exist: "%_MY_OPT_INPUT%"
+goto end_failed
+
+:no_more_arguments
+rem validate specified options
+if not exist "%_MY_OPT_BINDIR%"     goto error_bindir_does_not_exist
+
+rem figure defaults here: if ".%_MY_OPT_INPUT%" == "." if exist "%_MY_OPT_BINDIR%\x86" set _MY_OPT_INPUT=VBoxDrivers-amd64.cab
+rem figure defaults here: if ".%_MY_OPT_INPUT%" == "."       set _MY_OPT_INPUT=VBoxDrivers-x86.cab
+if not exist "%_MY_OPT_INPUT%"      goto error_input_not_found
+
+rem
+rem Unpack the stuff.
+rem We ignore error level 1 here as that is what unzip returns on warning (slashes).
+rem
+"%_MY_UNZIP%" -o -j "%_MY_OPT_INPUT%" -d "%_MY_OPT_BINDIR%" && goto unzip_okay
+if NOT ERRORLEVEL 1 goto end_failed
+:unzip_okay
+
+if ".%_MY_OPT_SIGN_VERIFY%" == ".0" goto no_sign_verify
+rem
+rem Verify it against the PreW10 catalog files we saved.
+rem
+set _MY_SIGNTOOL=%KBUILD_DEVTOOLS%\win.x86\sdk\v8.1\bin\x86\signtool.exe
+if not exist "%_MY_SIGNTOOL%" set _MY_SIGNTOOL=%KBUILD_DEVTOOLS%\win.x86\selfsign\r3\signtool.exe
+
+for %%d in (%_MY_DRIVER_BASE_NAMES%) do (
+    @echo * Verifying %%d against %%d.cat...
+    "%_MY_SIGNTOOL%" verify /kp /c "%_MY_OPT_BINDIR%\%%d.cat"        "%_MY_OPT_BINDIR%\%%d.inf" || goto end_failed
+    "%_MY_SIGNTOOL%" verify /kp /c "%_MY_OPT_BINDIR%\%%d.cat"        "%_MY_OPT_BINDIR%\%%d.sys" || goto end_failed
+    rem The following is disabled because signtool.exe does not accept these
+    rem signatures because it fails to look at the timestamp. Eventually should
+    rem replace this by doing out own signature verification in RTSignTool.
+    rem @echo * Verifying %%d against %%d-PreW10.cat...
+    rem "%_MY_SIGNTOOL%" verify /kp /c "%_MY_OPT_BINDIR%\%%d-PreW10.cat" "%_MY_OPT_BINDIR%\%%d.inf" || goto end_failed
+    rem "%_MY_SIGNTOOL%" verify /kp /c "%_MY_OPT_BINDIR%\%%d-PreW10.cat" "%_MY_OPT_BINDIR%\%%d.sys" || goto end_failed
+)
+:no_sign_verify
+
+rem
+rem Modify the catalog signatures.
+rem
+if "%_MY_OPT_SIGN_CAT%" == "0" goto no_sign_cat
+set PATH=%PATH%;%_MY_OPT_BINDIR%
+for %%d in (%_MY_DRIVER_BASE_NAMES%) do (
+    copy /y "%_MY_OPT_BINDIR%\%%d.cat" "%_MY_OPT_BINDIR%\%%d.cat.ms" || goto end_failed
+    call sign-dual.cmd "%_MY_OPT_BINDIR%\%%d.cat" || goto end_failed
+    "%_MY_OPT_BINDIR%\tools\RTSignTool.exe"  add-nested-cat-signature -v "%_MY_OPT_BINDIR%\%%d.cat" "%_MY_OPT_BINDIR%\%%d.cat.ms" || goto end_failed
+)
+:no_sign_cat
+goto end
+
+:end_failed
+@echo failed (%ERRORLEVEL%)
+@endlocal
+@endlocal
+@exit /b 1
+
+:end
+@endlocal
+@endlocal
+
diff --git a/src/VBox/Installer/win/Scripts/VBoxExtPackPuel.inf b/src/VBox/Installer/win/Scripts/VBoxExtPackPuel.inf
new file mode 100644
index 00000000..8ee3e50c
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/VBoxExtPackPuel.inf
@@ -0,0 +1,69 @@
+; $Id: VBoxExtPackPuel.inf $
+;; @file
+; VBoxExtPackPuel - VirtualBox PUEL ExtPack drivers.
+;
+
+;
+; Copyright (C) 2018-2023 Oracle and/or its affiliates.
+;
+; This file is part of VirtualBox base platform packages, as
+; available from https://www.virtualbox.org.
+;
+; This program is free software; you can redistribute it and/or
+; modify it under the terms of the GNU General Public License
+; as published by the Free Software Foundation, in version 3 of the
+; License.
+;
+; This program is distributed in the hope that it will be useful, but
+; WITHOUT ANY WARRANTY; without even the implied warranty of
+; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+; General Public License for more details.
+;
+; You should have received a copy of the GNU General Public License
+; along with this program; if not, see <https://www.gnu.org/licenses>.
+;
+; SPDX-License-Identifier: GPL-3.0-only
+;
+
+[Version]
+Signature   = "$Windows NT$"
+Class       = System
+ClassGuid   = {4d36e97d-e325-11ce-bfc1-08002be10318}
+CatalogFile = VBoxExtPackPuel.cat
+Provider    = %ORACLE%
+;edit-DriverVer  = 08/26/2008,2.00.0000
+
+[SourceDisksNames]
+1=%VBoxExtPackPuel.DskDesc%,"",,
+
+[SourceDisksFiles]
+;VBoxEhciR0.r0=1
+VBoxNvmeR0.r0=1
+;VBoxPciRawR0.r0=1
+
+[DestinationDirs]
+DefaultDestDir = 12
+VBoxExtPackPuel_Install.Files = 12
+
+[Manufacturer]
+%ORACLE%=VBoxExtPackPuel@COMMA-NT-ARCH@
+
+[VBoxExtPackPuel@DOT-NT-ARCH@]
+%VBoxExtPackPuel.DrvDesc% = VBoxExtPackPuel_Install, root\VBoxExtPackPuel
+
+[VBoxExtPackPuel_Install]
+CopyFiles = VBoxExtPackPuel_CopyFiles
+
+[VBoxExtPackPuel_Install.Services]
+AddService=,2   ; Dummy service using the NULL driver.
+
+[VBoxExtPackPuel_CopyFiles]
+;VBoxEhciR0.r0,,,2
+VBoxNvmeR0.r0,,,2
+;VBoxPciRawR0.r0,,,2
+
+[Strings]
+ORACLE = "Oracle Corporation"
+VBoxExtPackPuel.DrvDesc = "VirtualBox PUEL ExtPack drivers"
+VBoxExtPackPuel.DskDesc = "VirtualBox PUEL ExtPack drivers"
+
diff --git a/src/VBox/Installer/win/Scripts/VMMR0.inf b/src/VBox/Installer/win/Scripts/VMMR0.inf
new file mode 100644
index 00000000..14c552a7
--- /dev/null
+++ b/src/VBox/Installer/win/Scripts/VMMR0.inf
@@ -0,0 +1,67 @@
+; $Id: VMMR0.inf $
+;; @file
+; VMMR0.inf - VirtualBox VMM drivers.
+;
+
+;
+; Copyright (C) 2018-2023 Oracle and/or its affiliates.
+;
+; This file is part of VirtualBox base platform packages, as
+; available from https://www.virtualbox.org.
+;
+; This program is free software; you can redistribute it and/or
+; modify it under the terms of the GNU General Public License
+; as published by the Free Software Foundation, in version 3 of the
+; License.
+;
+; This program is distributed in the hope that it will be useful, but
+; WITHOUT ANY WARRANTY; without even the implied warranty of
+; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+; General Public License for more details.
+;
+; You should have received a copy of the GNU General Public License
+; along with this program; if not, see <https://www.gnu.org/licenses>.
+;
+; SPDX-License-Identifier: GPL-3.0-only
+;
+
+[Version]
+Signature   = "$Windows NT$"
+Class       = System
+ClassGuid   = {4d36e97d-e325-11ce-bfc1-08002be10318}
+CatalogFile = VMMR0.cat
+Provider    = %ORACLE%
+;edit-DriverVer  = 08/26/2008,2.00.0000
+
+[SourceDisksNames]
+1=%VBoxVMM.DskDesc%,"",,
+
+[SourceDisksFiles]
+VMMR0.r0=1
+VBoxDDR0.r0=1
+
+[DestinationDirs]
+DefaultDestDir = 12
+VBoxVMM_Install.Files = 12
+
+[Manufacturer]
+%ORACLE%=VBoxVMM@COMMA-NT-ARCH@
+
+[VBoxVMM@DOT-NT-ARCH@]
+%VBoxVMM.DrvDesc% = VBoxVMM_Install, root\VBoxVMM
+
+[VBoxVMM_Install]
+CopyFiles = VBoxVMM_CopyFiles
+
+[VBoxVMM_Install.Services]
+AddService=,2   ; Dummy service using the NULL driver.
+
+[VBoxVMM_CopyFiles]
+VMMR0.r0,,,2
+VBoxDDR0.r0,,,2
+
+[Strings]
+ORACLE = "Oracle Corporation"
+VBoxVMM.DrvDesc = "VirtualBox VMM drivers"
+VBoxVMM.DskDesc = "VirtualBox VMM drivers"
+
author	Daniel Baumann <daniel.baumann@progress-linux.org>	2024-04-11 08:17:27 +0000
committer	Daniel Baumann <daniel.baumann@progress-linux.org>	2024-04-11 08:17:27 +0000
commit	f215e02bf85f68d3a6106c2a1f4f7f063f819064 (patch)
tree	6bb5b92c046312c4e95ac2620b10ddf482d3fa8b /src/VBox/Installer/win/Scripts
parent	Initial commit. (diff)
download	virtualbox-f215e02bf85f68d3a6106c2a1f4f7f063f819064.tar.xz virtualbox-f215e02bf85f68d3a6106c2a1f4f7f063f819064.zip