summaryrefslogtreecommitdiffstats
path: root/shell/meson.build
blob: 9553c35ce9be1fac99dbb31b4effa019783d76a8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
subdir('appdata')
subdir('completions')

service_conf = configuration_data()
service_conf.set('bindir', control_center_bindir)

service = 'org.gnome.Settings.service'

configure_file(
          input : service + '.in',
         output : service,
        install : true,
    install_dir : join_paths(control_center_datadir, 'dbus-1', 'services'),
  configuration : service_conf
)

desktop = 'org.gnome.Settings.desktop'

desktop_in = configure_file(
          input : desktop + '.in.in',
         output : desktop + '.in',
  configuration : desktop_conf
)

i18n.merge_file(
         type : 'desktop',
        input : desktop_in,
       output : desktop,
       po_dir : po_dir,
      install : true,
  install_dir : control_center_desktopdir
)

cflags = ['-DGNOMELOCALEDIR="@0@"'.format(control_center_localedir)]


# Common sources between gnome-control-center and
# libtestshell.
common_sources = files(
  'cc-application.c',
  'cc-log.c',
  'cc-object-storage.c',
  'cc-panel-loader.c',
  'cc-panel.c',
  'cc-shell.c',
  'cc-panel-list.c',
  'cc-window.c',
)


###################
# Generated files #
###################

generated_sources = files()

# Debug
debug_conf = configuration_data()
debug_conf.set('BUGREPORT_URL', 'https://gitlab.gnome.org/GNOME/' + meson.project_name() + '/issues/new')
debug_conf.set10('ENABLE_TRACING', enable_tracing)

generated_sources += configure_file(
          input : 'cc-debug.h.in',
         output : 'cc-debug.h',
  configuration : debug_conf
)

#Resources
resource_data = files(
  'cc-panel-list.ui',
  'cc-window.ui',
  'help-overlay.ui',
)

generated_sources += gnome.compile_resources(
       'resources',
  meson.project_name() + '.gresource.xml',
     dependencies : resource_data,
           export : true
)

common_sources += generated_sources

############
# libshell #
############

libshell = static_library(
               'shell',
              sources : 'cc-shell-model.c',
  include_directories : [top_inc, common_inc],
         dependencies : common_deps,
               c_args : cflags
)

libshell_dep = declare_dependency(
              sources : generated_sources,
  include_directories : top_inc,
            link_with : libshell
)


########################
# gnome-control-center #
########################

shell_sources = common_sources + files('main.c')

shell_deps = common_deps + [
  libdevice_dep,
  liblanguage_dep,
  libwidgets_dep,
  x11_dep,
  libshell_dep,
]

if host_is_linux_not_s390
  shell_deps += wacom_deps
endif

executable(
  meson.project_name(),
         shell_sources,
  include_directories : top_inc,
         dependencies : shell_deps,
               c_args : cflags,
            link_with : panels_libs,
              install : true
)


##################
# lipanel_loader #
##################

# Because it is confusing and somewhat problematic to directly add and compile
# cc-panel-loader.o by another directory (i.e. the shell search provider), we
# have to create a library and link it there, just like libshell.la.
libpanel_loader = static_library(
        'panel_loader',
              sources : 'cc-panel-loader.c',
  include_directories : top_inc,
         dependencies : common_deps,
               c_args : cflags + ['-DCC_PANEL_LOADER_NO_GTYPES']
)


################
# libtestshell #
################

libtestshell = static_library(
           'testshell',
        common_sources,
  include_directories : top_inc,
         dependencies : shell_deps,
               c_args : cflags,
            link_with : panels_libs,
)
libtestshell_dep = declare_dependency(
              sources : generated_sources,
  include_directories : top_inc,
            link_with : libtestshell
)
libtestshell_deps = common_deps + [ libwidgets_dep, libtestshell_dep ]


install_data (
  'org.gnome.Settings.gschema.xml',
  install_dir : control_center_schemadir
)