1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
|
;;
;; Copyright (c) 2019, Intel Corporation
;;
;; Redistribution and use in source and binary forms, with or without
;; modification, are permitted provided that the following conditions are met:
;;
;; * Redistributions of source code must retain the above copyright notice,
;; this list of conditions and the following disclaimer.
;; * Redistributions in binary form must reproduce the above copyright
;; notice, this list of conditions and the following disclaimer in the
;; documentation and/or other materials provided with the distribution.
;; * Neither the name of Intel Corporation nor the names of its contributors
;; may be used to endorse or promote products derived from this software
;; without specific prior written permission.
;;
;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
;; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
;; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
;; DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE
;; FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
;; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
;; CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
;; OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
;; OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
;;
; routine to do AES ECB encrypt/decrypt on 16n bytes doing AES by 4
; XMM registers are clobbered. Saving/restoring must be done at a higher level
; void aes_ecb_x_y_sse(void *in,
; UINT128 keys[],
; void *out,
; UINT64 len_bytes);
;
; x = direction (enc/dec)
; y = key size (128/192/256)
; arg 1: IN: pointer to input (cipher text)
; arg 2: KEYS: pointer to keys
; arg 3: OUT: pointer to output (plain text)
; arg 4: LEN: length in bytes (multiple of 16)
;
%include "include/os.asm"
%ifndef AES_ECB_ENC_128
%define AES_ECB_ENC_128 aes_ecb_enc_128_sse
%define AES_ECB_ENC_192 aes_ecb_enc_192_sse
%define AES_ECB_ENC_256 aes_ecb_enc_256_sse
%define AES_ECB_DEC_128 aes_ecb_dec_128_sse
%define AES_ECB_DEC_192 aes_ecb_dec_192_sse
%define AES_ECB_DEC_256 aes_ecb_dec_256_sse
%endif
%ifdef LINUX
%define IN rdi
%define KEYS rsi
%define OUT rdx
%define LEN rcx
%else
%define IN rcx
%define KEYS rdx
%define OUT r8
%define LEN r9
%endif
%define IDX rax
%define TMP IDX
%define XDATA0 xmm0
%define XDATA1 xmm1
%define XDATA2 xmm2
%define XDATA3 xmm3
%define XKEY0 xmm4
%define XKEY2 xmm5
%define XKEY4 xmm6
%define XKEY6 xmm7
%define XKEY10 xmm8
%define XKEY_A xmm14
%define XKEY_B xmm15
section .text
%macro AES_ECB 2
%define %%NROUNDS %1 ; [in] Number of AES rounds, numerical value
%define %%DIR %2 ; [in] Direction (encrypt/decrypt)
%ifidn %%DIR, ENC
%define AES aesenc
%define AES_LAST aesenclast
%else ; DIR = DEC
%define AES aesdec
%define AES_LAST aesdeclast
%endif
mov TMP, LEN
and TMP, 3*16
jz %%initial_4
cmp TMP, 2*16
jb %%initial_1
ja %%initial_3
%%initial_2:
; load plain/cipher text
movdqu XDATA0, [IN + 0*16]
movdqu XDATA1, [IN + 1*16]
movdqa XKEY0, [KEYS + 0*16]
pxor XDATA0, XKEY0 ; 0. ARK
pxor XDATA1, XKEY0
movdqa XKEY2, [KEYS + 2*16]
AES XDATA0, [KEYS + 1*16] ; 1. ENC
AES XDATA1, [KEYS + 1*16]
mov IDX, 2*16
AES XDATA0, XKEY2 ; 2. ENC
AES XDATA1, XKEY2
movdqa XKEY4, [KEYS + 4*16]
AES XDATA0, [KEYS + 3*16] ; 3. ENC
AES XDATA1, [KEYS + 3*16]
AES XDATA0, XKEY4 ; 4. ENC
AES XDATA1, XKEY4
movdqa XKEY6, [KEYS + 6*16]
AES XDATA0, [KEYS + 5*16] ; 5. ENC
AES XDATA1, [KEYS + 5*16]
AES XDATA0, XKEY6 ; 6. ENC
AES XDATA1, XKEY6
movdqa XKEY_B, [KEYS + 8*16]
AES XDATA0, [KEYS + 7*16] ; 7. ENC
AES XDATA1, [KEYS + 7*16]
AES XDATA0, XKEY_B ; 8. ENC
AES XDATA1, XKEY_B
movdqa XKEY10, [KEYS + 10*16]
AES XDATA0, [KEYS + 9*16] ; 9. ENC
AES XDATA1, [KEYS + 9*16]
%if %%NROUNDS >= 12
AES XDATA0, XKEY10 ; 10. ENC
AES XDATA1, XKEY10
AES XDATA0, [KEYS + 11*16] ; 11. ENC
AES XDATA1, [KEYS + 11*16]
%endif
%if %%NROUNDS == 14
AES XDATA0, [KEYS + 12*16] ; 12. ENC
AES XDATA1, [KEYS + 12*16]
AES XDATA0, [KEYS + 13*16] ; 13. ENC
AES XDATA1, [KEYS + 13*16]
%endif
%if %%NROUNDS == 10
AES_LAST XDATA0, XKEY10 ; 10. ENC
AES_LAST XDATA1, XKEY10
%elif %%NROUNDS == 12
AES_LAST XDATA0, [KEYS + 12*16] ; 12. ENC
AES_LAST XDATA1, [KEYS + 12*16]
%else
AES_LAST XDATA0, [KEYS + 14*16] ; 14. ENC
AES_LAST XDATA1, [KEYS + 14*16]
%endif
movdqu [OUT + 0*16], XDATA0
movdqu [OUT + 1*16], XDATA1
cmp LEN, 2*16
je %%done
jmp %%main_loop
align 16
%%initial_1:
; load plain/cipher text
movdqu XDATA0, [IN + 0*16]
movdqa XKEY0, [KEYS + 0*16]
pxor XDATA0, XKEY0 ; 0. ARK
movdqa XKEY2, [KEYS + 2*16]
AES XDATA0, [KEYS + 1*16] ; 1. ENC
mov IDX, 1*16
AES XDATA0, XKEY2 ; 2. ENC
movdqa XKEY4, [KEYS + 4*16]
AES XDATA0, [KEYS + 3*16] ; 3. ENC
AES XDATA0, XKEY4 ; 4. ENC
movdqa XKEY6, [KEYS + 6*16]
AES XDATA0, [KEYS + 5*16] ; 5. ENC
AES XDATA0, XKEY6 ; 6. ENC
movdqa XKEY_B, [KEYS + 8*16]
AES XDATA0, [KEYS + 7*16] ; 7. ENC
AES XDATA0, XKEY_B ; 8. ENC
movdqa XKEY10, [KEYS + 10*16]
AES XDATA0, [KEYS + 9*16] ; 9. ENC
%if %%NROUNDS >= 12
AES XDATA0, XKEY10 ; 10. ENC
AES XDATA0, [KEYS + 11*16] ; 11. ENC
%endif
%if %%NROUNDS == 14
AES XDATA0, [KEYS + 12*16] ; 12. ENC
AES XDATA0, [KEYS + 13*16] ; 13. ENC
%endif
%if %%NROUNDS == 10
AES_LAST XDATA0, XKEY10 ; 10. ENC
%elif %%NROUNDS == 12
AES_LAST XDATA0, [KEYS + 12*16] ; 12. ENC
%else
AES_LAST XDATA0, [KEYS + 14*16] ; 14. ENC
%endif
movdqu [OUT + 0*16], XDATA0
cmp LEN, 1*16
je %%done
jmp %%main_loop
%%initial_3:
; load plain/cipher text
movdqu XDATA0, [IN + 0*16]
movdqu XDATA1, [IN + 1*16]
movdqu XDATA2, [IN + 2*16]
movdqa XKEY0, [KEYS + 0*16]
movdqa XKEY_A, [KEYS + 1*16]
pxor XDATA0, XKEY0 ; 0. ARK
pxor XDATA1, XKEY0
pxor XDATA2, XKEY0
movdqa XKEY2, [KEYS + 2*16]
AES XDATA0, XKEY_A ; 1. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
movdqa XKEY_A, [KEYS + 3*16]
mov IDX, 3*16
AES XDATA0, XKEY2 ; 2. ENC
AES XDATA1, XKEY2
AES XDATA2, XKEY2
movdqa XKEY4, [KEYS + 4*16]
AES XDATA0, XKEY_A ; 3. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
movdqa XKEY_A, [KEYS + 5*16]
AES XDATA0, XKEY4 ; 4. ENC
AES XDATA1, XKEY4
AES XDATA2, XKEY4
movdqa XKEY6, [KEYS + 6*16]
AES XDATA0, XKEY_A ; 5. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
movdqa XKEY_A, [KEYS + 7*16]
AES XDATA0, XKEY6 ; 6. ENC
AES XDATA1, XKEY6
AES XDATA2, XKEY6
movdqa XKEY_B, [KEYS + 8*16]
AES XDATA0, XKEY_A ; 7. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
movdqa XKEY_A, [KEYS + 9*16]
AES XDATA0, XKEY_B ; 8. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
movdqa XKEY_B, [KEYS + 10*16]
AES XDATA0, XKEY_A ; 9. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
%if %%NROUNDS >= 12
movdqa XKEY_A, [KEYS + 11*16]
AES XDATA0, XKEY_B ; 10. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
movdqa XKEY_B, [KEYS + 12*16]
AES XDATA0, XKEY_A ; 11. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
%endif
%if %%NROUNDS == 14
movdqa XKEY_A, [KEYS + 13*16]
AES XDATA0, XKEY_B ; 12. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
movdqa XKEY_B, [KEYS + 14*16]
AES XDATA0, XKEY_A ; 13. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
%endif
AES_LAST XDATA0, XKEY_B ; 10/12/14. ENC (depending on key size)
AES_LAST XDATA1, XKEY_B
AES_LAST XDATA2, XKEY_B
movdqu [OUT + 0*16], XDATA0
movdqu [OUT + 1*16], XDATA1
movdqu [OUT + 2*16], XDATA2
cmp LEN, 3*16
je %%done
jmp %%main_loop
align 16
%%initial_4:
; load plain/cipher text
movdqu XDATA0, [IN + 0*16]
movdqu XDATA1, [IN + 1*16]
movdqu XDATA2, [IN + 2*16]
movdqu XDATA3, [IN + 3*16]
movdqa XKEY0, [KEYS + 0*16]
movdqa XKEY_A, [KEYS + 1*16]
pxor XDATA0, XKEY0 ; 0. ARK
pxor XDATA1, XKEY0
pxor XDATA2, XKEY0
pxor XDATA3, XKEY0
movdqa XKEY2, [KEYS + 2*16]
AES XDATA0, XKEY_A ; 1. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 3*16]
mov IDX, 4*16
AES XDATA0, XKEY2 ; 2. ENC
AES XDATA1, XKEY2
AES XDATA2, XKEY2
AES XDATA3, XKEY2
movdqa XKEY4, [KEYS + 4*16]
AES XDATA0, XKEY_A ; 3. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 5*16]
AES XDATA0, XKEY4 ; 4. ENC
AES XDATA1, XKEY4
AES XDATA2, XKEY4
AES XDATA3, XKEY4
movdqa XKEY6, [KEYS + 6*16]
AES XDATA0, XKEY_A ; 5. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 7*16]
AES XDATA0, XKEY6 ; 6. ENC
AES XDATA1, XKEY6
AES XDATA2, XKEY6
AES XDATA3, XKEY6
movdqa XKEY_B, [KEYS + 8*16]
AES XDATA0, XKEY_A ; 7. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 9*16]
AES XDATA0, XKEY_B ; 8. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
AES XDATA3, XKEY_B
movdqa XKEY_B, [KEYS + 10*16]
AES XDATA0, XKEY_A ; 9. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
%if %%NROUNDS >= 12
movdqa XKEY_A, [KEYS + 11*16]
AES XDATA0, XKEY_B ; 10. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
AES XDATA3, XKEY_B
movdqa XKEY_B, [KEYS + 12*16]
AES XDATA0, XKEY_A ; 11. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
%endif
%if %%NROUNDS == 14
movdqa XKEY_A, [KEYS + 13*16]
AES XDATA0, XKEY_B ; 12. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
AES XDATA3, XKEY_B
movdqa XKEY_B, [KEYS + 14*16]
AES XDATA0, XKEY_A ; 13. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
%endif
AES_LAST XDATA0, XKEY_B ; 10/12/14. ENC (depending on key size)
AES_LAST XDATA1, XKEY_B
AES_LAST XDATA2, XKEY_B
AES_LAST XDATA3, XKEY_B
movdqu [OUT + 0*16], XDATA0
movdqu [OUT + 1*16], XDATA1
movdqu [OUT + 2*16], XDATA2
movdqu [OUT + 3*16], XDATA3
cmp LEN, 4*16
jz %%done
jmp %%main_loop
align 16
%%main_loop:
; load plain/cipher text
movdqu XDATA0, [IN + IDX + 0*16]
movdqu XDATA1, [IN + IDX + 1*16]
movdqu XDATA2, [IN + IDX + 2*16]
movdqu XDATA3, [IN + IDX + 3*16]
movdqa XKEY_A, [KEYS + 1*16]
pxor XDATA0, XKEY0 ; 0. ARK
pxor XDATA1, XKEY0
pxor XDATA2, XKEY0
pxor XDATA3, XKEY0
add IDX, 4*16
AES XDATA0, XKEY_A ; 1. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 3*16]
AES XDATA0, XKEY2 ; 2. ENC
AES XDATA1, XKEY2
AES XDATA2, XKEY2
AES XDATA3, XKEY2
AES XDATA0, XKEY_A ; 3. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 5*16]
AES XDATA0, XKEY4 ; 4. ENC
AES XDATA1, XKEY4
AES XDATA2, XKEY4
AES XDATA3, XKEY4
AES XDATA0, XKEY_A ; 5. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 7*16]
AES XDATA0, XKEY6 ; 6. ENC
AES XDATA1, XKEY6
AES XDATA2, XKEY6
AES XDATA3, XKEY6
movdqa XKEY_B, [KEYS + 8*16]
AES XDATA0, XKEY_A ; 7. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
movdqa XKEY_A, [KEYS + 9*16]
AES XDATA0, XKEY_B ; 8. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
AES XDATA3, XKEY_B
movdqa XKEY_B, [KEYS + 10*16]
AES XDATA0, XKEY_A ; 9. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
%if %%NROUNDS >= 12
movdqa XKEY_A, [KEYS + 11*16]
AES XDATA0, XKEY_B ; 10. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
AES XDATA3, XKEY_B
movdqa XKEY_B, [KEYS + 12*16]
AES XDATA0, XKEY_A ; 11. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
%endif
%if %%NROUNDS == 14
movdqa XKEY_A, [KEYS + 13*16]
AES XDATA0, XKEY_B ; 12. ENC
AES XDATA1, XKEY_B
AES XDATA2, XKEY_B
AES XDATA3, XKEY_B
movdqa XKEY_B, [KEYS + 14*16]
AES XDATA0, XKEY_A ; 13. ENC
AES XDATA1, XKEY_A
AES XDATA2, XKEY_A
AES XDATA3, XKEY_A
%endif
AES_LAST XDATA0, XKEY_B ; 10/12/14. ENC (depending on key size)
AES_LAST XDATA1, XKEY_B
AES_LAST XDATA2, XKEY_B
AES_LAST XDATA3, XKEY_B
movdqu [OUT + IDX + 0*16 - 4*16], XDATA0
movdqu [OUT + IDX + 1*16 - 4*16], XDATA1
movdqu [OUT + IDX + 2*16 - 4*16], XDATA2
movdqu [OUT + IDX + 3*16 - 4*16], XDATA3
cmp IDX, LEN
jne %%main_loop
%%done:
ret
%endmacro
align 16
MKGLOBAL(AES_ECB_ENC_128,function,internal)
AES_ECB_ENC_128:
AES_ECB 10, ENC
align 16
MKGLOBAL(AES_ECB_ENC_192,function,internal)
AES_ECB_ENC_192:
AES_ECB 12, ENC
align 16
MKGLOBAL(AES_ECB_ENC_256,function,internal)
AES_ECB_ENC_256:
AES_ECB 14, ENC
align 16
MKGLOBAL(AES_ECB_DEC_128,function,internal)
AES_ECB_DEC_128:
AES_ECB 10, DEC
align 16
MKGLOBAL(AES_ECB_DEC_192,function,internal)
AES_ECB_DEC_192:
AES_ECB 12, DEC
align 16
MKGLOBAL(AES_ECB_DEC_256,function,internal)
AES_ECB_DEC_256:
AES_ECB 14, DEC
%ifdef LINUX
section .note.GNU-stack noalloc noexec nowrite progbits
%endif
|
