Adding upstream version 2.117.0.upstream/2.117.0upstream

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>

13 files changed, 1162 insertions, 0 deletions

diff --git a/lib/Lintian/Check/Debian/Control/Field/Adopted.pm b/lib/Lintian/Check/Debian/Control/Field/Adopted.pm
new file mode 100644
index 0000000..d9d9379
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Adopted.pm
@@ -0,0 +1,98 @@
+# debian/control/field/adopted -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Adopted;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    my $KNOWN_SOURCE_FIELDS= $self->data->load('common/source-fields');
+    my $KNOWN_BINARY_FIELDS= $self->data->load('fields/binary-fields');
+
+    for my $field ($source_fields->names) {
+
+        my ($marker, $bare) = split(qr{-}, $field, 2);
+
+        next
+          unless length $marker
+          && length $bare;
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $source_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        # case-insensitive match
+        $self->pointed_hint(
+            'adopted-extended-field',$pointer,
+            '(in section for source)', $field
+          )
+          if $marker =~ m{^ X }ix
+          && $KNOWN_SOURCE_FIELDS->resembles($bare);
+    }
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        for my $field ($installable_fields->names) {
+
+            my ($marker, $bare) = split(qr{-}, $field, 2);
+
+            next
+              unless length $marker
+              && length $bare;
+
+            my $control_item= $self->processable->debian_control->item;
+            my $position = $installable_fields->position($field);
+            my $pointer = $control_item->pointer($position);
+
+            # case-insensitive match
+            $self->pointed_hint(
+                'adopted-extended-field', $pointer,
+                "(in section for $installable)", $field
+              )
+              if $marker =~ m{^ X }ix
+              && $KNOWN_BINARY_FIELDS->resembles($bare);
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Architecture/Multiline.pm b/lib/Lintian/Check/Debian/Control/Field/Architecture/Multiline.pm
new file mode 100644
index 0000000..dbb5dc2
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Architecture/Multiline.pm
@@ -0,0 +1,63 @@
+# debian/control/field/architecture/multiline -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Architecture::Multiline;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+
+    for my $installable ($control->installables) {
+
+        my $installable_fields = $control->installable_fields($installable);
+
+        my $field = 'Architecture';
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $installable_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        $self->pointed_hint('multiline-architecture-field',
+            $pointer, $field,"(in section for $installable)")
+          if $installable_fields->value($field)=~ /\n./;
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/BuildProfiles.pm b/lib/Lintian/Check/Debian/Control/Field/BuildProfiles.pm
new file mode 100644
index 0000000..50e9663
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/BuildProfiles.pm
@@ -0,0 +1,110 @@
+# debian/control/field/build-profiles -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::BuildProfiles;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Lintian::Relation;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+
+    my $KNOWN_BUILD_PROFILES= $self->data->load('fields/build-profiles');
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        my $field = 'Build-Profiles';
+
+        my $raw = $installable_fields->value($field);
+        next
+          unless $raw;
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $installable_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        if (
+            $raw!~ m{^\s*              # skip leading whitespace
+                     <                 # first list start
+                       !?[^\s<>]+      # (possibly negated) term
+                       (?:             # any additional terms
+                         \s+           # start with a space
+                         !?[^\s<>]+    # (possibly negated) term
+                       )*              # zero or more additional terms
+                     >                 # first list end
+                     (?:               # any additional restriction lists
+                       \s+             # start with a space
+                       <               # additional list start
+                         !?[^\s<>]+    # (possibly negated) term
+                         (?:           # any additional terms
+                           \s+         # start with a space
+                           !?[^\s<>]+  # (possibly negated) term
+                         )*            # zero or more additional terms
+                       >               # additional list end
+                     )*                # zero or more additional lists
+                     \s*$              # trailing spaces at the end
+              }x
+        ) {
+            $self->pointed_hint(
+                'invalid-restriction-formula-in-build-profiles-field',
+                $pointer, $raw,"(in section for $installable)");
+
+        } else {
+            # parse the field and check the profile names
+            $raw =~ s/^\s*<(.*)>\s*$/$1/;
+
+            for my $restrlist (split />\s+</, $raw) {
+                for my $profile (split /\s+/, $restrlist) {
+
+                    $profile =~ s/^!//;
+
+                    $self->pointed_hint(
+                        'invalid-profile-name-in-build-profiles-field',
+                        $pointer, $profile,"(in section for $installable)")
+                      unless $KNOWN_BUILD_PROFILES->recognizes($profile)
+                      || $profile =~ /^pkg\.[a-z0-9][a-z0-9+.-]+\../;
+                }
+            }
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/BuiltUsing.pm b/lib/Lintian/Check/Debian/Control/Field/BuiltUsing.pm
new file mode 100644
index 0000000..560f89b
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/BuiltUsing.pm
@@ -0,0 +1,66 @@
+# debian/control/field/built-using -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::BuiltUsing;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+
+    for my $installable ($control->installables) {
+        my $installable_fields= $control->installable_fields($installable);
+
+        my $field = 'Built-Using';
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $installable_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        $self->pointed_hint(
+            'built-using-field-on-arch-all-package',$pointer,
+            "(in section for $installable)", $field,
+            $installable_fields->value($field)
+          )
+          if $installable_fields->declares($field)
+          && $installable_fields->value('Architecture') eq 'all';
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Description/Duplicate.pm b/lib/Lintian/Check/Debian/Control/Field/Description/Duplicate.pm
new file mode 100644
index 0000000..294893b
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Description/Duplicate.pm
@@ -0,0 +1,114 @@
+# debian/control/field/description/duplicate -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Description::Duplicate;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Const::Fast;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+const my $EMPTY => q{};
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+
+    my %installables_by_synopsis;
+    my %installables_by_exended;
+
+    for my $installable ($control->installables) {
+
+        next
+          if $control->installable_package_type($installable) eq 'udeb';
+
+        my $installable_fields = $control->installable_fields($installable);
+
+        my $description = $installable_fields->untrimmed_value('Description');
+        next
+          unless length $description;
+
+        my ($synopsis, $extended) = split(/\n/, $description, 2);
+
+        $synopsis //= $EMPTY;
+        $extended //= $EMPTY;
+
+        # trim both ends
+        $synopsis =~ s/^\s+|\s+$//g;
+        $extended =~ s/^\s+|\s+$//g;
+
+        if (length $synopsis) {
+            $installables_by_synopsis{$synopsis} //= [];
+            push(@{$installables_by_synopsis{$synopsis}}, $installable);
+        }
+
+        if (length $extended) {
+            $installables_by_exended{$extended} //= [];
+            push(@{$installables_by_exended{$extended}}, $installable);
+        }
+    }
+
+    # check for duplicate short description
+    for my $synopsis (keys %installables_by_synopsis) {
+
+        # Assume that substvars are correctly handled
+        next
+          if $synopsis =~ m/\$\{.+\}/;
+
+        $self->pointed_hint(
+            'duplicate-short-description',
+            $control->item->pointer,
+            (sort @{$installables_by_synopsis{$synopsis}})
+        )if scalar @{$installables_by_synopsis{$synopsis}} > 1;
+    }
+
+    # check for duplicate long description
+    for my $extended (keys %installables_by_exended) {
+
+        # Assume that substvars are correctly handled
+        next
+          if $extended =~ m/\$\{.+\}/;
+
+        $self->pointed_hint(
+            'duplicate-long-description',
+            $control->item->pointer,
+            (sort @{$installables_by_exended{$extended}})
+        )if scalar @{$installables_by_exended{$extended}} > 1;
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/DoubledUp.pm b/lib/Lintian/Check/Debian/Control/Field/DoubledUp.pm
new file mode 100644
index 0000000..1e1e69a
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/DoubledUp.pm
@@ -0,0 +1,83 @@
+# debian/control/field/doubled-up -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::DoubledUp;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    # something like "Maintainer: Maintainer: bad field"
+    my @doubled_up_source_fields
+      = grep { $source_fields->value($_) =~ m{^ \Q$_\E \s* : }ix }
+      $source_fields->names;
+
+    for my $field (@doubled_up_source_fields) {
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $source_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        $self->pointed_hint('debian-control-repeats-field-name-in-value',
+            $pointer, '(in section for source)', $field);
+    }
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        # something like "Maintainer: Maintainer: bad field"
+        my @doubled_up_installable_fields
+          = grep { $installable_fields->value($_) =~ m{^ \Q$_\E \s* : }ix }
+          $installable_fields->names;
+
+        for my $field (@doubled_up_installable_fields) {
+
+            my $control_item= $self->processable->debian_control->item;
+            my $position = $installable_fields->position($field);
+            my $pointer = $control_item->pointer($position);
+
+            $self->pointed_hint('debian-control-repeats-field-name-in-value',
+                $pointer,"(in section for $installable)", $field);
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Empty.pm b/lib/Lintian/Check/Debian/Control/Field/Empty.pm
new file mode 100644
index 0000000..15b48ca
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Empty.pm
@@ -0,0 +1,84 @@
+# debian/control/field/empty -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Empty;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    my @empty_source_fields
+      = grep { !length $source_fields->value($_) } $source_fields->names;
+
+    for my $field (@empty_source_fields) {
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $source_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        $self->pointed_hint(
+            'debian-control-has-empty-field', $pointer,
+            '(in source paragraph)', $field
+        );
+    }
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        my @empty_installable_fields
+          = grep { !length $installable_fields->value($_) }
+          $installable_fields->names;
+
+        for my $field (@empty_installable_fields) {
+
+            my $control_item= $self->processable->debian_control->item;
+            my $position = $installable_fields->position($field);
+            my $pointer = $control_item->pointer($position);
+
+            $self->pointed_hint(
+                'debian-control-has-empty-field',$pointer,
+                "(in section for $installable)", $field
+            );
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Misplaced.pm b/lib/Lintian/Check/Debian/Control/Field/Misplaced.pm
new file mode 100644
index 0000000..743be38
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Misplaced.pm
@@ -0,0 +1,67 @@
+# debian/control/field/misplaced -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Misplaced;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    my @build_fields
+      =qw{Build-Depends Build-Depends-Indep Build-Conflicts Build-Conflicts-Indep};
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        for my $field (@build_fields) {
+
+            my $control_item= $self->processable->debian_control->item;
+            my $position = $installable_fields->position($field);
+            my $pointer = $control_item->pointer($position);
+
+            $self->pointed_hint('build-prerequisite-in-installable-section',
+                $pointer, $field,"(in section for $installable)")
+              if $installable_fields->declares($field);
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Redundant.pm b/lib/Lintian/Check/Debian/Control/Field/Redundant.pm
new file mode 100644
index 0000000..9f78dd4
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Redundant.pm
@@ -0,0 +1,68 @@
+# debian/control/field/redundant -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Redundant;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        for my $field ($installable_fields->names) {
+
+            my $control_item= $self->processable->debian_control->item;
+            my $position = $installable_fields->position($field);
+            my $pointer = $control_item->pointer($position);
+
+            $self->pointed_hint(
+                'installable-field-mirrors-source',$pointer,
+                "(in section for $installable)", $field
+              )
+              if $source_fields->declares($field)
+              && $installable_fields->value($field) eq
+              $source_fields->value($field);
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Relation.pm b/lib/Lintian/Check/Debian/Control/Field/Relation.pm
new file mode 100644
index 0000000..3047971
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Relation.pm
@@ -0,0 +1,180 @@
+# debian/control/field/relation -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Relation;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Lintian::Relation;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    # Check that fields which should be comma-separated or
+    # pipe-separated have separators.  Places where this tends to
+    # cause problems are with wrapped lines such as:
+    #
+    #     Depends: foo, bar
+    #      baz
+    #
+    # or with substvars.  If two substvars aren't separated by a
+    # comma, but at least one of them expands to an empty string,
+    # there will be a lurking bug.  The result will be syntactically
+    # correct, but as soon as both expand into something non-empty,
+    # there will be a syntax error.
+    #
+    # The architecture list can contain things that look like packages
+    # separated by spaces, so we have to remove any architecture
+    # restrictions first.  This unfortunately distorts our report a
+    # little, but hopefully not too much.
+    #
+    # Also check for < and > relations.  dpkg-gencontrol warns about
+    # them and then transforms them in the output to <= and >=, but
+    # it's easy to miss the error message.  Similarly, check for
+    # duplicates, which dpkg-source eliminates.
+
+    for my $field (
+        qw(Build-Depends Build-Depends-Indep
+        Build-Conflicts Build-Conflicts-Indep)
+    ) {
+        next
+          unless $source_fields->declares($field);
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $source_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        my @values = $source_fields->trimmed_list($field, qr{ \s* , \s* }x);
+        my @obsolete = grep { m{ [(] [<>] \s* [^<>=]+ [)] }x } @values;
+
+        $self->pointed_hint(
+            'obsolete-relation-form-in-source',
+            $pointer, '(in source paragraph)',
+            $field, $_
+        )for @obsolete;
+
+        my $raw = $source_fields->value($field);
+        my $relation = Lintian::Relation->new->load($raw);
+
+        for my $redundant_set ($relation->redundancies) {
+
+            $self->pointed_hint('redundant-control-relation', $pointer,
+                '(in source paragraph)',
+                $field,join(', ', sort @{$redundant_set}));
+        }
+
+        $self->check_separators($raw, $pointer, '(in source paragraph)');
+    }
+
+    for my $installable ($control->installables) {
+        my $installable_fields = $control->installable_fields($installable);
+
+        for my $field (
+            qw(Pre-Depends Depends Recommends Suggests Breaks
+            Conflicts Provides Replaces Enhances)
+        ) {
+            next
+              unless $installable_fields->declares($field);
+
+            my $control_item= $self->processable->debian_control->item;
+            my $position = $installable_fields->position($field);
+            my $pointer = $control_item->pointer($position);
+
+            my @values
+              = $installable_fields->trimmed_list($field, qr{ \s* , \s* }x);
+            my @obsolete = grep { m{ [(] [<>] \s* [^<>=]+ [)] }x } @values;
+
+            $self->pointed_hint(
+                'obsolete-relation-form-in-source',
+                $pointer, "(in section for $installable)",
+                $field, $_
+            )for @obsolete;
+
+            my $relation
+              = $self->processable->binary_relation($installable, $field);
+
+            for my $redundant_set ($relation->redundancies) {
+
+                $self->pointed_hint(
+                    'redundant-control-relation', $pointer,
+                    "(in section for $installable)", $field,
+                    join(', ', sort @{$redundant_set})
+                );
+            }
+
+            my $raw = $installable_fields->value($field);
+            $self->check_separators($raw, $pointer,
+                "(in section for $installable)");
+        }
+    }
+
+    return;
+}
+
+sub check_separators {
+    my ($self, $string, $pointer, $explainer) = @_;
+
+    $string =~ s/\n(\s)/$1/g;
+    $string =~ s/\[[^\]]*\]//g;
+
+    if (
+        $string =~ m{(?:^|\s)
+                   (
+                (?:\w[^\s,|\$\(]+|\$\{\S+:Depends\})\s*
+                (?:\([^\)]*\)\s*)?
+                   )
+                   \s+
+                   (
+                (?:\w[^\s,|\$\(]+|\$\{\S+:Depends\})\s*
+                (?:\([^\)]*\)\s*)?
+                   )}x
+    ) {
+        my ($prev, $next) = ($1, $2);
+
+        # trim right
+        $prev =~ s/\s+$//;
+        $next =~ s/\s+$//;
+
+        $self->pointed_hint('missing-separator-between-items',
+            $pointer,$explainer, "'$prev' and '$next'");
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/RulesRequiresRoot.pm b/lib/Lintian/Check/Debian/Control/Field/RulesRequiresRoot.pm
new file mode 100644
index 0000000..b97a673
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/RulesRequiresRoot.pm
@@ -0,0 +1,99 @@
+# debian/control/field/rules-requires-root -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::RulesRequiresRoot;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use List::SomeUtils qw(first_value);
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    my @r3_misspelled = grep { $_ ne 'Rules-Requires-Root' }
+      grep { m{^ Rules? - Requires? - Roots? $}xi } $source_fields->names;
+
+    for my $field (@r3_misspelled) {
+
+        my $control_item= $self->processable->debian_control->item;
+        my $position = $source_fields->position($field);
+        my $pointer = $control_item->pointer($position);
+
+        $self->pointed_hint('spelling-error-in-rules-requires-root',
+            $pointer, $field);
+    }
+
+    my $control_item= $self->processable->debian_control->item;
+    my $position = $source_fields->position('Rules-Requires-Root');
+    my $pointer = $control_item->pointer($position);
+
+    $self->pointed_hint('rules-do-not-require-root', $pointer)
+      if $source_fields->value('Rules-Requires-Root') eq 'no';
+
+    $self->pointed_hint('rules-require-root-explicitly', $pointer)
+      if $source_fields->declares('Rules-Requires-Root')
+      && $source_fields->value('Rules-Requires-Root') ne 'no';
+
+    $self->pointed_hint('silent-on-rules-requiring-root', $pointer)
+      unless $source_fields->declares('Rules-Requires-Root');
+
+    if (  !$source_fields->declares('Rules-Requires-Root')
+        || $source_fields->value('Rules-Requires-Root') eq 'no') {
+
+        for my $installable ($self->group->get_installables) {
+
+            my $user_owned_item
+              = first_value { $_->owner ne 'root' || $_->group ne 'root' }
+            @{$installable->installed->sorted_list};
+
+            next
+              unless defined $user_owned_item;
+
+            my $owner = $user_owned_item->owner;
+            my $group = $user_owned_item->group;
+
+            $self->pointed_hint('rules-silently-require-root',
+                $pointer, $installable->name,
+                "($owner:$group)", $user_owned_item->name);
+        }
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Section.pm b/lib/Lintian/Check/Debian/Control/Field/Section.pm
new file mode 100644
index 0000000..dd0ba52
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Section.pm
@@ -0,0 +1,52 @@
+# debian/control/field/section -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Section;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $control = $self->processable->debian_control;
+    my $source_fields = $control->source_fields;
+
+    $self->pointed_hint('no-source-section', $control->item->pointer)
+      unless $source_fields->declares('Section');
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et
diff --git a/lib/Lintian/Check/Debian/Control/Field/Spacing.pm b/lib/Lintian/Check/Debian/Control/Field/Spacing.pm
new file mode 100644
index 0000000..070ebdf
--- /dev/null
+++ b/lib/Lintian/Check/Debian/Control/Field/Spacing.pm
@@ -0,0 +1,78 @@
+# debian/control/field/spacing -- lintian check script -*- perl -*-
+#
+# Copyright (C) 2004 Marc Brockschmidt
+# Copyright (C) 2020 Chris Lamb <lamby@debian.org>
+# Copyright (C) 2020-2021 Felix Lechner
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, you can find it on the World Wide
+# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
+# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+# MA 02110-1301, USA.
+
+package Lintian::Check::Debian::Control::Field::Spacing;
+
+use v5.20;
+use warnings;
+use utf8;
+
+use Moo;
+use namespace::clean;
+
+with 'Lintian::Check';
+
+sub source {
+    my ($self) = @_;
+
+    my $item = $self->processable->debian_control->item;
+    return
+      unless defined $item;
+
+    my @lines = split(/\n/, $item->decoded_utf8);
+
+    my $position = 1;
+    while (defined(my $line = shift @lines)) {
+
+        # strip leading spaces
+        $line =~ s{\s*$}{};
+
+        next
+          if $line =~ m{^ [#]}x;
+
+        # line with field:
+        if ($line =~ m{^ (\S+) : }x) {
+
+            my $field = $1;
+
+            my $pointer = $item->pointer($position);
+
+            $self->pointed_hint('debian-control-has-unusual-field-spacing',
+                $pointer, $field)
+              unless $line =~ m{^ \S+ : [ ] \S }x
+              || $line =~ m{^ \S+ : $}x;
+        }
+
+    } continue {
+        ++$position;
+    }
+
+    return;
+}
+
+1;
+
+# Local Variables:
+# indent-tabs-mode: nil
+# cperl-indent-level: 4
+# End:
+# vim: syntax=perl sw=4 sts=4 sr et