blob: 460b4eec1ee888485c139ec2d6d95d78dddab7ea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
# Copyright © 2002 Adam Heath <doogie@debian.org>
# Copyright © 2012-2013 Guillem Jover <guillem@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <https://www.gnu.org/licenses/>.
package Dpkg::Exit;
use strict;
use warnings;
our $VERSION = '2.00';
our @EXPORT_OK = qw(
push_exit_handler
pop_exit_handler
run_exit_handlers
);
use Exporter qw(import);
my @handlers = ();
=encoding utf8
=head1 NAME
Dpkg::Exit - program exit handlers
=head1 DESCRIPTION
The Dpkg::Exit module provides support functions to run handlers on exit.
=head1 FUNCTIONS
=over 4
=item push_exit_handler($func)
Register a code reference into the exit function handlers stack.
=cut
sub push_exit_handler {
my ($func) = shift;
_setup_exit_handlers() if @handlers == 0;
push @handlers, $func;
}
=item pop_exit_handler()
Pop the last registered exit handler from the handlers stack.
=cut
sub pop_exit_handler {
_reset_exit_handlers() if @handlers == 1;
pop @handlers;
}
=item run_exit_handlers()
Run the registered exit handlers.
=cut
sub run_exit_handlers {
while (my $handler = pop @handlers) {
$handler->();
}
_reset_exit_handlers();
}
sub _exit_handler {
run_exit_handlers();
exit(127);
}
my @SIGNAMES = qw(INT HUP QUIT);
my %SIGOLD;
sub _setup_exit_handlers
{
foreach my $signame (@SIGNAMES) {
$SIGOLD{$signame} = $SIG{$signame};
$SIG{$signame} = \&_exit_handler;
}
}
sub _reset_exit_handlers
{
foreach my $signame (@SIGNAMES) {
$SIG{$signame} = $SIGOLD{$signame};
}
}
END {
local $?;
run_exit_handlers();
}
=back
=head1 CHANGES
=head2 Version 2.00 (dpkg 1.20.0)
Hide variable: @handlers.
=head2 Version 1.01 (dpkg 1.17.2)
New functions: push_exit_handler(), pop_exit_handler(), run_exit_handlers()
Deprecated variable: @handlers
=head2 Version 1.00 (dpkg 1.15.6)
Mark the module as public.
=cut
1;
|
