3 files changed, 94 insertions, 0 deletions
diff --git a/libc-top-half/musl/src/thread/mipsn32/__unmapself.s b/libc-top-half/musl/src/thread/mipsn32/__unmapself.s
new file mode 100644
index 0000000..4b032e5
--- /dev/null
+++ b/libc-top-half/musl/src/thread/mipsn32/__unmapself.s
@@ -0,0 +1,9 @@
+.set	noreorder
+.global	__unmapself
+.type	__unmapself,@function
+__unmapself:
+	li	$2, 6011
+	syscall
+	li	$4, 0
+	li	$2, 6058
+	syscall
diff --git a/libc-top-half/musl/src/thread/mipsn32/clone.s b/libc-top-half/musl/src/thread/mipsn32/clone.s
new file mode 100644
index 0000000..4d3c8c7
--- /dev/null
+++ b/libc-top-half/musl/src/thread/mipsn32/clone.s
@@ -0,0 +1,34 @@
+.set	noreorder
+.global	__clone
+.hidden __clone
+.type	__clone,@function
+__clone:
+	# Save function pointer and argument pointer on new thread stack
+	and	$5, $5, -16	# aligning stack to double word
+	subu	$5, $5, 16
+	sw	$4, 0($5)	# save function pointer
+	sw	$7, 4($5)	# save argument pointer
+
+	# Shuffle (fn,sp,fl,arg,ptid,tls,ctid) to (fl,sp,ptid,tls,ctid)
+	# sys_clone(u64 flags, u64 ustack_base, u64 parent_tidptr, u64 child_tidptr, u64 tls)
+	move	$4, $6
+	move	$6, $8
+	move	$7, $9
+	move	$8, $10
+	li	$2, 6055
+	syscall
+	beq	$7, $0, 1f
+	nop
+	jr	$ra
+	subu	$2, $0, $2
+1:	beq	$2, $0, 1f
+	nop
+	jr	$ra
+	nop
+1:	lw	$25, 0($sp)	# function pointer
+	lw	$4, 4($sp)	# argument pointer
+	jalr	$25		# call the user's function
+	nop
+	move 	$4, $2
+	li	$2, 6058
+	syscall
diff --git a/libc-top-half/musl/src/thread/mipsn32/syscall_cp.s b/libc-top-half/musl/src/thread/mipsn32/syscall_cp.s
new file mode 100644
index 0000000..e85615b
--- /dev/null
+++ b/libc-top-half/musl/src/thread/mipsn32/syscall_cp.s
@@ -0,0 +1,51 @@
+.set	noreorder
+.global	__cp_begin
+.hidden	__cp_begin
+.type	__cp_begin,@function
+.global	__cp_end
+.hidden	__cp_end
+.type	__cp_end,@function
+.global	__cp_cancel
+.hidden	__cp_cancel
+.type	__cp_cancel,@function
+.global	__cp_cancel_data
+.hidden	__cp_cancel_data
+.type	__cp_cancel_data,@function
+.hidden	__cancel
+.global	__syscall_cp_asm
+.hidden	__syscall_cp_asm
+.type	__syscall_cp_asm,@function
+__syscall_cp_asm:
+__cp_begin:
+	lw	$4, 0($4)
+	bne	$4, $0, __cp_cancel
+	move	$2, $5
+	move	$4, $6
+	move	$5, $7
+	move	$6, $8
+	move	$7, $9
+	move	$8, $10
+	move	$9, $11
+	lw	$10, 0($sp)
+	syscall
+__cp_end:
+	beq	$7, $0, 1f
+	nop
+	subu	$2, $0, $2
+1:	jr	$ra
+	nop
+
+	# if cancellation flag is 1 then call __cancel
+__cp_cancel:
+	move	$2, $ra
+	bal	1f
+	nop
+__cp_cancel_data:
+	.gpword __cp_cancel_data
+	.gpword __cancel
+1:	lw	$3, 0($ra)
+	subu	$3, $ra, $3
+	lw	$25, 4($ra)
+	addu	$25, $25, $3
+	jr	$25
+	move	$ra, $2