Adding upstream version 115.7.0esr.upstream/115.7.0esrupstream

Signed-off-by: Daniel Baumann <daniel.baumann@progress-linux.org>

4 files changed, 205 insertions, 0 deletions

diff --git a/dom/xml/resources/XMLPrettyPrint.css b/dom/xml/resources/XMLPrettyPrint.css
new file mode 100644
index 0000000000..845833c46f
--- /dev/null
+++ b/dom/xml/resources/XMLPrettyPrint.css
@@ -0,0 +1,58 @@
+@charset "UTF-8";
+/* This Source Code Form is subject to the terms of the Mozilla Public
+ * License, v. 2.0. If a copy of the MPL was not distributed with this
+ * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
+
+@import url("resource://content-accessible/viewsource.css");
+
+:host {
+  color-scheme: light dark;
+}
+
+#header {
+  background-color: #ccc;
+  border-bottom: 3px solid black;
+  padding: 0.5em;
+  margin-bottom: 1em;
+}
+
+@media (prefers-color-scheme: dark) {
+  #header {
+    background-color: #333;
+    border-color: #555;
+  }
+}
+
+#tree,
+.expandable-children {
+  margin-inline-start: 1em;
+}
+
+.expandable-body {
+  display: inline-block;
+}
+
+.expandable-body[open] {
+  display: block;
+}
+
+.expandable-opening {
+  list-style: '+' outside;
+}
+
+[open] > .expandable-opening {
+  list-style-type: '−';
+}
+
+.expandable-opening::marker {
+  cursor: pointer;
+  padding-inline-end: 2px;
+  /* Don't want to inherit the styling from pi and comment elements */
+  color: buttontext;
+  font: initial;
+}
+
+.comment {
+  font-family: monospace;
+  white-space: pre;
+}
diff --git a/dom/xml/resources/XMLPrettyPrint.xsl b/dom/xml/resources/XMLPrettyPrint.xsl
new file mode 100644
index 0000000000..b23296cf0d
--- /dev/null
+++ b/dom/xml/resources/XMLPrettyPrint.xsl
@@ -0,0 +1,133 @@
+<?xml version="1.0"?>
+<!-- This Source Code Form is subject to the terms of the Mozilla Public
+   - License, v. 2.0. If a copy of the MPL was not distributed with this
+   - file, You can obtain one at http://mozilla.org/MPL/2.0/. -->
+
+<!DOCTYPE overlay>
+
+<xsl:stylesheet version="1.0"
+                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                xmlns="http://www.w3.org/1999/xhtml">
+
+  <xsl:output method="xml"/>
+
+  <xsl:template match="/">
+    <div id="top">
+      <link rel="stylesheet" href="chrome://global/content/xml/XMLPrettyPrint.css"/>
+      <div id="header">
+        <p data-l10n-id="xml-nostylesheet"></p>
+      </div>
+      <main id="tree" class="highlight">
+        <xsl:apply-templates/>
+      </main>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="*">
+    <div>
+      <xsl:text>&lt;</xsl:text>
+      <span class="start-tag"><xsl:value-of select="name(.)"/></span>
+      <xsl:apply-templates select="@*"/>
+      <xsl:text>/&gt;</xsl:text>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="*[node()]">
+    <div>
+      <xsl:text>&lt;</xsl:text>
+      <span class="start-tag"><xsl:value-of select="name(.)"/></span>
+      <xsl:apply-templates select="@*"/>
+      <xsl:text>&gt;</xsl:text>
+
+      <span class="text"><xsl:value-of select="."/></span>
+
+      <xsl:text>&lt;/</xsl:text>
+      <span class="end-tag"><xsl:value-of select="name(.)"/></span>
+      <xsl:text>&gt;</xsl:text>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="*[* or processing-instruction() or comment() or string-length(.) &gt; 50]">
+    <div>
+      <details open="" class="expandable-body">
+        <summary class="expandable-opening">
+          <xsl:text>&lt;</xsl:text>
+          <span class="start-tag"><xsl:value-of select="name(.)"/></span>
+          <xsl:apply-templates select="@*"/>
+          <xsl:text>&gt;</xsl:text>
+        </summary>
+
+        <div class="expandable-children"><xsl:apply-templates/></div>
+
+      </details>
+      <span class="expandable-closing">
+        <xsl:text>&lt;/</xsl:text>
+        <span class="end-tag"><xsl:value-of select="name(.)"/></span>
+        <xsl:text>&gt;</xsl:text>
+      </span>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="@*">
+    <xsl:text> </xsl:text>
+    <span class="attribute-name"><xsl:value-of select="name(.)"/></span>
+    <xsl:text>=</xsl:text>
+    <span class="attribute-value">"<xsl:value-of select="."/>"</span>
+  </xsl:template>
+
+  <xsl:template match="text()">
+    <xsl:if test="normalize-space(.)">
+      <xsl:value-of select="."/>
+    </xsl:if>
+  </xsl:template>
+
+  <xsl:template match="processing-instruction()">
+    <div class="pi">
+      <xsl:text>&lt;?</xsl:text>
+      <xsl:value-of select="name(.)"/>
+      <xsl:text> </xsl:text>
+      <xsl:value-of select="."/>
+      <xsl:text>?&gt;</xsl:text>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="processing-instruction()[string-length(.) &gt; 50]">
+    <div class="pi">
+      <details open="" class="expandable-body">
+        <summary class="expandable-opening">
+          <xsl:text>&lt;?</xsl:text>
+          <xsl:value-of select="name(.)"/>
+        </summary>
+        <div class="expandable-children"><xsl:value-of select="."/></div>
+      </details>
+      <span class="expandable-closing">
+        <xsl:text>?&gt;</xsl:text>
+      </span>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="comment()">
+    <div class="comment">
+      <xsl:text>&lt;!--</xsl:text>
+      <xsl:value-of select="."/>
+      <xsl:text>--&gt;</xsl:text>
+    </div>
+  </xsl:template>
+
+  <xsl:template match="comment()[string-length(.) &gt; 50]">
+    <div class="comment">
+      <details open="" class="expandable-body">
+        <summary class="expandable-opening">
+          <xsl:text>&lt;!--</xsl:text>
+        </summary>
+        <div class="expandable-children">
+          <xsl:value-of select="."/>
+        </div>
+      </details>
+      <span class="expandable-closing">
+        <xsl:text>--&gt;</xsl:text>
+      </span>
+    </div>
+  </xsl:template>
+
+</xsl:stylesheet>
diff --git a/dom/xml/resources/jar.mn b/dom/xml/resources/jar.mn
new file mode 100644
index 0000000000..14fc365a3e
--- /dev/null
+++ b/dom/xml/resources/jar.mn
@@ -0,0 +1,7 @@
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+
+toolkit.jar:
+    content/global/xml/XMLPrettyPrint.css                 (XMLPrettyPrint.css)
+    content/global/xml/XMLPrettyPrint.xsl                 (XMLPrettyPrint.xsl)
diff --git a/dom/xml/resources/moz.build b/dom/xml/resources/moz.build
new file mode 100644
index 0000000000..d988c0ff9b
--- /dev/null
+++ b/dom/xml/resources/moz.build
@@ -0,0 +1,7 @@
+# -*- Mode: python; indent-tabs-mode: nil; tab-width: 40 -*-
+# vim: set filetype=python:
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+
+JAR_MANIFESTS += ["jar.mn"]