1 files changed, 42 insertions, 0 deletions
diff --git a/contrib/postgres_fdw/meson.build b/contrib/postgres_fdw/meson.build
new file mode 100644
index 0000000..2b451f1
--- /dev/null
+++ b/contrib/postgres_fdw/meson.build
@@ -0,0 +1,42 @@
+# Copyright (c) 2022-2023, PostgreSQL Global Development Group
+
+postgres_fdw_sources = files(
+  'connection.c',
+  'deparse.c',
+  'option.c',
+  'postgres_fdw.c',
+  'shippable.c',
+)
+
+if host_system == 'windows'
+  postgres_fdw_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
+    '--NAME', 'postgres_fdw',
+    '--FILEDESC', 'postgres_fdw - foreign data wrapper for PostgreSQL',])
+endif
+
+postgres_fdw = shared_module('postgres_fdw',
+  postgres_fdw_sources,
+  kwargs: contrib_mod_args + {
+    'dependencies': contrib_mod_args['dependencies'] + [libpq],
+  },
+)
+contrib_targets += postgres_fdw
+
+install_data(
+  'postgres_fdw.control',
+  'postgres_fdw--1.0.sql',
+  'postgres_fdw--1.0--1.1.sql',
+  kwargs: contrib_data_args,
+)
+
+tests += {
+  'name': 'postgres_fdw',
+  'sd': meson.current_source_dir(),
+  'bd': meson.current_build_dir(),
+  'regress': {
+    'sql': [
+      'postgres_fdw',
+    ],
+    'regress_args': ['--dlpath', meson.build_root() / 'src/test/regress'],
+  },
+}