From 35504d91654321ff2b378229ff13150f53d5aad2 Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Sun, 7 Apr 2024 19:49:37 +0200
Subject: Adding upstream version 43.0.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 tools/meson.build | 71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 tools/meson.build

(limited to 'tools/meson.build')

diff --git a/tools/meson.build b/tools/meson.build
new file mode 100644
index 0000000..b21519d
--- /dev/null
+++ b/tools/meson.build
@@ -0,0 +1,71 @@
+deps = session_deps + [
+  sm_dep,
+  ice_dep
+]
+
+cflags = ['-DLOCALE_DIR="@0@"'.format(session_localedir)]
+
+programs = [
+  # name, deps, cflags, install_dir
+  ['gnome-session-quit', deps, cflags, session_bindir],
+  ['gnome-session-inhibit', session_deps, cflags, session_bindir]
+]
+
+if enable_systemd_session
+  programs += [['gnome-session-ctl', session_bin_deps, cflags, session_libexecdir]]
+endif
+
+if enable_session_selector
+  deps = [
+    glib_dep,
+    gtk_dep
+  ]
+
+  install_data(
+    'gnome-session-custom-session',
+    install_dir: session_bindir
+  )
+
+  cflags += '-DGTKBUILDER_DIR="@0@"'.format(session_pkgdatadir)
+
+  programs += [['gnome-session-selector', deps, cflags, session_bindir]]
+endif
+
+deps = [
+  gtk_dep,
+  x11_dep,
+  dependency('egl'),
+  dependency('glesv2')
+]
+
+cflags = '-DPKGDATADIR="@0@"'.format(session_pkgdatadir)
+
+programs += [['gnome-session-check-accelerated-gles-helper', deps, cflags, session_libexecdir]]
+
+deps = [
+  glib_dep,
+  x11_dep,
+  dependency('gl'),
+  dependency('epoxy'),
+  dependency('xcomposite')
+]
+
+programs += [['gnome-session-check-accelerated-gl-helper', deps, cflags, session_libexecdir]]
+
+deps += [gtk_dep]
+
+cflags = '-DLIBEXECDIR="@0@"'.format(session_libexecdir)
+
+programs += [['gnome-session-check-accelerated', deps, cflags, session_libexecdir]]
+
+foreach program: programs
+  executable(
+    program[0],
+    program[0] + '.c',
+    include_directories: top_inc,
+    dependencies: program[1],
+    c_args: program[2],
+    install: true,
+    install_dir: program[3]
+  )
+endforeach
-- 
cgit v1.2.3