1 files changed, 122 insertions, 0 deletions
diff --git a/src/VBox/Runtime/common/string/memcpy.asm b/src/VBox/Runtime/common/string/memcpy.asm
new file mode 100644
index 00000000..8f056325
--- /dev/null
+++ b/src/VBox/Runtime/common/string/memcpy.asm
@@ -0,0 +1,122 @@
+; $Id: memcpy.asm $
+;; @file
+; IPRT - No-CRT memcpy - AMD64 & X86.
+;
+
+;
+; Copyright (C) 2006-2022 Oracle and/or its affiliates.
+;
+; This file is part of VirtualBox base platform packages, as
+; available from https://www.virtualbox.org.
+;
+; This program is free software; you can redistribute it and/or
+; modify it under the terms of the GNU General Public License
+; as published by the Free Software Foundation, in version 3 of the
+; License.
+;
+; This program is distributed in the hope that it will be useful, but
+; WITHOUT ANY WARRANTY; without even the implied warranty of
+; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+; General Public License for more details.
+;
+; You should have received a copy of the GNU General Public License
+; along with this program; if not, see <https://www.gnu.org/licenses>.
+;
+; The contents of this file may alternatively be used under the terms
+; of the Common Development and Distribution License Version 1.0
+; (CDDL), a copy of it is provided in the "COPYING.CDDL" file included
+; in the VirtualBox distribution, in which case the provisions of the
+; CDDL are applicable instead of those of the GPL.
+;
+; You may elect to license modified versions of this file under the
+; terms and conditions of either the GPL or the CDDL or both.
+;
+; SPDX-License-Identifier: GPL-3.0-only OR CDDL-1.0
+;
+
+%include "iprt/asmdefs.mac"
+
+BEGINCODE
+
+;;
+; @param    pvDst   gcc: rdi  msc: rcx  x86:[esp+4]   wcall: eax
+; @param    pvSrc   gcc: rsi  msc: rdx  x86:[esp+8]   wcall: edx
+; @param    cb      gcc: rdx  msc: r8   x86:[esp+0ch] wcall: ebx
+%ifdef IN_RING0_DRV_ON_DARWIN
+global NAME(memcpy):private_extern
+NAME(memcpy):
+%else
+RT_NOCRT_BEGINPROC memcpy
+%endif
+        cld
+
+        ; Do the bulk of the work.
+%ifdef RT_ARCH_AMD64
+ %ifdef DEBUG
+        push    rbp
+        mov     rbp, rsp
+ %endif
+ %ifdef ASM_CALL64_MSC
+        mov     r10, rdi                ; save
+        mov     r11, rsi                ; save
+        mov     rdi, rcx
+        mov     rsi, rdx
+        mov     rcx, r8
+        mov     rdx, r8
+ %else
+        mov     rcx, rdx
+ %endif
+        mov     rax, rdi                ; save the return value
+        shr     rcx, 3
+        rep movsq
+%else
+        push    edi
+        push    esi
+
+ %ifdef ASM_CALL32_WATCOM
+        mov     edi, eax
+        mov     esi, edx
+        mov     ecx, ebx
+        mov     edx, ebx
+ %else
+        mov     ecx, [esp + 0ch + 8]
+        mov     edi, [esp + 04h + 8]
+        mov     esi, [esp + 08h + 8]
+        mov     edx, ecx
+        mov     eax, edi                ; save the return value
+ %endif
+        shr     ecx, 2
+        rep movsd
+%endif
+
+        ; The remaining bytes.
+%ifdef RT_ARCH_AMD64
+        test    dl, 4
+        jz      .dont_move_dword
+        movsd
+%endif
+.dont_move_dword:
+        test    dl, 2
+        jz      .dont_move_word
+        movsw
+.dont_move_word:
+        test    dl, 1
+        jz      .dont_move_byte
+        movsb
+.dont_move_byte:
+
+%ifdef RT_ARCH_AMD64
+ %ifdef ASM_CALL64_MSC
+        mov     rdi, r10
+        mov     rsi, r11
+ %endif
+ %ifdef DEBUG
+        leave
+ %endif
+%else
+        pop     esi
+        pop     edi
+%endif
+        ret
+ENDPROC RT_NOCRT(memcpy)
+