1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
|
;;
;; Copyright (c) 2012-2018, Intel Corporation
;;
;; Redistribution and use in source and binary forms, with or without
;; modification, are permitted provided that the following conditions are met:
;;
;; * Redistributions of source code must retain the above copyright notice,
;; this list of conditions and the following disclaimer.
;; * Redistributions in binary form must reproduce the above copyright
;; notice, this list of conditions and the following disclaimer in the
;; documentation and/or other materials provided with the distribution.
;; * Neither the name of Intel Corporation nor the names of its contributors
;; may be used to endorse or promote products derived from this software
;; without specific prior written permission.
;;
;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
;; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
;; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
;; DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE
;; FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
;; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
;; CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
;; OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
;;
; routine to do AES128 CBC decrypt "by8"
;; clobbers xmm0-15
%include "include/os.asm"
%define CONCAT(a,b) a %+ b
%define VMOVDQ vmovdqu
%define xdata0 xmm0
%define xdata1 xmm1
%define xdata2 xmm2
%define xdata3 xmm3
%define xdata4 xmm4
%define xdata5 xmm5
%define xdata6 xmm6
%define xdata7 xmm7
%define xIV xmm8
%define xkey0 xmm9
%define xkey2 xmm10
%define xkey4 xmm11
%define xkey6 xmm12
%define xkey8 xmm13
%define xkey10 xmm14
%define xkeytmp xmm15
%ifdef LINUX
%define p_in rdi
%define p_IV rsi
%define p_keys rdx
%define p_out rcx
%define num_bytes r8
%else
%define p_in rcx
%define p_IV rdx
%define p_keys r8
%define p_out r9
%define num_bytes rax
%endif
%define tmp r10
%macro do_aes_load 1
do_aes %1, 1
%endmacro
%macro do_aes_noload 1
do_aes %1, 0
%endmacro
; do_aes num_in_par load_keys
; This increments p_in, but not p_out
%macro do_aes 2
%define %%by %1
%define %%load_keys %2
%if (%%load_keys)
vmovdqa xkey0, [p_keys + 0*16]
%endif
%assign i 0
%rep %%by
VMOVDQ CONCAT(xdata,i), [p_in + i*16]
%assign i (i+1)
%endrep
%if (%%load_keys)
vmovdqa xkey2, [p_keys + 2*16]
%endif
%assign i 0
%rep %%by
vpxor CONCAT(xdata,i), CONCAT(xdata,i), xkey0
%assign i (i+1)
%endrep
add p_in, 16*%%by
vmovdqa xkeytmp, [p_keys + 1*16]
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkeytmp
%assign i (i+1)
%endrep
%if (%%load_keys)
vmovdqa xkey4, [p_keys + 4*16]
%endif
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkey2
%assign i (i+1)
%endrep
vmovdqa xkeytmp, [p_keys + 3*16]
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkeytmp
%assign i (i+1)
%endrep
%if (%%load_keys)
vmovdqa xkey6, [p_keys + 6*16]
%endif
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkey4
%assign i (i+1)
%endrep
vmovdqa xkeytmp, [p_keys + 5*16]
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkeytmp
%assign i (i+1)
%endrep
%if (%%load_keys)
vmovdqa xkey8, [p_keys + 8*16]
%endif
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkey6
%assign i (i+1)
%endrep
vmovdqa xkeytmp, [p_keys + 7*16]
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkeytmp
%assign i (i+1)
%endrep
%if (%%load_keys)
vmovdqa xkey10, [p_keys + 10*16]
%endif
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkey8
%assign i (i+1)
%endrep
vmovdqa xkeytmp, [p_keys + 9*16]
%assign i 0
%rep %%by
vaesdec CONCAT(xdata,i), CONCAT(xdata,i), xkeytmp
%assign i (i+1)
%endrep
%assign i 0
%rep %%by
vaesdeclast CONCAT(xdata,i), CONCAT(xdata,i), xkey10
%assign i (i+1)
%endrep
vpxor xdata0, xdata0, xIV
%assign i 1
%if (%%by > 1)
%rep (%%by - 1)
VMOVDQ xIV, [p_in + (i-1)*16 - 16*%%by]
vpxor CONCAT(xdata,i), CONCAT(xdata,i), xIV
%assign i (i+1)
%endrep
%endif
VMOVDQ xIV, [p_in + (i-1)*16 - 16*%%by]
%assign i 0
%rep %%by
VMOVDQ [p_out + i*16], CONCAT(xdata,i)
%assign i (i+1)
%endrep
%endmacro
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
section .text
;; aes_cbc_dec_128_avx(void *in, void *IV, void *keys, void *out, UINT64 num_bytes)
MKGLOBAL(aes_cbc_dec_128_avx,function,internal)
aes_cbc_dec_128_avx:
%ifndef LINUX
mov num_bytes, [rsp + 8*5]
%endif
vmovdqu xIV, [p_IV]
mov tmp, num_bytes
and tmp, 7*16
jz mult_of_8_blks
; 1 <= tmp <= 7
cmp tmp, 4*16
jg gt4
je eq4
lt4:
cmp tmp, 2*16
jg eq3
je eq2
eq1:
do_aes_load 1
add p_out, 1*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
eq2:
do_aes_load 2
add p_out, 2*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
eq3:
do_aes_load 3
add p_out, 3*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
eq4:
do_aes_load 4
add p_out, 4*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
gt4:
cmp tmp, 6*16
jg eq7
je eq6
eq5:
do_aes_load 5
add p_out, 5*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
eq6:
do_aes_load 6
add p_out, 6*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
eq7:
do_aes_load 7
add p_out, 7*16
and num_bytes, ~7*16
jz do_return2
jmp main_loop2
mult_of_8_blks:
vmovdqa xkey0, [p_keys + 0*16]
vmovdqa xkey2, [p_keys + 2*16]
vmovdqa xkey4, [p_keys + 4*16]
vmovdqa xkey6, [p_keys + 6*16]
vmovdqa xkey8, [p_keys + 8*16]
vmovdqa xkey10, [p_keys + 10*16]
main_loop2:
; num_bytes is a multiple of 8 and >0
do_aes_noload 8
add p_out, 8*16
sub num_bytes, 8*16
jne main_loop2
do_return2:
; Don't write back IV
; vmovdqu [p_IV], xIV
ret
%ifdef LINUX
section .note.GNU-stack noalloc noexec nowrite progbits
%endif
|
