1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
|
;;
;; Copyright (c) 2012-2018, Intel Corporation
;;
;; Redistribution and use in source and binary forms, with or without
;; modification, are permitted provided that the following conditions are met:
;;
;; * Redistributions of source code must retain the above copyright notice,
;; this list of conditions and the following disclaimer.
;; * Redistributions in binary form must reproduce the above copyright
;; notice, this list of conditions and the following disclaimer in the
;; documentation and/or other materials provided with the distribution.
;; * Neither the name of Intel Corporation nor the names of its contributors
;; may be used to endorse or promote products derived from this software
;; without specific prior written permission.
;;
;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
;; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
;; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
;; DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE
;; FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
;; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
;; CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
;; OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
;;
; Routine to do AES key expansion
%include "include/os.asm"
%define NO_AESNI_RENAME
%include "include/aesni_emu.inc"
%include "include/clear_regs.asm"
%macro key_expansion_128_sse 0
;; Assumes the xmm3 includes all zeros at this point.
pshufd xmm2, xmm2, 11111111b
shufps xmm3, xmm1, 00010000b
pxor xmm1, xmm3
shufps xmm3, xmm1, 10001100b
pxor xmm1, xmm3
pxor xmm1, xmm2
%endmacro
%macro key_expansion_128_avx 0
;; Assumes the xmm3 includes all zeros at this point.
vpshufd xmm2, xmm2, 11111111b
vshufps xmm3, xmm3, xmm1, 00010000b
vpxor xmm1, xmm1, xmm3
vshufps xmm3, xmm3, xmm1, 10001100b
vpxor xmm1, xmm1, xmm3
vpxor xmm1, xmm1, xmm2
%endmacro
%ifdef LINUX
%define KEY rdi
%define EXP_ENC_KEYS rsi
%define EXP_DEC_KEYS rdx
%else
%define KEY rcx
%define EXP_ENC_KEYS rdx
%define EXP_DEC_KEYS r8
%endif
section .text
; void aes_keyexp_128(UINT128 *key,
; UINT128 *enc_exp_keys,
; UINT128 *dec_exp_keys);
;
; arg 1: rcx: pointer to key
; arg 2: rdx: pointer to expanded key array for encrypt
; arg 3: r8: pointer to expanded key array for decrypt
;
MKGLOBAL(aes_keyexp_128_sse,function,)
aes_keyexp_128_sse:
%ifdef SAFE_PARAM
cmp KEY, 0
jz aes_keyexp_128_sse_return
cmp EXP_ENC_KEYS, 0
jz aes_keyexp_128_sse_return
cmp EXP_DEC_KEYS, 0
jz aes_keyexp_128_sse_return
%endif
movdqu xmm1, [KEY] ; loading the AES key
movdqa [EXP_ENC_KEYS + 16*0], xmm1
movdqa [EXP_DEC_KEYS + 16*10], xmm1 ; Storing key in memory
pxor xmm3, xmm3
aeskeygenassist xmm2, xmm1, 0x1 ; Generating round key 1
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*1], xmm1
aesimc xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*9], xmm4
aeskeygenassist xmm2, xmm1, 0x2 ; Generating round key 2
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*2], xmm1
aesimc xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*8], xmm5
aeskeygenassist xmm2, xmm1, 0x4 ; Generating round key 3
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*3], xmm1
aesimc xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*7], xmm4
aeskeygenassist xmm2, xmm1, 0x8 ; Generating round key 4
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*4], xmm1
aesimc xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*6], xmm5
aeskeygenassist xmm2, xmm1, 0x10 ; Generating round key 5
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*5], xmm1
aesimc xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*5], xmm4
aeskeygenassist xmm2, xmm1, 0x20 ; Generating round key 6
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*6], xmm1
aesimc xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*4], xmm5
aeskeygenassist xmm2, xmm1, 0x40 ; Generating round key 7
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*7], xmm1
aesimc xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*3], xmm4
aeskeygenassist xmm2, xmm1, 0x80 ; Generating round key 8
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*8], xmm1
aesimc xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*2], xmm5
aeskeygenassist xmm2, xmm1, 0x1b ; Generating round key 9
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*9], xmm1
aesimc xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*1], xmm4
aeskeygenassist xmm2, xmm1, 0x36 ; Generating round key 10
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*10], xmm1
movdqa [EXP_DEC_KEYS + 16*0], xmm1
aes_keyexp_128_sse_return:
%ifdef SAFE_DATA
clear_scratch_gps_asm
clear_scratch_xmms_sse_asm
%endif
ret
MKGLOBAL(aes_keyexp_128_sse_no_aesni,function,)
aes_keyexp_128_sse_no_aesni:
%ifdef SAFE_PARAM
cmp KEY, 0
jz aes_keyexp_128_sse_no_aesni_return
cmp EXP_ENC_KEYS, 0
jz aes_keyexp_128_sse_no_aesni_return
cmp EXP_DEC_KEYS, 0
jz aes_keyexp_128_sse_no_aesni_return
%endif
movdqu xmm1, [KEY] ; loading the AES key
movdqa [EXP_ENC_KEYS + 16*0], xmm1
movdqa [EXP_DEC_KEYS + 16*10], xmm1 ; Storing key in memory
pxor xmm3, xmm3
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x1 ; Generating round key 1
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*1], xmm1
EMULATE_AESIMC xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*9], xmm4
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x2 ; Generating round key 2
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*2], xmm1
EMULATE_AESIMC xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*8], xmm5
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x4 ; Generating round key 3
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*3], xmm1
EMULATE_AESIMC xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*7], xmm4
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x8 ; Generating round key 4
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*4], xmm1
EMULATE_AESIMC xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*6], xmm5
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x10 ; Generating round key 5
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*5], xmm1
EMULATE_AESIMC xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*5], xmm4
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x20 ; Generating round key 6
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*6], xmm1
EMULATE_AESIMC xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*4], xmm5
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x40 ; Generating round key 7
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*7], xmm1
EMULATE_AESIMC xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*3], xmm4
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x80 ; Generating round key 8
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*8], xmm1
EMULATE_AESIMC xmm5, xmm1
movdqa [EXP_DEC_KEYS + 16*2], xmm5
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x1b ; Generating round key 9
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*9], xmm1
EMULATE_AESIMC xmm4, xmm1
movdqa [EXP_DEC_KEYS + 16*1], xmm4
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x36 ; Generating round key 10
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*10], xmm1
movdqa [EXP_DEC_KEYS + 16*0], xmm1
aes_keyexp_128_sse_no_aesni_return:
%ifdef SAFE_DATA
clear_scratch_gps_asm
clear_scratch_xmms_sse_asm
%endif
ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
MKGLOBAL(aes_keyexp_128_avx,function,)
MKGLOBAL(aes_keyexp_128_avx2,function,)
MKGLOBAL(aes_keyexp_128_avx512,function,)
aes_keyexp_128_avx:
aes_keyexp_128_avx2:
aes_keyexp_128_avx512:
%ifdef SAFE_PARAM
cmp KEY, 0
jz aes_keyexp_128_avx_return
cmp EXP_ENC_KEYS, 0
jz aes_keyexp_128_avx_return
cmp EXP_DEC_KEYS, 0
jz aes_keyexp_128_avx_return
%endif
vmovdqu xmm1, [KEY] ; loading the AES key
vmovdqa [EXP_ENC_KEYS + 16*0], xmm1
vmovdqa [EXP_DEC_KEYS + 16*10], xmm1 ; Storing key in memory
vpxor xmm3, xmm3, xmm3
vaeskeygenassist xmm2, xmm1, 0x1 ; Generating round key 1
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*1], xmm1
vaesimc xmm4, xmm1
vmovdqa [EXP_DEC_KEYS + 16*9], xmm4
vaeskeygenassist xmm2, xmm1, 0x2 ; Generating round key 2
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*2], xmm1
vaesimc xmm5, xmm1
vmovdqa [EXP_DEC_KEYS + 16*8], xmm5
vaeskeygenassist xmm2, xmm1, 0x4 ; Generating round key 3
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*3], xmm1
vaesimc xmm4, xmm1
vmovdqa [EXP_DEC_KEYS + 16*7], xmm4
vaeskeygenassist xmm2, xmm1, 0x8 ; Generating round key 4
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*4], xmm1
vaesimc xmm5, xmm1
vmovdqa [EXP_DEC_KEYS + 16*6], xmm5
vaeskeygenassist xmm2, xmm1, 0x10 ; Generating round key 5
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*5], xmm1
vaesimc xmm4, xmm1
vmovdqa [EXP_DEC_KEYS + 16*5], xmm4
vaeskeygenassist xmm2, xmm1, 0x20 ; Generating round key 6
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*6], xmm1
vaesimc xmm5, xmm1
vmovdqa [EXP_DEC_KEYS + 16*4], xmm5
vaeskeygenassist xmm2, xmm1, 0x40 ; Generating round key 7
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*7], xmm1
vaesimc xmm4, xmm1
vmovdqa [EXP_DEC_KEYS + 16*3], xmm4
vaeskeygenassist xmm2, xmm1, 0x80 ; Generating round key 8
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*8], xmm1
vaesimc xmm5, xmm1
vmovdqa [EXP_DEC_KEYS + 16*2], xmm5
vaeskeygenassist xmm2, xmm1, 0x1b ; Generating round key 9
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*9], xmm1
vaesimc xmm4, xmm1
vmovdqa [EXP_DEC_KEYS + 16*1], xmm4
vaeskeygenassist xmm2, xmm1, 0x36 ; Generating round key 10
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*10], xmm1
vmovdqa [EXP_DEC_KEYS + 16*0], xmm1
aes_keyexp_128_avx_return:
%ifdef SAFE_DATA
clear_scratch_gps_asm
clear_scratch_xmms_avx_asm
%endif
ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; void aes_keyexp_128_enc_sse(UINT128 *key,
; UINT128 *enc_exp_keys);
;
; arg 1: rcx: pointer to key
; arg 2: rdx: pointer to expanded key array for encrypt
;
MKGLOBAL(aes_keyexp_128_enc_sse,function,)
aes_keyexp_128_enc_sse:
%ifdef SAFE_PARAM
cmp KEY, 0
jz aes_keyexp_128_enc_sse_return
cmp EXP_ENC_KEYS, 0
jz aes_keyexp_128_enc_sse_return
%endif
movdqu xmm1, [KEY] ; loading the AES key
movdqa [EXP_ENC_KEYS + 16*0], xmm1
pxor xmm3, xmm3
aeskeygenassist xmm2, xmm1, 0x1 ; Generating round key 1
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*1], xmm1
aeskeygenassist xmm2, xmm1, 0x2 ; Generating round key 2
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*2], xmm1
aeskeygenassist xmm2, xmm1, 0x4 ; Generating round key 3
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*3], xmm1
aeskeygenassist xmm2, xmm1, 0x8 ; Generating round key 4
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*4], xmm1
aeskeygenassist xmm2, xmm1, 0x10 ; Generating round key 5
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*5], xmm1
aeskeygenassist xmm2, xmm1, 0x20 ; Generating round key 6
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*6], xmm1
aeskeygenassist xmm2, xmm1, 0x40 ; Generating round key 7
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*7], xmm1
aeskeygenassist xmm2, xmm1, 0x80 ; Generating round key 8
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*8], xmm1
aeskeygenassist xmm2, xmm1, 0x1b ; Generating round key 9
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*9], xmm1
aeskeygenassist xmm2, xmm1, 0x36 ; Generating round key 10
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*10], xmm1
aes_keyexp_128_enc_sse_return:
ret
MKGLOBAL(aes_keyexp_128_enc_sse_no_aesni,function,)
aes_keyexp_128_enc_sse_no_aesni:
%ifdef SAFE_PARAM
cmp KEY, 0
jz aes_keyexp_128_enc_sse_no_aesni_return
cmp EXP_ENC_KEYS, 0
jz aes_keyexp_128_enc_sse_no_aesni_return
%endif
movdqu xmm1, [KEY] ; loading the AES key
movdqa [EXP_ENC_KEYS + 16*0], xmm1
pxor xmm3, xmm3
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x1 ; Generating round key 1
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*1], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x2 ; Generating round key 2
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*2], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x4 ; Generating round key 3
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*3], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x8 ; Generating round key 4
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*4], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x10 ; Generating round key 5
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*5], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x20 ; Generating round key 6
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*6], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x40 ; Generating round key 7
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*7], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x80 ; Generating round key 8
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*8], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x1b ; Generating round key 9
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*9], xmm1
EMULATE_AESKEYGENASSIST xmm2, xmm1, 0x36 ; Generating round key 10
key_expansion_128_sse
movdqa [EXP_ENC_KEYS + 16*10], xmm1
aes_keyexp_128_enc_sse_no_aesni_return:
ret
MKGLOBAL(aes_keyexp_128_enc_avx,function,)
MKGLOBAL(aes_keyexp_128_enc_avx2,function,)
MKGLOBAL(aes_keyexp_128_enc_avx512,function,)
aes_keyexp_128_enc_avx:
aes_keyexp_128_enc_avx2:
aes_keyexp_128_enc_avx512:
%ifdef SAFE_PARAM
cmp KEY, 0
jz aes_keyexp_128_enc_avx_return
cmp EXP_ENC_KEYS, 0
jz aes_keyexp_128_enc_avx_return
%endif
vmovdqu xmm1, [KEY] ; loading the AES key
vmovdqa [EXP_ENC_KEYS + 16*0], xmm1
vpxor xmm3, xmm3, xmm3
vaeskeygenassist xmm2, xmm1, 0x1 ; Generating round key 1
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*1], xmm1
vaeskeygenassist xmm2, xmm1, 0x2 ; Generating round key 2
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*2], xmm1
vaeskeygenassist xmm2, xmm1, 0x4 ; Generating round key 3
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*3], xmm1
vaeskeygenassist xmm2, xmm1, 0x8 ; Generating round key 4
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*4], xmm1
vaeskeygenassist xmm2, xmm1, 0x10 ; Generating round key 5
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*5], xmm1
vaeskeygenassist xmm2, xmm1, 0x20 ; Generating round key 6
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*6], xmm1
vaeskeygenassist xmm2, xmm1, 0x40 ; Generating round key 7
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*7], xmm1
vaeskeygenassist xmm2, xmm1, 0x80 ; Generating round key 8
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*8], xmm1
vaeskeygenassist xmm2, xmm1, 0x1b ; Generating round key 9
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*9], xmm1
vaeskeygenassist xmm2, xmm1, 0x36 ; Generating round key 10
key_expansion_128_avx
vmovdqa [EXP_ENC_KEYS + 16*10], xmm1
aes_keyexp_128_enc_avx_return:
ret
%ifdef LINUX
section .note.GNU-stack noalloc noexec nowrite progbits
%endif
|
