1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# huge-usr-share -- lintian check script -*- perl -*-
# Copyright (C) 2004 Jeroen van Wolffelaar <jeroen@wolffelaar.nl>
# Copyright (C) 2018 Chris Lamb <lamby@debian.org>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, you can find it on the World Wide
# Web at https://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.
package Lintian::Check::HugeUsrShare;
use v5.20;
use warnings;
use utf8;
use Const::Fast;
use Moo;
use namespace::clean;
with 'Lintian::Check';
# Threshold in kB of /usr/share to trigger this warning. Consider that the
# changelog alone can be quite big, and cannot be moved away.
const my $KIB_SIZE_FACTOR => 1024;
const my $THRESHOLD_SIZE_SOFT => 4096;
const my $THRESHOLD_SIZE_HARD => 8192;
const my $PERCENT => 100;
const my $THRESHOLD_PERCENTAGE => 50;
has total_size => (is => 'rw', default => 0);
has usrshare_size => (is => 'rw', default => 0);
sub visit_installed_files {
my ($self, $file) = @_;
return
unless $file->is_regular_file;
# space taken up by package
$self->total_size($self->total_size + $file->size);
# space taken up in /usr/share.
$self->usrshare_size($self->usrshare_size + $file->size)
if $file =~ m{^usr/share/};
return;
}
sub installable {
my ($self) = @_;
# skip architecture-dependent packages.
my $arch = $self->processable->fields->value('Architecture');
return
if $arch eq 'all';
# meaningless; prevents division by zero
return
if $self->total_size == 0;
# convert the totals to kilobytes.
my $size = sprintf('%.0f', $self->total_size / $KIB_SIZE_FACTOR);
my $size_usrshare
= sprintf('%.0f', $self->usrshare_size / $KIB_SIZE_FACTOR);
my $percentage
= sprintf('%.0f', ($self->usrshare_size / $self->total_size) * $PERCENT);
$self->hint(
'arch-dep-package-has-big-usr-share',
"${size_usrshare}kB $percentage%"
)
if ( $percentage > $THRESHOLD_PERCENTAGE
&& $size_usrshare > $THRESHOLD_SIZE_SOFT)
|| $size_usrshare > $THRESHOLD_SIZE_HARD;
return;
}
1;
# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et
|
