1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
|
;
; Copyright (c) 2010 The WebM project authors. All Rights Reserved.
;
; Use of this source code is governed by a BSD-style license
; that can be found in the LICENSE file in the root of the source
; tree. An additional intellectual property rights grant can be found
; in the file PATENTS. All contributing project authors may
; be found in the AUTHORS file in the root of the source tree.
;
%include "vpx_ports/x86_abi_support.asm"
SECTION .text
;int vp8_block_error_sse2(short *coeff_ptr, short *dcoef_ptr)
globalsym(vp8_block_error_sse2)
sym(vp8_block_error_sse2):
push rbp
mov rbp, rsp
SHADOW_ARGS_TO_STACK 2
push rsi
push rdi
; end prologue
mov rsi, arg(0) ;coeff_ptr
mov rdi, arg(1) ;dcoef_ptr
movdqa xmm0, [rsi]
movdqa xmm1, [rdi]
movdqa xmm2, [rsi+16]
movdqa xmm3, [rdi+16]
psubw xmm0, xmm1
psubw xmm2, xmm3
pmaddwd xmm0, xmm0
pmaddwd xmm2, xmm2
paddd xmm0, xmm2
pxor xmm5, xmm5
movdqa xmm1, xmm0
punpckldq xmm0, xmm5
punpckhdq xmm1, xmm5
paddd xmm0, xmm1
movdqa xmm1, xmm0
psrldq xmm0, 8
paddd xmm0, xmm1
movq rax, xmm0
pop rdi
pop rsi
; begin epilog
UNSHADOW_ARGS
pop rbp
ret
;int vp8_mbblock_error_sse2_impl(short *coeff_ptr, short *dcoef_ptr, int dc);
globalsym(vp8_mbblock_error_sse2_impl)
sym(vp8_mbblock_error_sse2_impl):
push rbp
mov rbp, rsp
SHADOW_ARGS_TO_STACK 3
SAVE_XMM 6
push rsi
push rdi
; end prolog
mov rsi, arg(0) ;coeff_ptr
pxor xmm6, xmm6
mov rdi, arg(1) ;dcoef_ptr
pxor xmm4, xmm4
movd xmm5, dword ptr arg(2) ;dc
por xmm5, xmm4
pcmpeqw xmm5, xmm6
mov rcx, 16
.mberror_loop:
movdqa xmm0, [rsi]
movdqa xmm1, [rdi]
movdqa xmm2, [rsi+16]
movdqa xmm3, [rdi+16]
psubw xmm2, xmm3
pmaddwd xmm2, xmm2
psubw xmm0, xmm1
pand xmm0, xmm5
pmaddwd xmm0, xmm0
add rsi, 32
add rdi, 32
sub rcx, 1
paddd xmm4, xmm2
paddd xmm4, xmm0
jnz .mberror_loop
movdqa xmm0, xmm4
punpckldq xmm0, xmm6
punpckhdq xmm4, xmm6
paddd xmm0, xmm4
movdqa xmm1, xmm0
psrldq xmm0, 8
paddd xmm0, xmm1
movq rax, xmm0
pop rdi
pop rsi
; begin epilog
RESTORE_XMM
UNSHADOW_ARGS
pop rbp
ret
;int vp8_mbuverror_sse2_impl(short *s_ptr, short *d_ptr);
globalsym(vp8_mbuverror_sse2_impl)
sym(vp8_mbuverror_sse2_impl):
push rbp
mov rbp, rsp
SHADOW_ARGS_TO_STACK 2
push rsi
push rdi
; end prolog
mov rsi, arg(0) ;s_ptr
mov rdi, arg(1) ;d_ptr
mov rcx, 16
pxor xmm3, xmm3
.mbuverror_loop:
movdqa xmm1, [rsi]
movdqa xmm2, [rdi]
psubw xmm1, xmm2
pmaddwd xmm1, xmm1
paddd xmm3, xmm1
add rsi, 16
add rdi, 16
dec rcx
jnz .mbuverror_loop
pxor xmm0, xmm0
movdqa xmm1, xmm3
movdqa xmm2, xmm1
punpckldq xmm1, xmm0
punpckhdq xmm2, xmm0
paddd xmm1, xmm2
movdqa xmm2, xmm1
psrldq xmm1, 8
paddd xmm1, xmm2
movq rax, xmm1
pop rdi
pop rsi
; begin epilog
UNSHADOW_ARGS
pop rbp
ret
|
