1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
|
# Copyright © 2007, 2016 Raphaël Hertzog <hertzog@debian.org>
# Copyright © 2007-2008, 2012-2015 Guillem Jover <guillem@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <https://www.gnu.org/licenses/>.
=encoding utf8
=head1 NAME
Dpkg::Shlibs - shared library location handling
=head1 DESCRIPTION
This module provides functions to locate shared libraries.
B<Note>: This is a private module, its API can change at any time.
=cut
package Dpkg::Shlibs 0.03;
use strict;
use warnings;
use feature qw(state);
our @EXPORT_OK = qw(
blank_library_paths
setup_library_paths
get_library_paths
add_library_dir
find_library
);
use Exporter qw(import);
use List::Util qw(none);
use File::Spec;
use Dpkg::Gettext;
use Dpkg::ErrorHandling;
use Dpkg::Shlibs::Objdump;
use Dpkg::BuildAPI qw(get_build_api);
use Dpkg::Path qw(resolve_symlink canonpath);
use Dpkg::Arch qw(get_build_arch get_host_arch :mappers);
use constant DEFAULT_LIBRARY_PATH =>
qw(/lib /usr/lib);
# XXX: Deprecated multilib paths.
use constant DEFAULT_MULTILIB_PATH =>
qw(/lib32 /usr/lib32 /lib64 /usr/lib64);
# Library paths set by the user.
my @custom_librarypaths;
# Library paths from the system.
my @system_librarypaths;
my $librarypaths_init;
sub parse_ldso_conf {
my $file = shift;
state %visited;
local $_;
open my $fh, '<', $file or syserr(g_('cannot open %s'), $file);
$visited{$file}++;
while (<$fh>) {
next if /^\s*$/;
chomp;
s{/+$}{};
if (/^include\s+(\S.*\S)\s*$/) {
foreach my $include (glob($1)) {
parse_ldso_conf($include) if -e $include
&& !$visited{$include};
}
} elsif (m{^\s*/}) {
s/^\s+//;
my $libdir = $_;
if (none { $_ eq $libdir } (@custom_librarypaths, @system_librarypaths)) {
push @system_librarypaths, $libdir;
}
}
}
close $fh;
}
sub blank_library_paths {
@custom_librarypaths = ();
@system_librarypaths = ();
$librarypaths_init = 1;
}
sub setup_library_paths {
@custom_librarypaths = ();
@system_librarypaths = ();
# XXX: Deprecated. Update library paths with LD_LIBRARY_PATH.
if ($ENV{LD_LIBRARY_PATH}) {
require Cwd;
my $cwd = Cwd::getcwd;
foreach my $path (split /:/, $ENV{LD_LIBRARY_PATH}) {
$path =~ s{/+$}{};
my $realpath = Cwd::realpath($path);
next unless defined $realpath;
if ($realpath =~ m/^\Q$cwd\E/) {
if (get_build_api() >= 1) {
error(g_('use -l option instead of LD_LIBRARY_PATH'));
} else {
warning(g_('deprecated use of LD_LIBRARY_PATH with private ' .
'library directory which interferes with ' .
'cross-building, please use -l option instead'));
}
}
next if get_build_api() >= 1;
# XXX: This should be added to @custom_librarypaths, but as this
# is deprecated we do not care as the code will go away.
push @system_librarypaths, $path;
}
}
# Adjust set of directories to consider when we're in a situation of a
# cross-build or a build of a cross-compiler.
my $multiarch;
# Detect cross compiler builds.
if ($ENV{DEB_TARGET_GNU_TYPE} and
($ENV{DEB_TARGET_GNU_TYPE} ne $ENV{DEB_BUILD_GNU_TYPE}))
{
$multiarch = gnutriplet_to_multiarch($ENV{DEB_TARGET_GNU_TYPE});
}
# Host for normal cross builds.
if (get_build_arch() ne get_host_arch()) {
$multiarch = debarch_to_multiarch(get_host_arch());
}
# Define list of directories containing crossbuilt libraries.
if ($multiarch) {
push @system_librarypaths, "/lib/$multiarch", "/usr/lib/$multiarch";
}
push @system_librarypaths, DEFAULT_LIBRARY_PATH;
# Update library paths with ld.so config.
parse_ldso_conf('/etc/ld.so.conf') if -e '/etc/ld.so.conf';
push @system_librarypaths, DEFAULT_MULTILIB_PATH;
$librarypaths_init = 1;
}
sub add_library_dir {
my $dir = shift;
setup_library_paths() if not $librarypaths_init;
push @custom_librarypaths, $dir;
}
sub get_library_paths {
setup_library_paths() if not $librarypaths_init;
return (@custom_librarypaths, @system_librarypaths);
}
# find_library ($soname, \@rpath, $format, $root)
sub find_library {
my ($lib, $rpath, $format, $root) = @_;
setup_library_paths() if not $librarypaths_init;
my @librarypaths = (@{$rpath}, @custom_librarypaths, @system_librarypaths);
my @libs;
$root //= '';
$root =~ s{/+$}{};
foreach my $dir (@librarypaths) {
my $checkdir = "$root$dir";
if (-e "$checkdir/$lib") {
my $libformat = Dpkg::Shlibs::Objdump::get_format("$checkdir/$lib");
if (not defined $libformat) {
warning(g_("unknown executable format in file '%s'"), "$checkdir/$lib");
} elsif ($format eq $libformat) {
push @libs, canonpath("$checkdir/$lib");
} else {
debug(1, "Skipping lib $checkdir/$lib, libabi=<%s> != objabi=<%s>",
$libformat, $format);
}
}
}
return @libs;
}
=head1 CHANGES
=head2 Version 0.xx
This is a private module.
=cut
1;
|
