1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
panels_list += cappletname
desktop = 'gnome-@0@-panel.desktop'.format(cappletname)
desktop_in = configure_file(
input: desktop + '.in.in',
output: desktop + '.in',
configuration: desktop_conf
)
i18n.merge_file(
desktop,
type: 'desktop',
input: desktop_in,
output: desktop,
po_dir: po_dir,
install: true,
install_dir: control_center_desktopdir
)
polkit_conf = configuration_data()
polkit_conf.set('libexecdir', control_center_libexecdir)
polkit = 'org.gnome.controlcenter.remote-login-helper.policy'
polkit_in = configure_file(
input: polkit + '.in.in',
output: polkit + '.in',
configuration: polkit_conf
)
i18n.merge_file(
polkit,
input: polkit_in,
output: polkit,
po_dir: po_dir,
install: true,
install_dir: join_paths(control_center_datadir, 'polkit-1', 'actions')
)
sources = files(
'cc-sharing-panel.c',
'cc-media-sharing.c',
'cc-remote-login.c',
'cc-sharing-networks.c',
'cc-sharing-switch.c',
'cc-gnome-remote-desktop.c',
'file-share-properties.c',
)
resource_data = files(
'cc-sharing-panel.ui',
'cc-sharing-networks.ui',
)
sources += gnome.compile_resources(
'cc-' + cappletname + '-resources',
cappletname + '.gresource.xml',
c_name: 'cc_' + cappletname,
dependencies: resource_data,
export: true
)
settings_daemon = 'org.gnome.SettingsDaemon'
gdbus = settings_daemon + '.Sharing'
sources += gnome.gdbus_codegen(
gdbus,
gdbus + '.xml',
interface_prefix: settings_daemon + '.',
namespace: 'Gsd'
)
cflags += [
'-DLIBEXECDIR="@0@"'.format(control_center_libexecdir),
'-DSYSCONFDIR="@0@"'.format(control_center_sysconfdir)
]
libsecret_dep = dependency('libsecret-1')
panels_libs += static_library(
cappletname,
sources: sources,
include_directories: [ top_inc, common_inc ],
dependencies: [common_deps, libsecret_dep],
c_args: cflags
)
name = 'cc-remote-login-helper'
deps = [
gio_dep,
glib_dep
]
executable(
name,
name + '.c',
include_directories: top_inc,
dependencies: deps,
c_args: cflags,
install: true,
install_dir: control_center_libexecdir
)
|
