1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
// -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 2 -*-
//
// This Source Code Form is subject to the terms of the Mozilla Public
// License, v. 2.0. If a copy of the MPL was not distributed with this
// file, You can obtain one at http://mozilla.org/MPL/2.0/.
.text
// PRInt32 _PR_ia64_AtomicIncrement(PRInt32 *val)
//
// Atomically increment the integer pointed to by 'val' and return
// the result of the increment.
//
.align 16
.global _PR_ia64_AtomicIncrement#
.proc _PR_ia64_AtomicIncrement#
_PR_ia64_AtomicIncrement:
fetchadd4.acq r8 = [r32], 1 ;;
adds r8 = 1, r8
br.ret.sptk.many b0
.endp _PR_ia64_AtomicIncrement#
// PRInt32 _PR_ia64_AtomicDecrement(PRInt32 *val)
//
// Atomically decrement the integer pointed to by 'val' and return
// the result of the decrement.
//
.align 16
.global _PR_ia64_AtomicDecrement#
.proc _PR_ia64_AtomicDecrement#
_PR_ia64_AtomicDecrement:
fetchadd4.rel r8 = [r32], -1 ;;
adds r8 = -1, r8
br.ret.sptk.many b0
.endp _PR_ia64_AtomicDecrement#
// PRInt32 _PR_ia64_AtomicAdd(PRInt32 *ptr, PRInt32 val)
//
// Atomically add 'val' to the integer pointed to by 'ptr'
// and return the result of the addition.
//
.align 16
.global _PR_ia64_AtomicAdd#
.proc _PR_ia64_AtomicAdd#
_PR_ia64_AtomicAdd:
ld4 r15 = [r32] ;;
.L3:
mov r14 = r15
mov ar.ccv = r15
add r8 = r15, r33 ;;
cmpxchg4.acq r15 = [r32], r8, ar.ccv ;;
cmp4.ne p6, p7 = r15, r14
(p6) br.cond.dptk .L3
br.ret.sptk.many b0
.endp _PR_ia64_AtomicAdd#
// PRInt32 _PR_ia64_AtomicSet(PRInt32 *val, PRInt32 newval)
//
// Atomically set the integer pointed to by 'val' to the new
// value 'newval' and return the old value.
//
.align 16
.global _PR_ia64_AtomicSet#
.proc _PR_ia64_AtomicSet#
_PR_ia64_AtomicSet:
xchg4 r8 = [r32], r33
br.ret.sptk.many b0
.endp _PR_ia64_AtomicSet#
// Magic indicating no need for an executable stack
.section .note.GNU-stack, "", @progbits
|
