1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
|
%name-prefix="flb_sp_" // replace with %define api.prefix {flb_sp_}
%define api.pure full
%define parse.error verbose
%parse-param { struct flb_sp_cmd *cmd };
%parse-param { const char *query };
%lex-param { void *scanner }
%parse-param { void *scanner }
%{ // definition section (prologue)
#include <stdio.h>
#include <stdlib.h>
#include <ctype.h>
#include <fluent-bit/flb_mem.h>
#include <fluent-bit/flb_slist.h>
#include <fluent-bit/stream_processor/flb_sp_parser.h>
#include "sql_parser.h"
#include "sql_lex.h"
extern int yylex();
void yyerror(struct flb_sp_cmd *cmd, const char *query, void *scanner, const char *str)
{
flb_error("[sp] %s at '%s'", str, query);
}
%} /* EOF C code */
/* Bison declarations */
/* Known Tokens (refer to sql.l) */
/* Keywords */
%token IDENTIFIER QUOTE
/* Basic keywords for statements */
%token CREATE STREAM SNAPSHOT FLUSH WITH SELECT AS FROM FROM_STREAM FROM_TAG
%token WHERE WINDOW GROUP_BY LIMIT
/* Null keywords */
%token IS NUL
/* Aggregation functions */
%token AVG SUM COUNT MAX MIN TIMESERIES_FORECAST
/* Record functions */
%token RECORD CONTAINS TIME
/* Time functions */
%token NOW UNIX_TIMESTAMP
/* Record functions */
%token RECORD_TAG RECORD_TIME
/* Value types */
%token INTEGER FLOATING STRING BOOLTYPE
/* Logical operation tokens */
%token AND OR NOT NEQ LT LTE GT GTE
/* Time tokens */
%token HOUR MINUTE SECOND
/* Window tokens */
%token TUMBLING HOPPING ADVANCE_BY
/* Union and field types */
%union
{
bool boolean;
int integer;
float fval;
char *string;
struct flb_sp_cmd *cmd;
struct flb_exp *expression;
}
%type <boolean> BOOLTYPE
%type <integer> INTEGER
%type <fval> FLOATING
%type <string> IDENTIFIER
%type <string> STRING
%type <string> record_keys
%type <string> record_key
%type <string> prop_key
%type <string> prop_val
%type <expression> condition
%type <expression> comparison
%type <expression> key
%type <expression> record_func
%type <expression> value
%type <expression> null
%type <integer> time
%type <integer> time_record_func
%type <integer> NOW UNIX_TIMESTAMP RECORD_TAG RECORD_TIME
%type <integer> aggregate_func
%type <integer> COUNT AVG SUM MAX MIN TIMESERIES_FORECAST
%destructor { flb_free ($$); } IDENTIFIER
%% /* rules section */
statements: create | select
/* Parser for 'CREATE STREAM' statement */
create:
CREATE STREAM IDENTIFIER AS select
{
flb_sp_cmd_stream_new(cmd, $3);
flb_free($3);
}
|
CREATE STREAM IDENTIFIER WITH '(' properties ')' AS select
{
flb_sp_cmd_stream_new(cmd, $3);
flb_free($3);
}
|
CREATE SNAPSHOT IDENTIFIER AS SELECT '*' FROM source limit ';'
{
flb_sp_cmd_snapshot_new(cmd, $3);
flb_free($3);
}
|
CREATE SNAPSHOT IDENTIFIER WITH '(' properties ')' AS SELECT '*' FROM source limit ';'
{
flb_sp_cmd_snapshot_new(cmd, $3);
flb_free($3);
}
|
FLUSH SNAPSHOT IDENTIFIER AS SELECT '*' FROM source where ';'
{
flb_sp_cmd_snapshot_flush_new(cmd, $3);
flb_free($3);
}
|
FLUSH SNAPSHOT IDENTIFIER WITH '(' properties ')' AS SELECT '*' FROM source where ';'
{
flb_sp_cmd_snapshot_flush_new(cmd, $3);
flb_free($3);
}
properties: property
|
properties ',' property
property: prop_key '=' prop_val
{
flb_sp_cmd_stream_prop_add(cmd, $1, $3);
flb_free($1);
flb_free($3);
}
prop_key: IDENTIFIER
prop_val: STRING
/* Parser for 'SELECT' statement */
select: SELECT keys FROM source window where groupby limit ';'
{
cmd->type = FLB_SP_SELECT;
}
keys: record_keys
record_keys: record_key
|
record_keys ',' record_key
record_key: '*'
{
flb_sp_cmd_key_add(cmd, -1, NULL);
}
|
IDENTIFIER key_alias
{
flb_sp_cmd_key_add(cmd, -1, $1);
flb_free($1);
}
|
IDENTIFIER record_subkey key_alias
{
flb_sp_cmd_key_add(cmd, -1, $1);
flb_free($1);
}
|
COUNT '(' '*' ')' key_alias
{
flb_sp_cmd_key_add(cmd, $1, NULL);
}
|
COUNT '(' IDENTIFIER ')' key_alias
{
flb_sp_cmd_key_add(cmd, $1, $3);
flb_free($3);
}
|
COUNT '(' IDENTIFIER record_subkey ')' key_alias
{
flb_sp_cmd_key_add(cmd, $1, $3);
flb_free($3);
}
|
aggregate_func '(' IDENTIFIER ')' key_alias
{
flb_sp_cmd_key_add(cmd, $1, $3);
flb_free($3);
}
|
aggregate_func '(' IDENTIFIER record_subkey ')' key_alias
{
flb_sp_cmd_key_add(cmd, $1, $3);
flb_free($3);
}
|
TIMESERIES_FORECAST '(' IDENTIFIER ',' INTEGER ')' key_alias
{
flb_sp_cmd_timeseries_forecast(cmd, $1, $3, $5);
flb_free($3);
}
|
time_record_func '(' ')' key_alias
{
flb_sp_cmd_key_add(cmd, $1, NULL);
}
aggregate_func:
AVG | SUM | MAX | MIN
time_record_func:
NOW | UNIX_TIMESTAMP | RECORD_TAG | RECORD_TIME
key_alias:
%empty
|
AS IDENTIFIER
{
flb_sp_cmd_alias_add(cmd, $2);
}
record_subkey: '[' STRING ']'
{
flb_slist_add(cmd->tmp_subkeys, $2);
flb_free($2);
}
|
record_subkey record_subkey
source: FROM_STREAM IDENTIFIER
{
flb_sp_cmd_source(cmd, FLB_SP_STREAM, $2);
flb_free($2);
}
|
FROM_TAG STRING
{
flb_sp_cmd_source(cmd, FLB_SP_TAG, $2);
flb_free($2);
}
window: %empty
|
WINDOW window_spec
where: %empty
|
WHERE condition
{
flb_sp_cmd_condition_add(cmd, $2);
}
groupby: %empty
|
GROUP_BY gb_keys
limit: %empty
|
LIMIT INTEGER
{
flb_sp_cmd_limit_add(cmd, $2);
}
window_spec:
TUMBLING '(' INTEGER time ')'
{
flb_sp_cmd_window(cmd, FLB_SP_WINDOW_TUMBLING, $3, $4, 0, 0);
}
|
HOPPING '(' INTEGER time ',' ADVANCE_BY INTEGER time ')'
{
flb_sp_cmd_window(cmd, FLB_SP_WINDOW_HOPPING, $3, $4, $7, $8);
}
condition: comparison
|
key
{
$$ = flb_sp_cmd_operation(cmd, $1, NULL, FLB_EXP_OR);
}
|
value
{
$$ = flb_sp_cmd_operation(cmd, NULL, $1, FLB_EXP_OR);
}
|
'(' condition ')'
{
$$ = flb_sp_cmd_operation(cmd, $2, NULL, FLB_EXP_PAR);
}
|
NOT condition
{
$$ = flb_sp_cmd_operation(cmd, $2, NULL, FLB_EXP_NOT);
}
|
condition AND condition
{
$$ = flb_sp_cmd_operation(cmd, $1, $3, FLB_EXP_AND);
}
|
condition OR condition
{
$$ = flb_sp_cmd_operation(cmd, $1, $3, FLB_EXP_OR);
}
comparison:
key IS null
{
$$ = flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_EQ);
}
|
key IS NOT null
{
$$ = flb_sp_cmd_operation(cmd,
flb_sp_cmd_comparison(cmd, $1, $4, FLB_EXP_EQ),
NULL, FLB_EXP_NOT);
}
|
record_func
{
$$ = flb_sp_cmd_comparison(cmd,
$1,
flb_sp_cmd_condition_boolean(cmd, true),
FLB_EXP_EQ);
}
|
record_func '=' value
{
$$ = flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_EQ);
}
|
record_func NEQ value
{
$$ = flb_sp_cmd_operation(cmd,
flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_EQ),
NULL, FLB_EXP_NOT)
;
}
|
record_func LT value
{
$$ = flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_LT);
}
|
record_func LTE value
{
$$ = flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_LTE);
}
|
record_func GT value
{
$$ = flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_GT);
}
|
record_func GTE value
{
$$ = flb_sp_cmd_comparison(cmd, $1, $3, FLB_EXP_GTE);
}
record_func: key /* Similar to an identity function */
|
RECORD '.' CONTAINS '(' key ')'
{
$$ = flb_sp_record_function_add(cmd, "contains", $5);
}
|
RECORD '.' TIME '(' ')'
{
$$ = flb_sp_record_function_add(cmd, "time", NULL);
}
key: IDENTIFIER
{
$$ = flb_sp_cmd_condition_key(cmd, $1);
flb_free($1);
}
|
IDENTIFIER record_subkey
{
$$ = flb_sp_cmd_condition_key(cmd, $1);
flb_free($1);
}
value: INTEGER
{
$$ = flb_sp_cmd_condition_integer(cmd, $1);
}
|
FLOATING
{
$$ = flb_sp_cmd_condition_float(cmd, $1);
}
|
STRING
{
$$ = flb_sp_cmd_condition_string(cmd, $1);
flb_free($1);
}
|
BOOLTYPE
{
$$ = flb_sp_cmd_condition_boolean(cmd, $1);
}
null: NUL
{
$$ = flb_sp_cmd_condition_null(cmd);
}
time: SECOND
{
$$ = FLB_SP_TIME_SECOND;
}
|
MINUTE
{
$$ = FLB_SP_TIME_MINUTE;
}
|
HOUR
{
$$ = FLB_SP_TIME_HOUR;
}
gb_keys: gb_key
|
gb_key ',' gb_keys
gb_key: IDENTIFIER
{
flb_sp_cmd_gb_key_add(cmd, $1);
flb_free($1);
}
|
IDENTIFIER record_subkey
{
flb_sp_cmd_gb_key_add(cmd, $1);
flb_free($1);
}
;
|
