1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# PTHREAD_SET_NAME();
# Check which variant (if any) of pthread_set_name_np we have.
# -----------------------------------------------------------------------------
AC_DEFUN([PTHREAD_SET_NAME],
[
stored_LIBS="$LIBS"
LIBS="-lpthread"
# pthread setname (4 non-portable variants...)
AC_CHECK_HEADERS([pthread_np.h], [], [], [#include <pthread.h>])
define(pthread_np_preamble,[
#include <pthread.h>
#if HAVE_PTHREAD_NP_H
# include <pthread_np.h>
#endif
])
# 2-arg setname (e.g. Linux/glibc, QNX, IBM)
AC_MSG_CHECKING([for 2-arg pthread_setname_np])
AC_LINK_IFELSE([AC_LANG_PROGRAM(pthread_np_preamble, [
pthread_setname_np(pthread_self(), "foo")
])], [
AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_2, 1, [2-arg pthread_setname_np])
AC_MSG_RESULT([yes])
], [
AC_MSG_RESULT([no])
# 2-arg set_name (e.g. FreeBSD, OpenBSD)
AC_MSG_CHECKING([for 2-arg pthread_set_name_np])
AC_LINK_IFELSE([AC_LANG_PROGRAM(pthread_np_preamble, [
return pthread_set_name_np(pthread_self(), "foo");
])], [
AC_DEFINE(HAVE_PTHREAD_SET_NAME_NP_2, 1, [2-arg pthread_set_name_np])
AC_MSG_RESULT([yes])
], [
AC_MSG_RESULT([no])
# 2-arg void set_name (e.g. FreeBSD, OpenBSD)
AC_MSG_CHECKING([for 2-arg void pthread_set_name_np])
AC_LINK_IFELSE([AC_LANG_PROGRAM(pthread_np_preamble, [
pthread_set_name_np(pthread_self(), "foo");
])], [
AC_DEFINE(HAVE_PTHREAD_SET_NAME_NP_2_VOID, 1, [2-arg void pthread_set_name_np])
AC_MSG_RESULT([yes])
], [
AC_MSG_RESULT([no])
# 1-arg setname (e.g. Darwin)
AC_MSG_CHECKING([for 1-arg pthread_setname_np])
AC_LINK_IFELSE([AC_LANG_PROGRAM(pthread_np_preamble, [
return pthread_setname_np("foo");
])], [
AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_1, 1, [1-arg pthread_setname_np])
AC_MSG_RESULT([yes])
], [
AC_MSG_RESULT([no])
# 3-arg setname (e.g. NetBSD)
AC_MSG_CHECKING([for 3-arg pthread_setname_np])
AC_LINK_IFELSE([AC_LANG_PROGRAM(pthread_np_preamble, [
return pthread_setname_np(pthread_self(), "foo", NULL);
])], [
AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_3, 1, [3-arg pthread_setname_np])
AC_MSG_RESULT([yes])
], [
AC_MSG_RESULT([no])
])
])
])
])
])
LIBS=$stored_LIBS
])
|
