lib/Devscripts/Salsa/list_repos.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Lists repositories of group/user
package Devscripts::Salsa::list_repos;

use strict;
use Devscripts::Output;
use Moo::Role;

sub list_repos {
    my ($self, $match) = @_;
    my $projects;
    my $count = 0;
    my $opts  = {
        order_by => 'name',
        sort     => 'asc',
        simple   => 1,
        archived => $self->config->archived,
        ($match ? (search => $match) : ()),
    };
    if ($self->group_id) {
        $projects
          = $self->api->paginator('group_projects', $self->group_id, $opts);
    } else {
        $projects
          = $self->api->paginator('user_projects', $self->user_id, $opts);
    }
    while ($_ = $projects->next) {
        $count++;
        print <<END;
Id  : $_->{id}
Name: $_->{name}
URL : $_->{web_url}

END
    }
    unless ($count) {
        ds_warn "No projects found";
        return 1;
    }
    return 0;
}

1;