7 files changed, 153 insertions, 0 deletions
diff --git a/test cases/python/2 extmodule/blaster.py.in b/test cases/python/2 extmodule/blaster.py.in
new file mode 100755
index 0000000..b690b40
--- /dev/null
+++ b/test cases/python/2 extmodule/blaster.py.in
@@ -0,0 +1,11 @@
+#!/usr/bin/env python3
+
+import @tachyon_module@ as tachyon
+
+result = tachyon.phaserize('shoot')
+
+if not isinstance(result, int):
+    raise SystemExit('Returned result not an integer.')
+
+if result != 1:
+    raise SystemExit(f'Returned result {result} is not 1.')
diff --git a/test cases/python/2 extmodule/ext/meson.build b/test cases/python/2 extmodule/ext/meson.build
new file mode 100644
index 0000000..14fa94a
--- /dev/null
+++ b/test cases/python/2 extmodule/ext/meson.build
@@ -0,0 +1,9 @@
+pylib = py.extension_module('tachyon',
+  'tachyon_module.c',
+  c_args: '-DMESON_MODULENAME="tachyon"',
+  install: true,
+)
+
+subdir('nested')
+subdir('wrongdir')
+pypathdir = meson.current_build_dir()
diff --git a/test cases/python/2 extmodule/ext/nested/meson.build b/test cases/python/2 extmodule/ext/nested/meson.build
new file mode 100644
index 0000000..34c1192
--- /dev/null
+++ b/test cases/python/2 extmodule/ext/nested/meson.build
@@ -0,0 +1,15 @@
+py.extension_module('tachyon',
+  '../tachyon_module.c',
+  c_args: '-DMESON_MODULENAME="nested.tachyon"',
+  install: true,
+  subdir: 'nested'
+)
+py.install_sources(
+  configure_file(
+    input: '../../blaster.py.in',
+    output: 'blaster.py',
+    configuration: {'tachyon_module': 'nested.tachyon'}
+  ),
+  pure: false,
+  subdir: 'nested',
+)
diff --git a/test cases/python/2 extmodule/ext/tachyon_module.c b/test cases/python/2 extmodule/ext/tachyon_module.c
new file mode 100644
index 0000000..a5d7cdc
--- /dev/null
+++ b/test cases/python/2 extmodule/ext/tachyon_module.c
@@ -0,0 +1,49 @@
+/*
+  Copyright 2016 The Meson development team
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+      http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+*/
+
+/* A very simple Python extension module. */
+
+#include <Python.h>
+#include <string.h>
+
+static PyObject* phaserize(PyObject *self, PyObject *args) {
+    const char *message;
+    int result;
+
+    if(!PyArg_ParseTuple(args, "s", &message))
+        return NULL;
+
+    result = strcmp(message, "shoot") ? 0 : 1;
+    return PyLong_FromLong(result);
+}
+
+static PyMethodDef TachyonMethods[] = {
+    {"phaserize",  phaserize, METH_VARARGS,
+     "Shoot tachyon cannons."},
+    {NULL, NULL, 0, NULL}
+};
+
+static struct PyModuleDef tachyonmodule = {
+   PyModuleDef_HEAD_INIT,
+   MESON_MODULENAME,
+   NULL,
+   -1,
+   TachyonMethods
+};
+
+PyMODINIT_FUNC PyInit_tachyon(void) {
+    return PyModule_Create(&tachyonmodule);
+}
diff --git a/test cases/python/2 extmodule/ext/wrongdir/meson.build b/test cases/python/2 extmodule/ext/wrongdir/meson.build
new file mode 100644
index 0000000..5074701
--- /dev/null
+++ b/test cases/python/2 extmodule/ext/wrongdir/meson.build
@@ -0,0 +1,6 @@
+py.extension_module('tachyon',
+  '../tachyon_module.c',
+  c_args: '-DMESON_MODULENAME="tachyon"',
+  install: true,
+  install_dir: get_option('libdir')
+)
diff --git a/test cases/python/2 extmodule/meson.build b/test cases/python/2 extmodule/meson.build
new file mode 100644
index 0000000..239492c
--- /dev/null
+++ b/test cases/python/2 extmodule/meson.build
@@ -0,0 +1,50 @@
+project('Python extension module', 'c',
+  default_options : ['buildtype=release'])
+# Because Windows Python ships only with optimized libs,
+# we must build this project the same way.
+
+if meson.backend() != 'ninja'
+  error('MESON_SKIP_TEST: Ninja backend required')
+endif
+
+
+py_mod = import('python')
+py = py_mod.find_installation()
+py_dep = py.dependency(required: false)
+
+if not py_dep.found()
+  error('MESON_SKIP_TEST: Python libraries not found.')
+endif
+
+subdir('ext')
+
+blaster = configure_file(
+  input: 'blaster.py.in',
+  output: 'blaster.py',
+  configuration: {'tachyon_module': 'tachyon'}
+)
+
+test('extmod',
+  py,
+  args : blaster,
+  env : ['PYTHONPATH=' + pypathdir])
+
+py.install_sources(blaster, pure: false)
+py.install_sources(blaster, subdir: 'pure')
+
+py3_pkg_dep = dependency('python3', method: 'pkg-config', required : false)
+if py3_pkg_dep.found()
+  py3_dep_majver = py3_pkg_dep.version().split('.')
+  py3_dep_majver = py3_dep_majver[0] + '.' + py3_dep_majver[1]
+  message(f'got two pythons: pkg-config is @py3_dep_majver@, and module is', py.language_version())
+  if py3_dep_majver != py.language_version()
+    message('skipped python3 pkg-config test because the default python3 is different from Meson\'s')
+  else
+    python_lib_dir = py3_pkg_dep.get_pkgconfig_variable('libdir')
+
+    # Check we can apply a version constraint
+    dependency('python3', version: '>=@0@'.format(py_dep.version()))
+  endif
+else
+  message('Skipped python3 pkg-config test because it was not found')
+endif
diff --git a/test cases/python/2 extmodule/test.json b/test cases/python/2 extmodule/test.json
new file mode 100644
index 0000000..6bd1195
--- /dev/null
+++ b/test cases/python/2 extmodule/test.json
@@ -0,0 +1,13 @@
+{
+  "installed": [
+    { "type": "python_file", "file": "usr/@PYTHON_PLATLIB@/blaster.py" },
+    { "type": "python_lib",  "file": "usr/@PYTHON_PLATLIB@/tachyon" },
+    { "type": "py_implib",   "file": "usr/@PYTHON_PLATLIB@/tachyon" },
+    { "type": "python_file", "file": "usr/@PYTHON_PURELIB@/pure/blaster.py" },
+    { "type": "python_file", "file": "usr/@PYTHON_PLATLIB@/nested/blaster.py" },
+    { "type": "python_lib",  "file": "usr/@PYTHON_PLATLIB@/nested/tachyon" },
+    { "type": "py_implib",   "file": "usr/@PYTHON_PLATLIB@/nested/tachyon" },
+    { "type": "python_lib",  "file": "usr/lib/tachyon" },
+    { "type": "py_implib",   "file": "usr/lib/tachyon" }
+  ]
+}