5 files changed, 98 insertions, 0 deletions
diff --git a/test cases/common/33 run program/check-env.py b/test cases/common/33 run program/check-env.py
new file mode 100644
index 0000000..ef04433
--- /dev/null
+++ b/test cases/common/33 run program/check-env.py
@@ -0,0 +1,5 @@
+#!/usr/bin/env python3
+
+import os
+
+assert os.environ['MY_PATH'] == os.pathsep.join(['0', '1', '2'])
diff --git a/test cases/common/33 run program/get-version.py b/test cases/common/33 run program/get-version.py
new file mode 100644
index 0000000..a22d559
--- /dev/null
+++ b/test cases/common/33 run program/get-version.py
@@ -0,0 +1,3 @@
+#!/usr/bin/env python3
+
+print('1.2')
diff --git a/test cases/common/33 run program/meson.build b/test cases/common/33 run program/meson.build
new file mode 100644
index 0000000..aa0a1d6
--- /dev/null
+++ b/test cases/common/33 run program/meson.build
@@ -0,0 +1,85 @@
+project('run command', version : run_command('get-version.py', check : true).stdout().strip())
+
+if build_machine.system() == 'windows'
+  c = run_command('cmd', '/c', 'echo', 'hello', check: false)
+else
+  c = run_command('echo', 'hello', check: false)
+endif
+
+correct = 'hello'
+
+if c.returncode() != 0
+  error('Executing echo failed.')
+endif
+
+result = c.stdout().strip()
+
+if result != correct
+  error('Getting stdout failed.')
+endif
+
+if c.stderr() != ''
+  error('Extra text in stderr.')
+endif
+
+# Now the same with a script.
+
+if build_machine.system() == 'windows'
+  cs = run_command('scripts/hello.bat', check: false)
+else
+  cs = run_command('scripts/hello.sh', check: false)
+endif
+
+if cs.returncode() != 0
+  error('Executing script failed.')
+endif
+
+if cs.stdout().strip() != correct
+  error('Getting stdout failed (script).')
+endif
+
+if cs.stderr() != ''
+  error('Extra text in stderr (script).')
+endif
+
+# We should be able to have files() in argument
+f = files('meson.build')
+
+if build_machine.system() == 'windows'
+  c = run_command('cmd', '/c', 'echo', f, check: false)
+else
+  c = run_command('echo', f, check: false)
+endif
+
+if c.returncode() != 0
+  error('Using files() in argument failed.')
+endif
+
+py3 = import('python3').find_python()
+
+ret = run_command(py3, '-c', 'print("some output")', check: false)
+assert(ret.returncode() == 0, 'failed to run python3: ' + ret.stderr())
+assert(ret.stdout() == 'some output\n', 'failed to run python3')
+
+ret = run_command(py3, '-c', 'print("some output")', check: false, capture: false)
+assert(ret.returncode() == 0, 'failed to run python3: ' + ret.stderr())
+assert(ret.stdout() == '', 'stdout is "@0@" instead of empty'.format(ret.stdout()))
+
+c_env = environment()
+c_env.append('CUSTOM_ENV_VAR', 'FOOBAR')
+ret = run_command(py3, '-c', 'import os; print(os.environ.get("CUSTOM_ENV_VAR"))', env: c_env, check: false)
+assert(ret.returncode() == 0, 'failed to run python3: ' + ret.stderr())
+assert(ret.stdout() == 'FOOBAR\n', 'stdout is "@0@" instead of FOOBAR'.format(ret.stdout()))
+
+dd = find_program('dd', required : false)
+if dd.found()
+  ret = run_command(dd, 'if=/dev/urandom', 'bs=10', 'count=1', check: false, capture: false)
+  assert(ret.returncode() == 0, 'failed to run dd: ' + ret.stderr())
+  assert(ret.stdout() == '', 'stdout is "@0@" instead of empty'.format(ret.stdout()))
+endif
+
+env = environment()
+env.append('MY_PATH', '1')
+env.append('MY_PATH', '2')
+env.prepend('MY_PATH', '0')
+run_command('check-env.py', env: env, check: true)
diff --git a/test cases/common/33 run program/scripts/hello.bat b/test cases/common/33 run program/scripts/hello.bat
new file mode 100644
index 0000000..cbc346b
--- /dev/null
+++ b/test cases/common/33 run program/scripts/hello.bat
@@ -0,0 +1,2 @@
+@ECHO OFF
+ECHO hello
diff --git a/test cases/common/33 run program/scripts/hello.sh b/test cases/common/33 run program/scripts/hello.sh
new file mode 100755
index 0000000..2a22daa
--- /dev/null
+++ b/test cases/common/33 run program/scripts/hello.sh
@@ -0,0 +1,3 @@
+#!/bin/sh
+
+echo hello