1 files changed, 56 insertions, 0 deletions
diff --git a/panels/color/meson.build b/panels/color/meson.build
new file mode 100644
index 0000000..9368ae9
--- /dev/null
+++ b/panels/color/meson.build
@@ -0,0 +1,56 @@
+panels_list += cappletname
+desktop = 'gnome-@0@-panel.desktop'.format(cappletname)
+
+desktop_in = configure_file(
+  input: desktop + '.in.in',
+  output: desktop + '.in',
+  configuration: desktop_conf
+)
+
+i18n.merge_file(
+  type: 'desktop',
+  input: desktop_in,
+  output: desktop,
+  po_dir: po_dir,
+  install: true,
+  install_dir: control_center_desktopdir
+)
+
+sources = files(
+  'cc-color-panel.c',
+  'cc-color-calibrate.c',
+  'cc-color-cell-renderer-text.c',
+  'cc-color-common.c',
+  'cc-color-device.c',
+  'cc-color-profile.c'
+)
+
+resource_data = files(
+  'cc-color-calibrate.ui',
+  'cc-color-panel.ui',
+)
+
+sources += gnome.compile_resources(
+  'cc-' + cappletname + '-resources',
+  cappletname + '.gresource.xml',
+  c_name: 'cc_' + cappletname,
+  dependencies: resource_data,
+  export: true
+)
+
+deps = common_deps + [
+  colord_dep,
+  gnome_rr_dep,
+  m_dep,
+  dependency('colord-gtk4', version: '>= 0.1.24'),
+]
+
+panels_libs += static_library(
+  cappletname,
+  sources: sources,
+  include_directories: [ top_inc, common_inc ],
+  dependencies: deps,
+  c_args: cflags
+)
+
+subdir('icons')