From 6f0f7d1b40a8fa8d46a2d6f4317600001cdbbb18 Mon Sep 17 00:00:00 2001
From: Daniel Baumann <daniel.baumann@progress-linux.org>
Date: Sun, 7 Apr 2024 19:57:27 +0200
Subject: Adding upstream version 43.5.

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>
---
 plugins/flatpak/meson.build | 63 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 plugins/flatpak/meson.build

(limited to 'plugins/flatpak/meson.build')

diff --git a/plugins/flatpak/meson.build b/plugins/flatpak/meson.build
new file mode 100644
index 0000000..6a0baed
--- /dev/null
+++ b/plugins/flatpak/meson.build
@@ -0,0 +1,63 @@
+cargs = ['-DG_LOG_DOMAIN="GsPluginFlatpak"']
+deps = [
+  plugin_libs,
+  flatpak,
+  libxmlb,
+  ostree,
+]
+
+if get_option('mogwai')
+  deps += mogwai_schedule_client
+endif
+
+shared_module(
+  'gs_plugin_flatpak',
+  sources : [
+    'gs-flatpak-app.c',
+    'gs-flatpak.c',
+    'gs-flatpak-transaction.c',
+    'gs-flatpak-utils.c',
+    'gs-plugin-flatpak.c'
+  ],
+  include_directories : [
+    include_directories('../..'),
+    include_directories('../../lib'),
+  ],
+  install : true,
+  install_dir: plugin_dir,
+  c_args : cargs,
+  dependencies : deps,
+)
+metainfo = 'org.gnome.Software.Plugin.Flatpak.metainfo.xml'
+
+i18n.merge_file(
+  input: metainfo + '.in',
+  output: metainfo,
+  type: 'xml',
+  po_dir: join_paths(meson.project_source_root(), 'po'),
+  install: true,
+  install_dir: join_paths(get_option('datadir'), 'metainfo')
+)
+
+if get_option('tests')
+  subdir('tests')
+
+  cargs += ['-DLOCALPLUGINDIR="' + meson.current_build_dir() + '"']
+  cargs += ['-DLOCALPLUGINDIR_CORE="' + meson.current_build_dir() + '/../core"']
+  cargs += ['-DTESTDATADIR="' + join_paths(meson.current_build_dir(), 'tests') + '"']
+  e = executable(
+    'gs-self-test-flatpak',
+    compiled_schemas,
+    sources : [
+      'gs-flatpak-app.c',
+      'gs-self-test.c'
+    ],
+    include_directories : [
+      include_directories('../..'),
+      include_directories('../../lib'),
+    ],
+    dependencies : deps,
+    c_args : cargs,
+  )
+  test('gs-self-test-flatpak', e, suite: ['plugins', 'flatpak'], env: test_env, timeout : 120)
+endif
-- 
cgit v1.2.3