Adding upstream version 6.0.4-dfsg.upstream/6.0.4-dfsgupstream

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>

1 files changed, 88 insertions, 0 deletions

diff --git a/src/VBox/Runtime/common/err/errmsg.sed b/src/VBox/Runtime/common/err/errmsg.sed
new file mode 100644
index 00000000..cf7a8c7b
--- /dev/null
+++ b/src/VBox/Runtime/common/err/errmsg.sed
@@ -0,0 +1,88 @@
+# $Id: errmsg.sed $
+## @file
+# IPRT - SED script for converting */err.h.
+#
+
+#
+# Copyright (C) 2006-2019 Oracle Corporation
+#
+# This file is part of VirtualBox Open Source Edition (OSE), as
+# available from http://www.virtualbox.org. This file is free software;
+# you can redistribute it and/or modify it under the terms of the GNU
+# General Public License (GPL) as published by the Free Software
+# Foundation, in version 2 as it comes in the "COPYING" file of the
+# VirtualBox OSE distribution. VirtualBox OSE is distributed in the
+# hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
+#
+# The contents of this file may alternatively be used under the terms
+# of the Common Development and Distribution License Version 1.0
+# (CDDL) only, as it comes in the "COPYING.CDDL" file of the
+# VirtualBox OSE distribution, in which case the provisions of the
+# CDDL are applicable instead of those of the GPL.
+#
+# You may elect to license modified versions of this file under the
+# terms and conditions of either the GPL or the CDDL or both.
+#
+
+# Handle text inside the markers.
+/SED-START/,/SED-END/{
+
+# if (#define) goto defines
+/^[[:space:]]*#[[:space:]]*define/b defines
+
+# if (/**) goto description
+/\/\*\*/b description
+
+}
+
+# Everything else is deleted!
+d
+b end
+
+
+##
+# Convert the defines
+:defines
+s/^[[:space:]]*#[[:space:]]*define[[:space:]]*\([[:alnum:]_]*\)[[:space:]]*\(.*\)[[:space:]]*$/    "\1",\n     \1 }, /
+b end
+
+##
+# Convert descriptive comments. /** desc */
+:description
+
+# Read all the lines belonging to the comment into the buffer.
+:look-for-end-of-comment
+/\*\//bend-of-comment
+N
+blook-for-end-of-comment
+:end-of-comment
+
+# anything with @{ and @} is skipped
+/@[\{\}]/d
+
+# Fix double spaces
+s/[[:space:]][[:space:]]/ /g
+
+# Fix \# sequences (doxygen needs them, we don't).
+s/\\#/#/g
+
+# insert punctuation.
+s/\([^.[:space:]]\)[[:space:]]*\*\//\1. \*\//
+
+# convert /** short. more
+s/[[:space:]]*\/\*\*[[:space:]]*/  { NULL, \"/
+s/  { NULL, \"\([^.!?"]*[.!?][.!?]*\)/  { \"\1\",\n    \"\1/
+
+# terminate the string
+s/[[:space:]]*\*\//\"\,/
+
+# translate empty lines into new-lines (only one, please).
+s/[[:space:]]*[[:space:]]\*[[:space:]][[:space:]]*\*[[:space:]][[:space:]]*/\\n/g
+
+# remove asterics.
+s/[[:space:]]*[[:space:]]\*[[:space:]][[:space:]]*/ /g
+b end
+
+
+# next expression
+:end