1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
|
# Copyright (C) 2012 Niels Thykier <niels@thykier.net>
# Copyright (C) 2017-2018 Chris Lamb <lamby@debian.org>
# Copyright (C) 2019-2021 Felix Lechner <felix.lechner@lease-up.com>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, you can find it on the World Wide
# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.
package Lintian::Check;
use v5.20;
use warnings;
use utf8;
use Const::Fast;
use Unicode::UTF8 qw(encode_utf8);
use Lintian::Hint::Annotated;
use Lintian::Hint::Pointed;
const my $EMPTY => q{};
const my $SPACE => q{ };
const my $UNDERSCORE => q{_};
use Moo::Role;
use namespace::clean;
=head1 NAME
Lintian::Check -- Common facilities for Lintian checks
=head1 SYNOPSIS
use Moo;
use namespace::clean;
with('Lintian::Check');
=head1 DESCRIPTION
A class for operating Lintian checks
=head1 INSTANCE METHODS
=over 4
=item name
=item processable
=item group
=item profile
=item hints
=cut
has name => (is => 'rw', default => $EMPTY);
has processable => (is => 'rw', default => sub { {} });
has group => (is => 'rw', default => sub { {} });
has profile => (is => 'rw');
has hints => (is => 'rw', default => sub { [] });
=item data
=cut
sub data {
my ($self) = @_;
return $self->profile->data;
}
=item visit_files
=cut
sub visit_files {
my ($self, $index) = @_;
my $visit_hook = 'visit' . $UNDERSCORE . $index . $UNDERSCORE . 'files';
return
unless $self->can($visit_hook);
my @items = @{$self->processable->$index->sorted_list};
# do not look inside quilt directory
@items = grep { $_->name !~ m{^\.pc/} } @items
if $index eq 'patched';
# exclude Lintian's test suite from source scans
@items = grep { $_->name !~ m{^t/} } @items
if $self->processable->name eq 'lintian' && $index eq 'patched';
$self->$visit_hook($_) for @items;
return;
}
=item run
=cut
sub run {
my ($self) = @_;
# do not carry over any hints
$self->hints([]);
my $type = $self->processable->type;
if ($type eq 'source') {
$self->visit_files('orig');
$self->visit_files('patched');
}
if ($type eq 'binary' || $type eq 'udeb') {
$self->visit_files('control');
$self->visit_files('installed');
$self->installable
if $self->can('installable');
}
$self->$type
if $self->can($type);
$self->always
if $self->can('always');
return @{$self->hints};
}
=item pointed_hint
=cut
sub pointed_hint {
my ($self, $tag_name, $pointer, @notes) = @_;
my $hint = Lintian::Hint::Pointed->new;
$hint->tag_name($tag_name);
$hint->issued_by($self->name);
my $note = stringify(@notes);
$hint->note($note);
$hint->pointer($pointer);
push(@{$self->hints}, $hint);
return;
}
=item hint
=cut
sub hint {
my ($self, $tag_name, @notes) = @_;
my $hint = Lintian::Hint::Annotated->new;
$hint->tag_name($tag_name);
$hint->issued_by($self->name);
my $note = stringify(@notes);
$hint->note($note);
push(@{$self->hints}, $hint);
return;
}
=item stringify
=cut
sub stringify {
my (@arguments) = @_;
# skip empty arguments
my @meaningful = grep { length } @arguments;
# trim both ends of each item
s{^ \s+ | \s+ $}{}gx for @meaningful;
# concatenate with spaces
my $text = join($SPACE, @meaningful) // $EMPTY;
# escape newlines; maybe add others
$text =~ s{\n}{\\n}g;
return $text;
}
=back
=head1 AUTHOR
Originally written by Felix Lechner <felix.lechner@lease-up.com> for Lintian.
=head1 SEE ALSO
lintian(1)
=cut
1;
# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et
|
